[PinHeaDi]

1. How can I print the reaming time from a timer?

PHP Code:

RollTheDiceUser[client] = CreateTimer(60.0, AllowRTD, GetClientUserId(client)); 


PHP Code:

public Action PrepareTheDice(int client, int args)
{
    if (client > 0 && client <= MaxClients && IsClientInGame(client) && !RolledTheDice[client])
    {
        switch(IsPlayerAlive(client))
        {
            case true: RollTheDice(client);
            case false: CPrintToChat(client, "[{orange}RollTheDice{default}] You must be {gree}alive {default} to use RTD.");
        }
    }
    else{CPrintToChat(client, "[{orange}RollTheDice{default}] You {red}can't {default}use RTD yet. Please wait {green}%i {default} more seconds", ?!? );}

    return Plugin_Handled;
} 


2. If player A used !rtd how can I tell user B that he used the command and that he(B) should wait until the X item that player A got is gone.

[Impact123]

You don't need a timer, you can implement it like this

PHP Code:

int g_iLastCommand[MAXPLAYERS +1];

// This should probably be a convar
#define WAIT_TIME 10


public void OnPluginStart()
{
    RegConsoleCmd("sm_test", Command_Test);
}


public Action Command_Test(int client, int args)
{
    if (g_iLastCommand[client] == 0 || g_iLastCommand[client] <= GetTime())
    {
        // Your command goes here
        
        g_iLastCommand[client] = GetTime() + WAIT_TIME;
    }
    else
    {
        ReplyToCommand(client, "You have to wait %d seconds to be able to use the command again", g_iLastCommand[client] - GetTime());
    }
    

    return Plugin_Handled;
}


public void OnClientConnected(int client)
{
    g_iLastCommand[client] = 0;
} 


[PinHeaDi]

PHP Code:

public void OnClientConnected(int client)
{
    g_iLastCommand[client] = 0;
} 


With that they can use the command again even if the time isn't passed when they retry? Or I got it wrong.

Maybe:

PHP Code:

public void OnClientConnected(int client)
{
    if (g_iLastCommand[client] < 1){
    g_iLastCommand[client] = 0;}
} 


[Impact123]

Yes, but that's the same as with the timer. Client indexes are not unique so it makes sense to reset the variable when a client connects. If you want to track reconnecting player you can use a stringmap with a steamid as key.