[skatz_ws]

Hi!
I want to create a options menu for players to turn on/off things in my server, and I want to create a enumeration with all options, to see if it's on and off.

The best way to do it is with bits? like:

PHP Code:

enum Options ( <<=1 )
{
    Option1 = 1,
    Option2,
    Option3,
    Option4,
    Option5 
}; 


[Natsheh]

You are going in the right direction now just create an array with 33 cells for players to store the data.

PHP Code:


enum Options ( <<=1 )
{
    Option1 = 1,
    Option2,
    Option3,
    Option4,
    Option5 
}; 

new g_menu_Options[33]

@function(id)
{
     g_menu_options[id] |= Option3; 


[skatz_ws]

Right, made it!
Now I want to create a const to give "names" to that option in the menu, is this the right way?

PHP Code:

new const MenuOptions[][Options] = 
{
    "Option 1",
    "Option 2",
    "Option 3"
}; 


And in the menu, something like:

PHP Code:

static item[128];
for(new i = 0; i < sizeof Options; i++)
{
    formatex(item, sizeof(item) - 1, "%s%s", MenuOptions[i], Options:(1<<i) ? "\yON" : "\rOFF");
    menu_additem(menu, item, "");
} 


I think that's incorrect because I dont know much about bits and how to work with that enumeration but its just to explain what I want to make

[LearninG]

just a note :

sizeof(item) - 1

to

charsmax(item)

[skatz_ws]

Originally Posted by LearninG just a note : sizeof(item) - 1 to charsmax(item)

Can you explain me the difference? I want to learn

[EFFx]

The charsmax is a macro which contains the same thing you've used. Basically it's the same, but amxx already gives you a format to make it easier to write, so you can use it, its up to you.

[LearninG]

128 - 1

127

126 + 1

sizeof(item) - 1

charsmax(item)

all of them works same ( in your case ) , but as you can see "charsmax(item)" is less hardcoded choice , and hardcoding is never welcome.

[Bugsy]

Associating a selection with a string really only works when using an integer-sized enum since it's an identical association. 0 in the enum corresponds to index 0 in the string array, and so on. This is not as easily done using bit-fields. Technically this will work if you allowed only 1 Option selection per player, but when allowing multiple, this will not work without checking if each individual bit exists and adding the option name to the string.

Your enum:

Option1 = 1
Option2 = 2
Option3 = 4
Option4 = 8
Option5 = 16

PHP Code:

new const MenuOptions[ Options ][] = 


This will result in an array sized at [ 32 * string size ] while you would only use [ 5 * string size ], which is a waste of memory.

You would also need to define your Options names like this:

PHP Code:

new const MenuOptions[ Options ][] = 
{
    "",
    "Option 1",  // 1
    "Option 2",  // 2
    "",
    "Option 3",  // 4
    "",
    "",
    "",
    "Option 4",  // 8
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "Option 5",  // 16
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    "",
    ""
}; 


IMO, at your skill level you may be better off using an array of integers to store which option(s) a player has selected. I'm not saying what you want is not doable, but I'm not sure you will be able to do this yourself.

[Xalus]

You could do it in a different way:

PHP Code:

#define bit(%1) (1<<%1)

enum _:option_enum
{
    OPTION_1,
  OPTION_2,
  OPTION_3
}

new const option_list[option_enum][] =
{
  "Option 1",
  "Option 2",
  "Option 3"
}

new g_client_options[33]

// Check if player has the option
for(new i = 0; i < option_enum; i++)
{
  if( g_client_options[ client] & bit(i) )
  {
  
  }
}

// Add option to player
g_client_options[client] |= bit( Option_%i ) 


It's been a long time, so not sure "Option_1" can be actually "zero".
But you get the point.

[Bugsy]

I don't see a benefit in using bit-sums here, unless I am missing something. The only exception would be is if you did not need to associate an item with it's string name; in this case bitsums can save you a bit of coding. The below will be much easier to understand if you are just starting.

PHP Code:


#include <amxmodx>

enum Options
{
    Option1,
    Option2,
    Option3
}

new const OptionNames[ Options ][] =
{
    "Option 1",
    "Option 2",
    "Option 3"
};

new bool:g_bPlayerOptions[ MAX_PLAYERS ][ Options ];

public plugin_init()
{
    register_clcmd( "say addopt1" , "AddOpt1" );
    register_clcmd( "say addopt2" , "AddOpt2" );
    register_clcmd( "say addopt3" , "AddOpt3" );
    
    register_clcmd( "say delopt1" , "DelOpt1" );
    register_clcmd( "say delopt2" , "DelOpt2" );
    register_clcmd( "say delopt3" , "DelOpt3" );
    
    register_clcmd( "say options" , "ShowPlayerOptions" );
}

//The below 3 function's code can be inserted into your code directly, having functions for 1 line of code is overkill. These
//can also be accomplished using macros.
public AddOption( id , Options:oOption )
{
    g_bPlayerOptions[ id ][ oOption ] = true;
}

public RemoveOption( id , Options:oOption )
{
    g_bPlayerOptions[ id ][ oOption ] = false;
}

public bool:PlayerHasOption( id , Options:oOption )
{
    return g_bPlayerOptions[ id ][ oOption ];
}

public ShowPlayerOptions( id )
{
    new szOptions[ 48 ] , iPos;
    
    for ( new Options:oOpt = Option1 ; oOpt < Options ; oOpt++ )
    {
        if ( PlayerHasOption( id , oOpt ) == true )
        {
            iPos += formatex( szOptions[ iPos ] , charsmax( szOptions ) - iPos , "%s, " , OptionNames[ oOpt ] );
        }
    }
    
    if ( iPos == 0 )
        copy( szOptions , charsmax( szOptions ) , "(none)" );
    else    
        szOptions[ iPos - 2 ] = EOS;
    
    client_print( id , print_chat , "You have options: %s" , szOptions );
}

public AddOpt1(id) AddOption( id , Option1 );
public AddOpt2(id) AddOption( id , Option2 );
public AddOpt3(id) AddOption( id , Option3 );

public DelOpt1(id) RemoveOption( id , Option1 );
public DelOpt2(id) RemoveOption( id , Option2 );
public DelOpt3(id) RemoveOption( id , Option3 );