[Emp`]

Originally Posted by fysiks PHP Code: stock get_random_player() {     new iPlayers[32], iPlayersNum     get_players(iPlayers, iPlayersNum)     return iPlayers[ iPlayersNum ? random( iPlayersNum ) : 0 ] }

ftfy

[meTaLiCroSS]

Originally Posted by Emp` ftfy

PHP Code:

stock get_random_player() 
{ 
    new iPlayers[32], iPlayersNum 
    get_players(iPlayers, iPlayersNum) 
    return iPlayersNum ? iPlayers[ random( iPlayersNum ) ] : 0
} 


[edon1337]

Originally Posted by meTaLiCroSS PHP Code: stock get_random_player()  {      new iPlayers[32], iPlayersNum     get_players(iPlayers, iPlayersNum)     return iPlayersNum ? iPlayers[ random( iPlayersNum ) ] : 0 }

PHP Code:

stock get_random_player() 
{ 
    new iPlayers[32], iPlayersNum;
    get_players(iPlayers, iPlayersNum);
    return iPlayersNum ? iPlayers[ random( iPlayersNum ) ] : 0;
} 


[happy_2012]

Maybe I can use that feature for a later update, thank you.

[Craxor]

Btw )

PHP Code:

stock get_random_alive_player()  
{  
    new iPlayers[32], iPlayersNum; 
    get_players(iPlayers, iPlayersNum, "a");
 
    return iPlayersNum ? iPlayers[ random( iPlayersNum ) ] : 0; 
} 


[PRoSToTeM@]

Hack hack hack:

PHP Code:

#include <amxmodx>
#include <amxmisc>

#if !defined MAX_PLAYERS
const MAX_PLAYERS = 32;
#endif

#define ForEachPlayer(%1,%2,%3) do {\
    for (new %1 = 1; %1 <= MAX_PLAYERS; %1++) {\
        if (%2) {\
            %3;\
        }\
    }\
} while (is_linux_server() == 0xDEADBEEF)

public plugin_init() {
    register_clcmd("say /dd", "DD");
}

public DD() {
    ForEachPlayer(x, is_user_alive(x) && is_user_admin(x), client_print(x, print_chat, "!!!"));
} 


PHP Code:

ForEachPlayer(x, is_user_alive(x) && is_user_admin(x), client_print(x, print_chat, "!!!"), give_item(x, "weapon_ak47")); 


[Freezo Begin]

Originally Posted by PRoSToTeM@ Hack hack hack: PHP Code: #include <amxmodx> #include <amxmisc> #if !defined MAX_PLAYERS const MAX_PLAYERS = 32; #endif #define ForEachPlayer(%1,%2,%3) do {\     for (new %1 = 1; %1 <= MAX_PLAYERS; %1++) {\         if (%2) {\             %3;\         }\     }\ } while (is_linux_server() == 0xDEADBEEF) public plugin_init() {     register_clcmd("say /dd", "DD"); } public DD() {     ForEachPlayer(x, is_user_alive(x) && is_user_admin(x), client_print(x, print_chat, "!!!")); }  PHP Code: ForEachPlayer(x, is_user_alive(x) && is_user_admin(x), client_print(x, print_chat, "!!!"), give_item(x, "weapon_ak47"));

wait wait wait, what is this for :

 while (is_linux_server() == 0xDEADBEEF)

[PRoSToTeM@]

Originally Posted by Freezo Begin wait wait wait, what is this for : while (is_linux_server() == 0xDEADBEEF)

This is guaranted loop break without compiler warnings. (but not compile-time...)

[klippy]

Why did you need that in the first place?

[PRoSToTeM@]

Wow, this works too:

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>

#pragma tabsize 0 // I can't win loose indentation in macro...

#if !defined MAX_PLAYERS
const MAX_PLAYERS = 32;
#endif

#define ForEachPlayer(%1,%2,%3) do {\
    for (new %1 = 1; %1 <= MAX_PLAYERS; %1++) {\
        if (%2) {\
            %3;\
        }\
    }\
} while (is_linux_server() == 0xDEADBEEF)

#define GetPlayers(%0,%1,%2,%3) do {\
    %1 = 0;\
    for (new %2 = 1; %2 <= MAX_PLAYERS; %2++) {\
        if (%3) {\
            %0[%1++] = %2;\
        }\
    }\
} while (is_linux_server() == 0xDEADBEEF)

#define GetRandomPlayers(%0,%1,%2,%3) do {\
    static _plrs[MAX_PLAYERS];\
    new _plrCount;\
    GetPlayers(_plrs, _plrCount, %2, %3);\
    \
    %1 = min(%1, _plrCount);\
    for (new _i = 0; _i < %1; _i++) {\
        new _rnd = random_num(0, _plrCount - 1);\
        \
        %0[_i] = _plrs[_rnd];\
        _plrs[_rnd] = _plrs[_plrCount - 1];\
        \
        _plrCount--;\
    }\
} while (is_linux_server() == 0xDEADBEEF)

#define GetRandomPlayer(%0,%1,%2) do {\
    static _players[MAX_PLAYERS];\
    new _playerCount;\
    GetPlayers(_players, _playerCount, %1, %2);\
    %0 = _playerCount ? _players[random_num(0, _playerCount - 1)] : 0;\
} while (is_linux_server() == 0xDEADBEEF)

public plugin_init() {
    register_clcmd("say /dd", "DD");
} 


PHP Code:

public DD() {
    ForEachPlayer(x, is_user_alive(x) && is_user_admin(x), client_print(x, print_chat, "!!!"), give_item(x, "weapon_ak47"));
    
    new players[2], count = sizeof(players);
    GetRandomPlayers(players, count, x, is_user_connected(x) && is_user_admin(x));
    
    new player;
    GetRandomPlayer(player, x, is_user_alive(x) && is_user_admin(x));
    client_print(0, print_chat, "%d", player);
} 


Originally Posted by KliPPy Why did you need that in the first place?

What do you mean?