[Gasior]

public SaveData(id)
{ 
	new authid[32];
	get_user_authid(id, authid, 31);
	
	nvault_set( plik_vault , authid , Model_Name, bla  bbla, you knwo here .. )
}

public LoadModel(id)
{ 
    new authid[32] , GetModel[64] , iTs;
    get_user_authid(id, authid, 31);

    if( is_user_alive ( id ) && nvault_lookup( plik_vault, authid, GetModel, charsmax( GetModel ), iTs ) )
        cs_set_user_model( id, team = 0 , GetModel );
    
}

I am totally lost here, I try to make sense of it but my mind is shattered.

So I abandon SaveData & Load Data and whatever I nvault I had in there and replace it with above?

Couple of questions:
Where did you get "GetModel" from? Sorry but how am I supposed to use it an what is it?
So how are we going to save the nvault data in the above form?
Why does team equal to 0?

I'm sorry but I am totally lost .

Could someone perhaps fix it up or at least write comments next to the lines so I understand the whole process. I sit here for like an hour, trying to figure it all up but I think my brain gave up on me.

[Craxor]

Yes yes sorry, just a wait a minute.

new const Model_Name[] = "cstrike/models/players/vip.mdl";

public plugin_precache()
{
    precache_model( Model_Name);
}

public SaveData(id)
{
    // Here you take the user SteamID , correct ?  

    new authid[35];
    get_user_authid(id, authid, charsmax ( authid ) );

    //////////////////////////////


    //
        plik_vault - Here should be your nvault file Index ( that is how i found its name. )
        authid - is the KEY .
        Model_name - is the DATA of the KEY.

    //  
    nvault_set( plik_vault , authid , Model_Name )

    // About the Model_Name, just the Model_variable string wich you used to precache it, example in plugin_precache()
}

public LoadModel(id)
{ 
    //  Same process, we create variables ...  inside of GetModel we retrieve the data of the Key 
    // iTs variabile its the TimeStamp wich is a must to retrieve, even if you do not use it.

    new authid[35] , GetModel[64] , iTs;
    get_user_authid(id, authid, charsmax( authid ) );


    // We check here if the user is ALIVE and Also if the entry exists, nvault_lookup() return 0 if the entry is not founded.
    // in the same time we check bla bla and also we insert the data of the key (authid) inside of our variable ( GetModel ).

    if( is_user_alive ( id ) && nvault_lookup( plik_vault, authid, GetModel, charsmax( GetModel ), iTs ) )
        cs_set_user_model( id, team = 0 , GetModel );

    // about team = 0 is UNNASIGNED, you can just read cs_set_user_team native information ( open cstrike.inc ) and you will se.
    
    
}

Also, read what i wrote > https://forums.alliedmods.net/showthread.php?t=290692
Also, open nvault.inc and try to understand something not only by reading my code.

[Bugsy]

You are better off saving the model index number instead of the actual model name. I went through your code and fixed some things but I could not fully test because I do not have those models. I also assumed that you are not using nvault to store anything else in your plugin. If you are, you will need to make the key unique for the model index, as you have in your original code.

Please review the code and compare with your code to see what I changed so you can learn something from it.

Edit: This will take additional work to set the players model when he first connects because at client_authorized() his team is not yet assigned.
Edit2: Code updated to set model when a team is selected and also fixed an index out of bounds error. Untested.

Spoiler

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <engine> 
#include <nvault>

#pragma semicolon 1

#define MAX_PLAYERS    32
#define MENUITEM_DISABLED    (1<<26)

const NoModelSet = -1;

new const g_ModelFiles[][][] = 
{
    { "saperterro" , "ctsplinter" },
    { "oranget" , "camoct" },
    { "phoenixt" , "urbanos" },
    { "viptt" , "snowct" }
};


new const g_ModelNames[][] = 
{
    "Model 1",
    "Model 2",
    "Model 3",
    "Model 4"
};

new g_Model[ MAX_PLAYERS + 1 ];
new g_szAuthID[ MAX_PLAYERS + 1 ][ 34 ];
new CsTeams:g_csTeam[ MAX_PLAYERS + 1 ];
new plik_vault;

public plugin_init() 
{
    register_plugin( "Modele VIP" , "1.3" , "Gasior" );
    
    register_event( "ResetHUD" , "resetModel" , "b" );
    register_event( "TeamInfo" , "teamInfo" , "a" , "2=TERRORIST" , "2=CT" );
    
    register_clcmd( "say /modele" , "modelevip" );
    
    plik_vault = nvault_open( "g_Model" );
    
    if( plik_vault == INVALID_HANDLE )
        set_fail_state( "Nie moge otworzyc pliku :/" );
}

public plugin_precache() 
{
    new tempfile[ 128 ];
    
    for ( new iModelIndex = 0 ; iModelIndex < sizeof( g_ModelFiles ) ; iModelIndex++ ) 
    {
        formatex( tempfile , charsmax( tempfile ) , "models/player/%s/%s.mdl" , g_ModelFiles[ iModelIndex ][ 0 ] , g_ModelFiles[ iModelIndex ][ 0 ] );
        precache_model( tempfile );
        
        formatex( tempfile , charsmax( tempfile ) , "models/player/%s/%s.mdl" , g_ModelFiles[ iModelIndex ][ 1 ] , g_ModelFiles[ iModelIndex ][ 1 ] );
        precache_model( tempfile );
    }
}

