[Otokiru]

Hi, need help with coding on how to check the number of alive players on a particular team.
E.g

If GetAlivePlayers on blueTeam == 1 {
do something;
}

[Patrick Star]

Not quite sure either but this might help , it counts the number of people in a certain team:
GetTeamClientCount
Get the id's of all the people in that certain team and then
IsPlayerAlive


Good luck and hope I helped.

Edit : Well - I can see that your server is Saxton and by that I think you are trying to see if the Saxton is still alive. that could make the job much easier. I bet that in saxton there is already a name for it and therefore all you have to do is
if (IsPlayerAlive(NAMEOFSAXTON))
{

// code

}

[Otokiru]

Originally Posted by Patrick Star Not quite sure either but this might help , it counts the number of people in a certain team: GetTeamClientCount Get the id's of all the people in that certain team and then IsPlayerAlive Good luck and hope I helped. Edit : Well - I can see that your server is Saxton and by that I think you are trying to see if the Saxton is still alive. that could make the job much easier. I bet that in saxton there is already a name for it and therefore all you have to do is if (IsPlayerAlive(NAMEOFSAXTON)) { // code }

Thx but I'm adding bullets particles trails for the hale. My code works well but one of the issue is that one of the hale can re-spawn deadplayers onto the haleteam and whoever spawn in the haleteam also has the bullet particles trails which is not meant to be like that.

I manage to fix it by using the GetTeamClientCount. If GetTeamClientCount(BossTeam)==1 then attach the particle. It works too, but then, if a new player join the server, he will be switched to the blueTeam temporarily until the next roundstart which will make the GetTeamClientCount to 2 and won't attach the particles to the hale.... GAHHH!~

[Leonardo]

Originally Posted by Otokiru If GetAlivePlayers on blueTeam == 1 { do something; }

add this in .sp

stock GetTeamAliveCount( iTeamNum )
{
    new iCount;
    for( new iClient = 1; iClient <= MaxClients; iClient++ )
        if( IsClientInGame( iClient ) && GetClientTeam( iClient ) == iTeamNum && IsPlayerAlive( iClient ) )
            iCount++;
    return iCount;
}

[Powerlord]

btw, don't assume hale's team is always BLU. Always use the FF2_GetBossTeam native.

Better yet, use the FF2_OnSpecialSelected callback to set the bullet particles in the first place:

PHP Code:

public Action:FF2_OnSpecialSelected( index, &SpecialNum, String:SpecialName[])
{
    // You may need to do a timer here

    // If you need a player client/entity, use this:
    new client = GetClientOfUserId(FF2_GetBossUserId(index));
    // If you just need a userid, use this instead
    new userid = FF2_GetBossUserId(index);
    // code to set particles here
} 


Edit: This is apparently a pre-event, you may need a timer so the client entity is spawned first.

[claudiuhks]

Originally Posted by Leonardo add this in .sp stock GetTeamAliveCount( iTeamNum ) { new iCount; for( new iClient = 0; iClient < MaxClients; iClient++ ) if( IsClientInGame( iClient ) && GetClientTeam( iClient ) == iTeamNum && IsPlayerAlive( iClient ) ) iCount++; return iCount; }

No. You should start checking client one, not zero. Client may be equal with MaxClients. Stock is not required because this function will be definetly used in plugin. Use decl instead of new.

PHP Code:

GetAlivePlayersCount( iTeam )
{
  decl iCount, i; iCount = 0;

  for( i = 1; i <= MaxClients; i++ )
    if( IsClientInGame( i ) && IsPlayerAlive( i ) && GetClientTeam( i ) == iTeam )
      iCount++;

  return iCount;
} 


[Cookies.net]

Originally Posted by claudiuhks No. You should start checking client one, not zero. Client may be equal with MaxClients. Stock is not required because this function will be definetly used in plugin. Use decl instead of new. PHP Code: GetAlivePlayersCount( iTeam ) {   decl iCount, i; iCount = 0;   for( i = 1; i <= MaxClients; i++ )     if( IsClientInGame( i ) && IsPlayerAlive( i ) && GetClientTeam( i ) == iTeam )       iCount++;   return iCount; }

Absolutely no reason to use "decl" instead of "new" in this case, read: http://wiki.alliedmods.net/Introduct...n#Golden_Rules

[Dr. McKay]

Originally Posted by Cookies.net Absolutely no reason to use "decl" instead of "new" in this case, read: http://wiki.alliedmods.net/Introduct...n#Golden_Rules

Yeah. As a rule of thumb, I only really decl Strings, since you have to fill them with a function of some kind anyway.

[Otokiru]

Ok thanks all. Got it.