[abdobiskra]

Hi!
My idea is to make score team shows in Game Description
I tried

PHP Code:


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_forward(FM_GetGameDescription    , "fwd_GetGameDescription");
}

public fwd_GetGameDescription()
{ 
    forward_return(FMV_STRING, "blue %d|%d red", ScoreBlue, ScoreRed);
    server_print("===========^n%d ^n %d^n===========", ScoreBlue, ScoreRed);
    return FMRES_SUPERCEDE;
} 


But I did not get it i see like that : ( blue %d|%d red)
without value scores
i try dubug using server_print it succeeded with me and i get the value

=========== -1 0 =========== =========== -1 0 ===========

What is the Problem in that?

[PRoSToTeM@]

forward_return(FMV_STRING, fmt("blue %d|%d red", ScoreBlue, ScoreRed));

[abdobiskra]

Originally Posted by PRoSToTeM@ forward_return(FMV_STRING, fmt("blue %d|%d red", ScoreBlue, ScoreRed));

thx for rply
error compile ? this ==> (fmt)
did you mean format ? (i test it also error argument)

[klippy]

fmt is only available in 1.8.3-dev. If you are using 1.8.2 then you will have to format your string with formatex.

Anyway it's cool to see that someone is actually aware of fmt and is using it.

[abdobiskra]

Originally Posted by KliPPy fmt is only available in 1.8.3-dev. If you are using 1.8.2 then you will have to format your string with formatex. Anyway it's cool to see that someone is actually aware of fmt and is using it.

Yes thx bro))

[PRoSToTeM@]

You can use it in 1.8.2:

PHP Code:

#include <amxmodx>

#if !defined MAX_FMT_LENGTH
const MAX_FMT_LENGTH = 256;

stock fmt(const format[], any:...)
{
    static formatted[MAX_FMT_LENGTH];
    vformat(formatted, charsmax(formatted), format, 2);
    // We can't use code without emitting opcodes because the compiler can't find hidden return argument correctly in variadic functions (the compiler generates code like for fmt(a, b) function)
#emit LOAD.S.PRI 0x8 // Get size of arguments (count of arguments multiply by sizeof(cell))
#emit ADDR.ALT 0xC // This is the pointer to first argument
#emit ADD // Now in PRI we have the pointer to hidden return argument
#emit LOAD.I // Now in PRI we have the pointer to return buffer
#emit MOVE.ALT
#emit CONST.PRI formatted
    const MAX_FMT_LENGTH_X4 = MAX_FMT_LENGTH * 4;
#emit MOVS MAX_FMT_LENGTH_X4 // Copy from formatted buffer to return buffer
#emit RETN // Don't execute the code for copy return generated by compiler
    return formatted;
}
#endif

public plugin_init()
{
    server_print("%s", fmt("%s %d %f", fmt("%d", 55), 55, 55.0));
} 


And also the optimized version:

PHP Code:

#include <amxmodx>

#if !defined MAX_FMT_LENGTH
const MAX_FMT_LENGTH = 256;

#if !defined __vformat_allower
#define __vformat_allower __vformat_allower_
__vformat_allower_()
{
    vformat("", 0, "", 0);
}
#endif

stock fmt(const format[], any:...)
{
    static formatted[MAX_FMT_LENGTH];
#emit PUSH.C 0x2
#emit PUSH.S format
    const FORMATTED_CHARSMAX = charsmax(formatted);
#emit PUSH.C FORMATTED_CHARSMAX
#emit LOAD.S.PRI 0x8 // Get size of arguments (count of arguments multiply by sizeof(cell))
#emit ADDR.ALT 0xC // This is the pointer to first argument
#emit ADD // Now in PRI we have the pointer to hidden return argument
#emit LOAD.I // Now in PRI we have the pointer to return buffer
#emit PUSH.PRI
#emit PUSH.C 0x10
#emit SYSREQ.C vformat
#emit STACK 0x14
#emit RETN // Don't execute the code for copy return generated by compiler
    __vformat_allower();
    return formatted;
}
#endif

public plugin_init()
{
    server_print("%s", fmt("%s %d %f", fmt("%d", 55), 55, 55.0));
} 


[OciXCrom]

So, that's basically returning a string instead of passing it by ref? The thing that approvers say is "stupid". Are all of those #emit things needed? What could go wrong without them? It's a simple stock that uses vformat and returns the string, nothing else.

[PRoSToTeM@]

Originally Posted by OciXCrom So, that's basically returning a string instead of passing it by ref?

The main purpose of fmt is inlining string formatting in function calls like:

PHP Code:

forward_return(FMV_STRING, fmt("blue %d|%d red", ScoreBlue, ScoreRed)); 


Originally Posted by OciXCrom Are all of those #emit things needed? What could go wrong without them?

There is a problem with variadic functions, you can read about it in my code comments.