[pillowCloud]

I'm looking for a way to start a random button from the all buttons that exist in map.

for example: If this a deathrun mod, so traps will be started automatically by their buttons.

Thanks in advance

[klippy]

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "Use Random Button"
#define VERSION "1.0.0"
#define AUTHOR "KliPPy"


new Array: g_aButtons;
new g_iButtonsCount;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_aButtons = ArrayCreate();
    g_iButtonsCount = FindAllButtons();
    
    register_clcmd("say !randombutton", "Cmd_Say_randombutton");
}

FindAllButtons() {
#if AMXX_VERSION_NUM < 183
    new iEnt = get_maxplayers() + 1;
#else
    new iEnt = MaxClients + 1;
#endif
    while((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", "func_button")) > 0) {
        ArrayPushCell(g_aButtons, iEnt);
    }
    
    return ArraySize(g_aButtons);
}

public Cmd_Say_randombutton() {
     new iEnt = ArrayGetCell(g_aButtons, random(g_iButtonsCount));
     if(pev_valid(iEnt)) {
         dllfunc(DLLFunc_Use, iEnt, 0);
     }
} 


This plugin will let a player write "!randombutton" in chat and will activate a random button on the map. Tested and works fine.
I made it like so because you didn't explain it good enough what you need. When do you need buttons to activate? All of them or just one of them? Et cetera...

[pillowCloud]

Originally Posted by KliPPy PHP Code: #include <amxmodx> #include <fakemeta> #define PLUGIN "Use Random Button" #define VERSION "1.0.0" #define AUTHOR "KliPPy" new Array: g_aButtons; new g_iButtonsCount; public plugin_init() {     register_plugin(PLUGIN, VERSION, AUTHOR);          g_aButtons = ArrayCreate();     g_iButtonsCount = FindAllButtons();          register_clcmd("say !randombutton", "Cmd_Say_randombutton"); } FindAllButtons() { #if AMXX_VERSION_NUM < 183     new iEnt = get_maxplayers() + 1; #else     new iEnt = MaxClients + 1; #endif     while((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", "func_button")) > 0) {         ArrayPushCell(g_aButtons, iEnt);     }          return ArraySize(g_aButtons); } public Cmd_Say_randombutton() {      new iEnt = ArrayGetCell(g_aButtons, random(g_iButtonsCount));      if(pev_valid(iEnt)) {          dllfunc(DLLFunc_Use, iEnt, 0);      } }  This plugin will let a player write "!randombutton" in chat and will activate a random button on the map. Tested and works fine. I made it like so because you didn't explain it good enough what you need. When do you need buttons to activate? All of them or just one of them? Et cetera...

That's just what i needed.

Thank you very very much!

edit:
I'm experiencing problem when the func_button is tied to a camera.
when it do, the players gets the camera view.

there is any possibility to fix this?

Thanks again.

[klippy]

Try this one. Untested, but I guess it should work. It should ignore triggering of any "trigger_camera" that's been triggered by a randomly used button.

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "Use Random Button"
#define VERSION "1.0.0"
#define AUTHOR "KliPPy"


new Array: g_aButtons;
new g_iButtonsCount;
new g_iButtonInUse;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_aButtons = ArrayCreate();
    g_iButtonsCount = FindAllButtons();
    
    RegisterHam(Ham_Use, "trigger_camera", "TriggerCamera_Use", false);
    
    register_clcmd("say !randombutton", "Cmd_Say_randombutton");
}

FindAllButtons() {
#if AMXX_VERSION_NUM < 183
    new iEnt = get_maxplayers() + 1;
#else
    new iEnt = MaxClients + 1;
#endif

    while((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", "func_button")) > 0) {
        if(pev_valid(iEnt)) {
            ArrayPushCell(g_aButtons, iEnt);
        }
    }
    
    return ArraySize(g_aButtons);
}

// iActivator - one that triggered the chain
// iCaller - previous one in the chain
public TriggerCamera_Use(this, iActivator, iCaller, iUseType, Float: fValue) {
    if(iActivator == g_iButtonInUse) {
        return HAM_SUPERCEDE;
    }
    
    return HAM_IGNORED;
}

public Cmd_Say_randombutton() {
    new iEnt = ArrayGetCell(g_aButtons, random(g_iButtonsCount));
     
    if(pev_valid(iEnt)) {
        g_iButtonInUse = iEnt;
        dllfunc(DLLFunc_Use, iEnt, iEnt);
        g_iButtonInUse = FM_NULLENT;
    }
    
} 


[pillowCloud]

Originally Posted by KliPPy Try this one. Untested, but I guess it should work. It should ignore triggering of any "trigger_camera" that's been triggered by a randomly used button. PHP Code: #include <amxmodx> #include <hamsandwich> #include <fakemeta> #define PLUGIN "Use Random Button" #define VERSION "1.0.0" #define AUTHOR "KliPPy" new Array: g_aButtons; new g_iButtonsCount; new g_iButtonInUse; public plugin_init() {     register_plugin(PLUGIN, VERSION, AUTHOR);          g_aButtons = ArrayCreate();     g_iButtonsCount = FindAllButtons();          RegisterHam(Ham_Use, "trigger_camera", "TriggerCamera_Use", false);          register_clcmd("say !randombutton", "Cmd_Say_randombutton"); } FindAllButtons() { #if AMXX_VERSION_NUM < 183     new iEnt = get_maxplayers() + 1; #else     new iEnt = MaxClients + 1; #endif     while((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", "func_button")) > 0) {         if(pev_valid(iEnt)) {             ArrayPushCell(g_aButtons, iEnt);         }     }          return ArraySize(g_aButtons); } // iActivator - one that triggered the chain // iCaller - previous one in the chain public TriggerCamera_Use(this, iActivator, iCaller, iUseType, Float: fValue) {     if(iActivator == g_iButtonInUse) {         return HAM_SUPERCEDE;     }          return HAM_IGNORED; } public Cmd_Say_randombutton() {     new iEnt = ArrayGetCell(g_aButtons, random(g_iButtonsCount));           if(pev_valid(iEnt)) {         g_iButtonInUse = iEnt;         dllfunc(DLLFunc_Use, iEnt, iEnt);         g_iButtonInUse = FM_NULLENT;     }      }

Thank you so much!!
I saw many ppl saying +Karma
so, +Karma