[Therepower]

hello,
i try to get the clan tag of a user but it does not work
the code i try:

bool	b_IsMember[MAXPLAYERS+1],

public void OnClientPutInServer(int client)
{
	b_IsMember[client] = false;
char sClan[64];
	CS_GetClientClanTag(client, sClan, sizeof(sClan));
	if (StrEqual(sClan, "blood-G") || StrEqual(sClan, "BLOOD ."))
	{
		b_IsMember[client]=true;
	}
}

CS_GetClientClanTag(client, sClan, sizeof(sClan)); returns false for some reason.
Does this even work on csgo?

[8guawong]

should work in csgo
maybe try getting the on later event?

[DarkDeviL]

OnClientPutInServer is probably too early for CS_GetClientClanTag.

Try OnClientPostAdminCheck.

OnClientSettingsChanged is called every time stuff like clantag (as well as certain other things) are changed. You could also use that one, and change isMember back to FALSE if the new clantag isn't the same, etc.

E.g.:

bool	b_IsMember[MAXPLAYERS+1] = false;

public void OnClientSettingsChanged(int client)
{
	char sClan[64];
	CS_GetClientClanTag(client, sClan, sizeof(sClan));
	if (StrEqual(sClan, "blood-G") || StrEqual(sClan, "BLOOD ."))
	{
		b_IsMember[client]=true;
	}
	else
	{
		b_IsMember[client]=false;
	}
}

[Therepower]

Originally Posted by arne1288 OnClientPutInServer is probably too early for CS_GetClientClanTag. Try OnClientPostAdminCheck. OnClientSettingsChanged is called every time stuff like clantag (as well as certain other things) are changed. You could also use that one, and change isMember back to FALSE if the new clantag isn't the same, etc. E.g.: bool b_IsMember[MAXPLAYERS+1] = false; public void OnClientSettingsChanged(int client) { char sClan[64]; CS_GetClientClanTag(client, sClan, sizeof(sClan)); if (StrEqual(sClan, "blood-G") || StrEqual(sClan, "BLOOD .")) { b_IsMember[client]=true; } else { b_IsMember[client]=false; } }

i tried with player_connect_full hook but still seems not to work

    HookEventEx("player_connect_full", player_connect_full);

also thanks for the method you provided

OnClientSettingsChanged seems to be triggered when user connects if i'm right?

[PinHeaDi]

PHP Code:

#include <sourcemod>
#include <cstrike>

bool b_IsMember[MAXPLAYERS+1];

public void OnPluginStart()
{
    AddCommandListener(JoinTeam, "jointeam");
}

public Action JoinTeam(int client, char[] command, int args)
{
    CreateTimer(0.5, CheckGroupMember, client);
}

public Action CheckGroupMember(Handle timer, any client)
{
    char sClan[64];
    CS_GetClientClanTag(client, sClan, sizeof(sClan));
    if (StrEqual(sClan, "blood-G", true) || StrEqual(sClan, "BLOOD .", true))
    {
        b_IsMember[client]=true;
    }
    else
    {
        b_IsMember[client]=false;
    }
} 


Try this.

[Domino_]

I would suggest using OnClientCommandKeyValues as this will be called when someone sends the clantag they're using to the server. This method also has the advantage of being able disable their membership if they remove the tag. Here I'm only using the "tag" KeyValue, but you can also use the "name" KeyValue.

PHP Code:

#include <sourcemod>

bool b_IsMember[MAXPLAYERS+1];

public Action OnClientCommandKeyValues(int iClient, KeyValues kv)
{
    char sCmd[PLATFORM_MAX_PATH];
    
    if(kv.GetSectionName(sCmd, sizeof(sCmd)) && StrEqual(sCmd, "ClanTagChanged", false))
    {
        char sClan[PLATFORM_MAX_PATH];
        
        if(kv.GetString("tag", sClan, sizeof(sClan), ""))
        {
            if(StrEqual(sClan, "blood-G") || StrEqual(sClan, "BLOOD ."))
                b_IsMember[iClient] = true;
            else
                b_IsMember[iClient] = false;
        }
        else
            b_IsMember[iClient] = false;
    }
    
    return Plugin_Continue;
} 


Example dumped ClanTagChanged:

Spoiler

PHP Code:

"ClanTagChanged"
{
    "tag"        "๖Cαƒє"
    "name"        "Cafe Official"
}