[mikasonwar]

Guys as you can probably figure out i'm pretty new to the sourcepawn and therefore i can't make a simple plugin properly. my idea was to make a plugin that would give a round start bonus to a certain flag "p" and as soon as i jump into the game with the plugin it says on the server console "client index 0 is not valid" Any idea how to fix this? and try to explain also , so next time i don't have to annoy you guys ^-^

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <cstrike>
#include <clients>

public Plugin:myinfo = 
{
    name = "Round bonus",
    author = "Mikasonwar",
    description = "<- Description ->",
    version = "0.1",
    url = ""
}

public OnPluginStart()
{
    HookEvent("round_start",RStartEvent);
}

public Action:RStartEvent(Handle:event,const String:name[],bool:dontBroadcast)
{
    new client_id = GetEventInt(event, "userid");
    new client = GetClientOfUserId(client_id);
    
    CreateTimer(0.2, GiveEquipment, client, TIMER_FLAG_NO_MAPCHANGE);
}

public Action:GiveEquipment(Handle:timer, any:client)
{
if (GetUserFlagBits(client) == ADMFLAG_CUSTOM2)
{
if(GetClientTeam(client)==3)
{
GivePlayerItem(client, "defuser");
}
CS_DropWeapon(client, 2, false, false);
GivePlayerItem(client, "weapon_hegrenade");
GivePlayerItem(client, "weapon_deagle");
GivePlayerItem(client, "item_assaultsuit");
GivePlayerItem(client, "weapon_smokegrenade");
GivePlayerItem(client, "weapon_molotov");
GivePlayerItem(client, "weapon_flashbang");
}

CloseHandle(timer);
} 


[Deathknife]

round_start does not have the flag "userid", it's global and not called once per player.
What you want to do, is either hook it on player spawn or on round start loop through all players.
Something like this:

PHP Code:

for(int i=1; i<= MaxClients; i++) {
    if(IsClientInGame(i) && IsPlayerAlive(i)) {
        CreateTimer(0.2, GiveEquipment, i, TIMER_FLAG_NO_MAPCHANGE);
    }
} 


Also, on the timer event it would be a good idea to check if player is still connected & alive.

[mikasonwar]

hmm for they to actually start the round don't they already need to be connected + alive?

[Deathknife]

Originally Posted by mikasonwar hmm for they to actually start the round don't they already need to be connected + alive?

The round start is not when players start the round, but when a new round begins on the server. The loop I included looped through possible client's indexes.

PHP Code:

for(int i=1;i<=MaxClients; i++) {
//
} 


This doesn't loop through clients, but through "indexes". Thus, we have to ensure the client is in game, for example by

PHP Code:

if(IsClientInGame(i)) 


But the client could also be in spectator, so he would be dead. And can't really give guns to dead people. So we use

PHP Code:

if(IsPlayerAlive(i)) 


[mikasonwar]

hmm it seems it still gives me an error something regarding the giveequipment + the timer...

[mikasonwar]

gives me This errors.

[ESK0]

Not tested.

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <cstrike>

#define LoopAliveClients(%1) for(int %1 = 1;%1 <= MaxClients;%1++) if(IsValidClient(%1, true))

public Plugin myinfo =
{
	name = "VIPReward",
	author = "ESK0",
	description = "VIPRewards",
	version = "1.0",
	url = "www.github.com/esk0"
};
public void OnPluginStart()
{
	HookEvent("round_start", Event_OnRoundStart);
}
public Action Event_OnRoundStart(Handle event, char[] name, bool dontBroadcast)
{
	LoopAliveClients(i)
	{
		if(IsClientVIP(i))
		{
			CreateTimer(2.0, Timer_VIPPlayerReward, i, TIMER_FLAG_NO_MAPCHANGE);
		}
	}
}
public Action Timer_VIPPlayerReward(Handle timer, client)
{
	if(IsValidClient(client, true))
	{
		if(GetClientTeam(client) == CS_TEAM_CT)
		{
			GivePlayerItem(client, "defuser");
		}
		CS_DropWeapon(client, 2, false, false);
		GivePlayerItem(client, "weapon_hegrenade");
		GivePlayerItem(client, "weapon_deagle");
		GivePlayerItem(client, "item_assaultsuit");
		GivePlayerItem(client, "weapon_smokegrenade");
		GivePlayerItem(client, "weapon_molotov");
		GivePlayerItem(client, "weapon_flashbang");
	}
}
stock bool IsClientVIP(int client)
{
  if (GetAdminFlag(GetUserAdmin(client), Admin_Custom2))
  {
    return true;
  }
  return false;
}
stock bool IsValidClient(int client,bool alive = false)
{
  if(0 < client && client <= MaxClients && IsClientInGame(client) && (alive == false || IsPlayerAlive(client)))
  {
    return true;
  }
  return false;
}

[Powerlord]

You might be better off hooking the player_spawn event.

[mikasonwar]

Thank you ESK0! i've been trying to understand your code so i learn more of soucemod (i'm a total noob at the time of being.)

Can i publish this plugin after i mess around with it? ^-^

[ESK0]

Originally Posted by mikasonwar Thank you ESK0! i've been trying to understand your code so i learn more of soucemod (i'm a total noob at the time of being.) Can i publish this plugin after i mess around with it? ^-^

Of course you can )