[WilliamDG]

Hi guys,

1)can someone tell me how can i manage the server chat?
In my CSGO server if i change the convar "sv_password" it print on the chat the following message:

Server cvar 'sv_password' changed to ***PROTECTED***

So is possible to manage it? (With manage i mean modify or better: remove it with a "return Plugin_Stop;" instead the callback but how can i do that function? Is present on sourcepawn/sourcemod?)


2)Dynamic arrays...
Suppose that i want to create an array size with a convar (sm_myArraySize = 5) and i put it on array declaration:

PHP Code:

ConVar myConvar;


myConvar = CreateConVar("sm_myArraySize" etc etc...)
char myArray[GetConVarInt(myConvar)];     //Obviously on this line compiler generate an error. 


How can i do something like that?

Thankyou in advance for help!

[Benoist3012]

1)I have no idea, what kind of user message the server sends to tell a client a cvar value changed, but try by starting hooking those 3:

HookUserMessage(GetUserMessageId("SayText2"), Hook_BlockUserMessage, true);
HookUserMessage(GetUserMessageId("SayText"), Hook_BlockUserMessage, true);
HookUserMessage(GetUserMessageId("TextMsg"), Hook_BlockUserMessage, true);

Edit: See asherkin's post.

2)
If you want to use dynamic array, you must set it up like this:

char[] myArray = new char[myConvar.IntValue];

[asherkin]

If you're changing sv_password in a plugin, just remove FCVAR_NOTIFY from it before setting it, and add it back afterwards.

[WilliamDG]

1) I had time only to test the ConVar thing, thank you guys for the help and for the quick reply!!!

i solved it in this way:

PHP Code:

SetConVarFlags(FindConVar("sv_password"), FCVAR_NEVER_AS_STRING);
ServerCommand("sv_password %s", string); 


2) For dynamic array i will test it tomorrow and i will write here the feedback!

Thank you again

[WilliamDG]

Originally Posted by Benoist3012 2) If you want to use dynamic array, you must set it up like this: char[] myArray = new char[myConvar.IntValue];

Ok, i have tested the dynamic array thing.
It work perfectly and i thank you for quick reply!

Only a little question, if i'm in this situation:

PHP Code:

ConVar myConvar;


myConvar = CreateConVar("sm_myArraySize" etc etc...)
char[] myArray = new char[myConvar.IntValue]; 


and after i want use the sizeoff command to get the length it give me an error so i supposed to use again the myConvar.IntValue

My question is: There is another way to get the sizeoff or this is the only way to get the dynamic array length?

Thank you again guys!!!

[asherkin]

sizeof is evaluated at compile-time, you can't use it on dynamic arrays.

[Byte]

Originally Posted by asherkin If you're changing sv_password in a plugin, just remove FCVAR_NOTIFY from it before setting it, and add it back afterwards.

Alternatively:

PHP Code:

public void OnPluginStart()
{
  HookEvent("server_cvar", Event_ServerCvar, EventHookMode_Pre);
}

public Action Event_ServerCvar(Event event, const char[] name, bool dontBroadcast)
{
  char cvarName[128];
  event.GetString("cvarname", cvarName, sizeof(cvarName));
  
  if (StrEqual(cvarName, "sv_password")) {
    return Plugin_Handled;
  }

  return Plugin_Continue;  
} 


Another similar way:

PHP Code:

public void OnPluginStart()
{
  HookEvent("server_cvar", Event_ServerCvar, EventHookMode_Pre);
}

public Action Event_ServerCvar(Event event, const char[] name, bool dontBroadcast)
{
  char cvarName[128];
  event.GetString("cvarname", cvarName, sizeof(cvarName));
  
  if (StrEqual(cvarName, "sv_password")) {
    event.BroadcastDisabled = true;
  }

  return Plugin_Continue;  
} 


[Benoist3012]

Originally Posted by WilliamDG Ok, i have tested the dynamic array thing. It work perfectly and i thank you for quick reply! Only a little question, if i'm in this situation: PHP Code: ConVar myConvar; myConvar = CreateConVar("sm_myArraySize" etc etc...) char[] myArray = new char[myConvar.IntValue];  and after i want use the sizeoff command to get the length it give me an error so i supposed to use again the myConvar.IntValue My question is: There is another way to get the sizeoff or this is the only way to get the dynamic array length? Thank you again guys!!!

You have no choice but do:

int iSize = myConvar.IntValue;
char[] myArray = new char[iSize];
Format(myArray, iSize, "%s%s",something, something2);

[Neuro Toxin]

Have a look at Dynamic.

[WilliamDG]

Thank you for all help guys!!