[hadesownage]

Hello! I have an deathmatch server and Kills feed is too long (to much kills) and i want to show only my kills/deaths.
I tired like that, but is hiding all kills.

PHP Code:

#pragma semicolon 1

// ====[ INCLUDES ]============================================================
#include <sourcemod>

// ====[ DEFINES ]=============================================================
#define    PLUGIN_VERSION            "1.3"


public Plugin:myinfo =
{
    name = "Hide Kill Feed",
    author = "ReFlexPoison",
    description = "Disables advertisements of bot deaths and/or kills in the kill feed",
    version = PLUGIN_VERSION,
    url = "http://forums.alliedmods.net/showthread.php?p=1684156"
}

public OnPluginStart()
{
    HookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
}



public Action:OnPlayerDeath(Handle:hEvent, const String:strName[], bool:bBroadcast)
{
    
        new iVictim = GetClientOfUserId(GetEventInt(hEvent, "userid"));
        new iAttacker = GetClientOfUserId(GetEventInt(hEvent, "attacker"));
        
        if(IsValidClient(iVictim) && IsValidClient(iAttacker) ) {
        
                for (new i = 1; i <= MaxClients; i++)
                {
                    if ( !IsValidClient ( i ) || IsFakeClient( i ) || iVictim == i || iAttacker == i )
                        continue;
                        
                    SetEventBroadcast(hEvent, true);
                        
                }
            
                
        }

        return Plugin_Continue;
}

stock IsValidClient ( client ) {

    if ( !( 1 <= client <= MaxClients ) || !IsClientInGame ( client ) )
        return false;

    return true;
} 


Thank you!

[Mitchell]

I don't think you can create events specifically for certain clients and send them it. meaning that you can't fake a death message, all you can do is block it.

[cristian20042]

Originally Posted by hadesownage Hello! I have an deathmatch server and Kills feed is too long (to much kills) and i want to show only my kills/deaths. I tired like that, but is hiding all kills. PHP Code: #pragma semicolon 1 // ====[ INCLUDES ]============================================================ #include <sourcemod> // ====[ DEFINES ]============================================================= #define    PLUGIN_VERSION            "1.3" public Plugin:myinfo = {     name = "Hide Kill Feed",     author = "ReFlexPoison",     description = "Disables advertisements of bot deaths and/or kills in the kill feed",     version = PLUGIN_VERSION,     url = "http://forums.alliedmods.net/showthread.php?p=1684156" } public OnPluginStart() {     HookEvent("player_death", OnPlayerDeath, EventHookMode_Pre); } public Action:OnPlayerDeath(Handle:hEvent, const String:strName[], bool:bBroadcast) {              new iVictim = GetClientOfUserId(GetEventInt(hEvent, "userid"));         new iAttacker = GetClientOfUserId(GetEventInt(hEvent, "attacker"));                  if(IsValidClient(iVictim) && IsValidClient(iAttacker) ) {                          for (new i = 1; i <= MaxClients; i++)                 {                     if ( !IsValidClient ( i ) || IsFakeClient( i ) || iVictim == i || iAttacker == i )                         continue;                                              SetEventBroadcast(hEvent, true);                                          }                                       }         return Plugin_Continue; } stock IsValidClient ( client ) {     if ( !( 1 <= client <= MaxClients ) || !IsClientInGame ( client ) )         return false;     return true; }  Thank you!

+1 Mitchell si salut hades ! (Sunt SniperHero)
Si uite-te aici :
https://wiki.alliedmods.net/Events_(SourceMod_Scripting)

[Maxximou5]

Originally Posted by Mitchell I don't think you can create events specifically for certain clients and send them it. meaning that you can't fake a death message, all you can do is block it.

You may be right.

If OP wants to test it, I think this is what he wants.
Set your steamid (STEAM_1:0:00000) with sm_hidekillfeed_id

Spoiler

PHP Code:

// ====[ INCLUDES ]============================================================
#include <sourcemod>

// ====[ DEFINES ]=============================================================
#define PLUGIN_VERSION  "1.3.1"

// ====[ VARIABLES ]=============================================================
ConVar g_hCvar_Hide_ID;

char g_sHide_ID[32];

public Plugin myinfo =
{
    name = "Hide Kill Feed",
    author = "ReFlexPoison",
    description = "Disables advertisements of bot deaths and/or kills in the kill feed",
    version = PLUGIN_VERSION,
    url = "http://forums.alliedmods.net/showthread.php?p=1684156"
}

public void OnPluginStart()
{
    g_hCvar_Hide_ID = CreateConVar("sm_hidekillfeed_id", "STEAM_1:0:000000", "Display kill feed for this STEAMID only.");
    GetConVarString(g_hCvar_Hide_ID, g_sHide_ID, sizeof(g_sHide_ID));
    HookEvent("player_death", OnPlayerDeath, EventHookMode_Pre);
}

