[zipcore]

It's been a long time since my last contribution to this forum section or at all
So what do I have here to share with you today?
It's an example code of something I've used in many ways for different private plugins already.



The snipped shows you how to use custom icons inside the killfeed. The attached example plugin adds an icon for deaths caused by fall damage, but you can use it for many other things too.

PHP Code:

stock Action FakeDeathEvent(Event oldEvent, char[] weapon)
{
    oldEvent.BroadcastDisabled = true;
    
    Event event_fake = CreateEvent("player_death", true);
    
    char sWeapon[64];
    Format(sWeapon, sizeof sWeapon, "weapon_%s", weapon); // trys to use materials/panorama/images/icons/equipment/<WEAPONNAME>.svg
    event_fake.SetString("weapon", sWeapon);
    
    event_fake.SetInt("userid", oldEvent.GetInt("userid"));
    event_fake.SetInt("attacker", oldEvent.GetInt("attacker"));
    
    event_fake.SetInt("assister", oldEvent.GetInt("assister"));
    event_fake.SetBool("assistedflash", oldEvent.GetBool("assistedflash"));
    event_fake.SetBool("headshot", oldEvent.GetBool("headshot"));
    event_fake.SetBool("dominated", oldEvent.GetBool("dominated"));
    event_fake.SetBool("revenge", oldEvent.GetBool("revenge"));
    event_fake.SetBool("wipe", oldEvent.GetBool("wipe"));
    event_fake.SetBool("penetrated", oldEvent.GetBool("penetrated"));
    event_fake.SetBool("noreplay", oldEvent.GetBool("noreplay"));
    event_fake.SetBool("noscope", oldEvent.GetBool("noscope"));
    event_fake.SetBool("thrusmoke", oldEvent.GetBool("thrusmoke"));
    event_fake.SetBool("attackerblind", oldEvent.GetBool("attackerblind"));
    
    for(int i = 1; i <= MaxClients; i++) if(IsClientInGame(i) && !IsFakeClient(i))
    {
        event_fake.FireToClient(i);
    }
    
    event_fake.Cancel();
    
    return Plugin_Changed;
} 


If you plan to use this for your own servers, please choose unique filenames which include a shortcut of your communityname as a prefix or something, thanks.


.

[The Killer NL]

Dope!

[kratoss1812]

thanks for sharing <3

[Ilusion9]

PHP Code:


HookEvent("player_death", Event_PlayerDeath_Pre, EventHookMode_Pre);

public void Event_PlayerDeath_Pre(Event event, const char[] name, bool dontBroadcast) 
{
    if (event.GetInt("attacker"))
    {
        // kills made by traps
        char weapon[256];
        event.GetString("weapon", weapon, sizeof(weapon));
        
        if (StrEqual(weapon, "point_hurt", true) || StrEqual(weapon, "worldspawn", true))
        {
            event.SetString("weapon", "breachcharge_projectile");
        }
    }
} 


You can do this, it's cleaner than how you do.
For that icon to work, the setting should be: event.SetString("weapon", "fall");

[zipcore]

You're right, at the time I used this code I was also limiting who receives the killfeed. Totally forgot to clean that out as I've stripped the code to make this public. I will rework th snipped and example code later. Thanks for letting me know.

[PC Gamer]

Adding this from a 'Be the Wizard Merasmus' plugin by Starman4xz, Mitch, Plipoika, FlaminSarge:

PHP Code:

public void OnPluginStart() 
{ 
    HookEvent("player_death", Event_DeathPre, EventHookMode_Pre);
}

public Action Event_DeathPre(Handle event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "attacker"));
    char weapon[20];
    GetEventString(event, "weapon", weapon, sizeof(weapon));
    if(g_bIsWizard[client])
    {
        if(StrEqual(weapon, "club", false))
        {
            SetEventString(event, "weapon", "merasmus_decap");
            SetEventString(event, "weapon_logclassname", "merasmus_decap");
        }
        else if(StrEqual(weapon, "flamethrower", false))
        {
            SetEventString(event, "weapon", "merasmus_zap");
            SetEventString(event, "weapon_logclassname", "merasmus_zap");
        }
        else if(StrEqual(weapon, "env_explosion", false))
        {
            SetEventString(event, "weapon", "merasmus_grenade");
            SetEventString(event, "weapon_logclassname", "merasmus_grenade");
        }
    }
} 


And adding this from a 'Be the Monoculus' plugin by Leonardo:

PHP Code:

public OnPluginStart()
{
    HookEvent( "player_death", OnPlayerDeath, EventHookMode_Pre );
}

public Action:OnPlayerDeath( Handle:hEvent, const String:strEventName[], bool:bDontBroadcast )
{
    new iClient = GetClientOfUserId( GetEventInt( hEvent, "userid" ) );
    if( !IsValidClient(iClient) )
    return Plugin_Continue;
    
    if( bEyeStatus[iClient] )
    {
        DontBeTheMonoculus( iClient );
        return Plugin_Continue;
    }
    
    new iKiller = GetClientOfUserId( GetEventInt( hEvent, "attacker" ) );
    if( !IsValidClient(iKiller) || !bEyeStatus[iKiller] )
    return Plugin_Continue;
    
    SetEventString( hEvent, "weapon", "eyeball_rocket" );
    SetEventInt( hEvent, "weaponid", 0 );
    SetEventString( hEvent, "weapon_logclassname", "eyeball_rocket" );
    SetEventInt( hEvent, "customkill", TF_CUSTOM_EYEBALL_ROCKET );
    
    //    SetEntityHealth( iKiller, GetClientHealth(iKiller) + iEyeHPP );
    return Plugin_Continue;
}