public client_authorized( id ) 
{
    get_user_authid( id , g_szAuthID[ id ] , charsmax( g_szAuthID[] ) );
    
    g_Model[ id ] = NoModelSet;
    
    LoadData( id );
}

public teamInfo()
{
    new id = read_data( 1 );
    new szTeam[ 2 ];
    new CsTeams:csNewTeam;

    read_data( 2 , szTeam , charsmax( szTeam ) );
    
    csNewTeam = ( szTeam[ 0 ] == 'T' ) ? CS_TEAM_T : CS_TEAM_CT;

    if ( g_csTeam[ id ] != csNewTeam )
    {
        if ( g_Model[ id ] != NoModelSet )
        {
            resetModel( id );
        }
        
        g_csTeam[ id ] = csNewTeam;
    }    
}

public modelevip(id) 
{
    if ( ! ( get_user_flags( id ) & ADMIN_LEVEL_H ) )
        return PLUGIN_HANDLED;
    
    new menu = menu_create( "\yWybierz swoj VIP Model:", "menu_handler" );
    
    for ( new i = 0 , menuitem[ 64 ] ; i < sizeof( g_ModelFiles ) ; i++ ) 
    {
        formatex( menuitem , charsmax( menuitem ) , "\%c%s", g_Model[ id ] == i ? 'd' : 'w' , g_ModelNames[ i ] );
        menu_additem( menu , menuitem, _ , ( g_Model[ id ] == i ) ? MENUITEM_DISABLED : 0 );
    }
    
    menu_addblank(menu, 0);
    menu_additem(menu, "Pokaz Modele");
    menu_addblank(menu, 0);
    menu_addtext(menu, "Dziekujemy za bycie VIPem na FFA ProjektSpark.pl", 0);
    
    menu_display(id, menu);
    
    return PLUGIN_HANDLED;
}


public menu_handler( id , menu , item ) 
{
    if ( item == MENU_EXIT ) 
    {
        menu_destroy(menu);
        
        return PLUGIN_HANDLED;
    }

    if ( 0 <= item < sizeof( g_ModelFiles ) )
    {
        g_Model[ id ] = item;
        
        resetModel( id );
        SaveData( id );
    }
    else
    {
        show_motd( id , "modele.txt" , "Modele" );
    }
    
    return PLUGIN_CONTINUE;
}


public resetModel( id ) 
{
    new CsTeams:userTeam;
    
    if ( ( g_Model[ id ] != NoModelSet ) && ( CS_TEAM_T <= ( userTeam = cs_get_user_team( id ) ) <= CS_TEAM_CT ) )
        cs_set_user_model( id , g_ModelFiles[ g_Model[ id ] ][ _:userTeam - 1 ]);
    else
        cs_reset_user_model( id );
}


public SaveData(id)
{ 
    new szData[ 3 ];
    
    num_to_str( g_Model[ id ] , szData , charsmax( szData ) );
    nvault_set( plik_vault , g_szAuthID[ id ] , szData );
}


public LoadData(id) 
{ 
    new szData[ 3 ] , iTS;
    
    if ( nvault_lookup( plik_vault , g_szAuthID[ id ] , szData , charsmax( szData ) , iTS ) )
    {
        g_Model[ id ] = str_to_num( szData );
    }
} 


[Craxor]

honestly i didn't know models have an index ) sorry

[Bugsy]

Originally Posted by Craxor honestly i didn't know models have an index ) sorry

They don't, but when they are stored in an array they do.

PHP Code:

new g_ModelFiles[][][] = {
    {"saperterro", "ctsplinter"},  = 0
    {"oranget", "camoct"},   = 1
    {"phoenixt", "urbanos"},   = 2
    {"viptt", "snowct"}   = 3
};

new g_ModelNames[][] = {
    "Model 1",  = 0
    "Model 2",  = 1
    "Model 3",  = 2
    "Model 4"  = 3
}; 


[Craxor]

Originally Posted by Bugsy They don't, but when they are stored in an array they do.

AAaaa, sorry, didn't check the code.

Hope the author can understand

[Bugsy]

Originally Posted by Craxor AAaaa, sorry, didn't check the code. Hope the author can understand

Yea, I should have commented line by line. It required very little effort to make it work by storing the model index in the vault--he already had the logic in place to show the current model as disabled in the menu.

[Gasior]

Hi,

Tremendous thank you for you help, however the models do not set on the player.

When I choose the option from the menu nothing happens.

//
Edit

Actually models in CT team do not work but when I go to T team I have CT models. There's also a problem because once I picked a model of CT in T Team I change teams so T (with CT model) goes to CT (still have CT model) it doesn't change.

It also saves appropriately but works only after player has re spawned not the first original spawn after connection, which is totally fine with me.

[Bugsy]

Yes, I added a comment above. I didn't totally think it through since I went through the code quickly. It will take more work to set the model after the user chooses a team. In my code above, it attempts to set the model immediately upon connecting at which time the team is unassigned. It also does not account for team changes.

[Gasior]

What if on connection we would just read the data and then set it up on respawn? After respawn set up an index preventing a cycle. Would that fix the problem?