[Resuelto] Votacion bunny hop

Sinaloense · **Author**

Hola me encontre este plugin que es para que cuando escribes /jumpmenu sale un menu para escojer activarte o desactivarte el bunny, lo que yo quiero es que cuando empiese cada ronda salga una votacion sobre si quieren bunny o no pero no e podido >.< espero me puedan ayudar.

PHP Code:


			
#include <amxmodx>
#include <engine>

#define PLUGIN    "Jump Menu Modified"
#define VERSION "2.1b"
#define AUTHOR    "v3x"

#define MAX_PLAYERS    33

public plugin_init() 
{
    register_plugin(PLUGIN , VERSION , AUTHOR);

    register_clcmd("say /jumpmenu"    , "ClCmd_JumpMenu");
    register_clcmd("jumpmenu"    , "ClCmd_JumpMenu");
}

enum 
{
    JUMP_REGULAR = 0,
    JUMP_BUNNY,
}

new g_iJumpType[33];

public client_putinserver(id) 
    g_iJumpType[id] = JUMP_REGULAR;

public client_disconnect(id) 
    g_iJumpType[id] = JUMP_REGULAR;

public ClCmd_JumpMenu(id) 
{
    new menu = menu_create("Select your jump type:" , "menuHandler_Jump");

    menu_additem(menu , "Bunnyhop"        , "" , 0);
    menu_additem(menu , "Regular"        , "" , 0);

    menu_setprop(menu , MPROP_EXIT , MEXIT_ALL);
    
    menu_display(id , menu , 0);

    new arg[21];
    read_argv(0 , arg , 20);
    if(!contain(arg , "say"))
        return PLUGIN_CONTINUE;

    return PLUGIN_HANDLED;
}

public menuHandler_Jump(id , menu , item) 
{
    if(item == MENU_EXIT) 
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new szCommand[6] , szName[64];
    new access , callback;
    
    menu_item_getinfo(menu , item , access , szCommand , 5 , szName , 63 , callback);
    
    if(equal(szName , "Bunnyhop")) 
    {
        client_print(id , print_chat , "[AMXX] Bunnyhop enabled");
        g_iJumpType[id] = JUMP_BUNNY;

        menu_destroy(menu); return PLUGIN_CONTINUE;
    }
    else 
    {
        client_print(id , print_chat , "[AMXX] Regular jumping enabled");
        g_iJumpType[id] = JUMP_REGULAR;

        menu_destroy(menu); return PLUGIN_CONTINUE;
    }
    
    menu_destroy(menu);
    
    return PLUGIN_HANDLED;
}

public client_PreThink(id) 
{
    if(!is_user_alive(id) || !g_iJumpType[id])
        return PLUGIN_CONTINUE;

    entity_set_float(id, EV_FL_fuser2, 0.0)     // Disable slow down after jumping

    // Code from CBasePlayer::Jump (player.cpp)     Make a player jump automatically
    if (entity_get_int(id, EV_INT_button) & 2) {    // If holding jump
        new flags = entity_get_int(id, EV_INT_flags)

        if (flags & FL_WATERJUMP)
            return PLUGIN_CONTINUE
        if ( entity_get_int(id, EV_INT_waterlevel) >= 2 )
            return PLUGIN_CONTINUE
        if ( !(flags & FL_ONGROUND) )
            return PLUGIN_CONTINUE

        new Float:velocity[3]
        entity_get_vector(id, EV_VEC_velocity, velocity)
        velocity[2] += 250.0
        entity_set_vector(id, EV_VEC_velocity, velocity)

        entity_set_int(id, EV_INT_gaitsequence, 6)    // Play the Jump Animation
    }

    return PLUGIN_CONTINUE;
}

MexPower · *Last edited by MexPower; 07-23-2013 at 20:50.*

Pruebalo

PHP Code:


			
#include <amxmodx>
#include <engine>

#define maxplayers 32

#define    FL_WATERJUMP    (1<<11)    // player jumping out of water
#define    FL_ONGROUND    (1<<9)    // At rest / on the ground

new vote_yes, vote_no, votes
new g_bunny

public plugin_init() 
{
    register_plugin("Super Bunny Hopper", "1.2", "Cheesy Peteza")
    
    register_cvar("sbhopper_version", "1.2", FCVAR_SERVER)
    register_event("HLTV", "event_new_round", "a", "1=0", "2=0") 
}

public show_menu2(id)
{
    new menu = menu_create("Votaciones, desea que se active bunnyhoop esta ronda","handler"), len[10]
    
    formatex(len, charsmax(len), "Si (%d)", vote_yes)
    menu_additem(menu, len, "0")
    
    formatex(len, charsmax(len), "No (%d)", vote_no)
    menu_additem(menu, len, "1")
    
    menu_display(id, menu, 0)
}
public handler(id, menu, item)
{
    if(!item) vote_yes++
    else vote_no++
        
    votes++
}
public event_new_round()
{
    vote_yes = vote_no = votes = 0
    g_bunny = false
    
    for(new i = 1; i <= maxplayers; i++)
    {
        if(is_user_connected(i))
        show_menu2(i)
    }
        
    
    set_task(15.0, "check_votes")
}

public check_votes()
{
    if(vote_yes >= vote_no) g_bunny = true
    else g_bunny = false
    
    client_print(0, print_chat, "Votacion terminada, A favor: %d/%d, en contra: %d/%d. Bunnyhoop: %sctivado", vote_yes, votes, vote_no, votes, g_bunny ? "A" : "Desa")
}
public client_PreThink(id) 
{
    if(!g_bunny)
        return PLUGIN_CONTINUE;
        
    entity_set_float(id, EV_FL_fuser2, 0.0)        // Disable slow down after jumping

// Code from CBasePlayer::Jump (player.cpp)        Make a player jump automatically
    if (entity_get_int(id, EV_INT_button) & 2) {    // If holding jump
        new flags = entity_get_int(id, EV_INT_flags)

        if (flags & FL_WATERJUMP)
            return PLUGIN_CONTINUE
        if ( entity_get_int(id, EV_INT_waterlevel) >= 2 )
            return PLUGIN_CONTINUE
        if ( !(flags & FL_ONGROUND) )
            return PLUGIN_CONTINUE

        new Float:velocity[3]
        entity_get_vector(id, EV_VEC_velocity, velocity)
        velocity[2] += 250.0
        entity_set_vector(id, EV_VEC_velocity, velocity)

        entity_set_int(id, EV_INT_gaitsequence, 6)    // Play the Jump Animation
    }
    return PLUGIN_CONTINUE  
}

Fix

Sinaloense · 07-23-2013 , 22:08 Re: [Ayuda] Votacion bunny hop

Gracias por segunda ves MexPower me sacaste de otro apuro x.x