public Action OnPlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    GetConVarString(g_hCvar_Hide_ID, g_sHide_ID, sizeof(g_sHide_ID));
    int iVictim = GetClientOfUserId(GetEventInt(event, "userid"));
    int iAttacker = GetClientOfUserId(GetEventInt(event, "attacker"));

    char steamIDa[32], steamIDv[32];
    GetClientAuthId(iAttacker, AuthId_Steam2, steamIDa, sizeof(steamIDa));
    GetClientAuthId(iVictim, AuthId_Steam2, steamIDv, sizeof(steamIDv));

    if (IsValidClient(iVictim) && IsValidClient(iAttacker) && (StrEqual(steamIDa, g_sHide_ID) || StrEqual(steamIDv, g_sHide_ID)))
    {
        return Plugin_Continue;
    }
    else
    {
        SetEventBroadcast(event, true);
    }

    return Plugin_Continue;
}

stock bool IsValidClient(int client)
{
    if (!(0 < client <= MaxClients)) return false;
    if (!IsClientConnected(client)) return false;
    if (!IsClientInGame(client)) return false;
    return true;
} 


[hadesownage]

@Maxximou5 Is not working. I put my steamid and nothing appears.

[Maxximou5]

Originally Posted by hadesownage @Maxximou5 Is not working. I put my steamid and nothing appears.

My bad, I made a very silly mistake. I just tested it and it does actually work for me testing against bots.
It's set so you will only see that person's (steamid) kills and deaths. If you don't want deaths to be shown you can edit out the StrEqual(steamIDv, g_sHide_ID)

[Benoist3012]

Originally Posted by Mitchell I don't think you can create events specifically for certain clients and send them it. meaning that you can't fake a death message, all you can do is block it.

You can.

To answer the op, just move your code to new syntax(or you won't be able to do my soluce), set dont broadcast on true, copy the event over a new one, and fire it to the desired client using FireToClient func.

[R3TROATTACK]

Well Benoist gave you the answer before I could, but here is some code that should do what you want

PHP Code:

#pragma semicolon 1

#define DEBUG

#define PLUGIN_AUTHOR "R3TROATTACK"
#define PLUGIN_VERSION "1.00"

#include <sourcemod>

#pragma newdecls required

public Plugin myinfo = 
{
    name = "Death Broadcast",
    author = PLUGIN_AUTHOR,
    description = "Displays kill feed to only the victim and attacker",
    version = PLUGIN_VERSION,
    url = "http://steamcommunity.com/id/R3TROATTACK/"
};

public void OnPluginStart()
{    
    HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre);
}

public void Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int victim = GetClientOfUserId(event.GetInt("userid"));
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    char sWeapon[128];
    event.GetString("weapon", sWeapon, 128);
    bool headshot = event.GetBool("headshot");
    
    CreateDeathEvent(victim, attacker, sWeapon, headshot);
    
    SetEventBroadcast(event, true);
}

public void CreateDeathEvent(int victim, int attacker, char[] sWeapon, bool headshot)
{
    Event event = CreateEvent("player_death");
    event.SetInt("userid", victim);
    event.SetInt("attacker", attacker);
    event.SetString("weapon", sWeapon);
    event.SetBool("headshot", headshot);
    
    if(IsValidClient(victim))
        event.FireToClient(victim);
    if(IsValidClient(attacker) && victim != attacker)
        event.FireToClient(attacker);
}

stock bool IsValidClient(int client)
{
    if(client <= 0 || client > MaxClients)
        return false;
        
    if(!IsClientInGame(client) || !IsClientConnected(client) || IsFakeClient(client))
        return false;
        
    return true;
} 


[hadesownage]

It works how I said, but is a problem. Names doesn't shows.



Same on death/kill.

Solution:

PHP Code:

event.SetInt("userid", GetClientUserId(victim));
event.SetInt("attacker", GetClientUserId(attacker)); 


[Mitchell]

I had no idea the Event had FireToClient, pretty neat.

PHP Code:


#pragma semicolon 1

#define DEBUG

#define PLUGIN_AUTHOR "R3TROATTACK"
#define PLUGIN_VERSION "1.00"

#include <sourcemod>

#pragma newdecls required

public Plugin myinfo = 
{
    name = "Death Broadcast",
    author = PLUGIN_AUTHOR,
    description = "Displays kill feed to only the victim and attacker",
    version = PLUGIN_VERSION,
    url = "http://steamcommunity.com/id/R3TROATTACK/"
};

public void OnPluginStart()
{    
    HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre);
}

public void Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int victim = GetClientOfUserId(event.GetInt("userid"));
    int attacker = GetClientOfUserId(event.GetInt("attacker"));
    char sWeapon[128];
    event.GetString("weapon", sWeapon, 128);
    bool headshot = event.GetBool("headshot");
    
    CreateDeathEvent(victim, attacker, sWeapon, headshot);
    
    SetEventBroadcast(event, true);
}

public void CreateDeathEvent(int victim, int attacker, char[] sWeapon, bool headshot)
{
    Event event = CreateEvent("player_death");
    event.SetInt("userid", victim);
    event.SetInt("attacker", attacker);
    event.SetString("weapon", sWeapon);
    event.SetBool("headshot", headshot);
    
    if(IsValidClient(victim))
        event.FireToClient(GetClientUserId(victim));
    if(IsValidClient(attacker) && victim != attacker)
        event.FireToClient(GetClientUserId(attacker));
}

stock bool IsValidClient(int client)
{
    if(client <= 0 || client > MaxClients)
        return false;
        
    if(!IsClientInGame(client) || !IsClientConnected(client) || IsFakeClient(client))
        return false;
        
    return true;
} 


You need to convert the attacker and client to UserId's again when you send the event.