[Scag]

So I was working with a forward to play music during gameplay with a sub-plugin. But I've run into a bit of a wall. I've consistantly got this error:

Which also spewed "instanced_scripted_scene" occasionally

I've got a repeating timer that does some stuff but also checks to see if music is playing. If no music is playing, then it it fires some functions to see if any exist. Shown below:

Spoiler

PHP Code:

public void _MusicPlay()
{
    if (gamemode.iRoundState != StateRunning)
        return;
    
    float currtime = GetGameTime();
    if (!cvarTF2Jail[EnableMusic].BoolValue || gamemode.flMusicTime > currtime)
        return;
    
    char sound[PLATFORM_MAX_PATH] = "";
    float time = -1.0;
    
    if (ManageMusic(sound, time) != Plugin_Continue)  // This always returns Plugin_Continue
        return;

    if (sound[0] != '\0')
    {
        float vol = cvarTF2Jail[MusicVolume].FloatValue;
        strcopy(BackgroundSong, PLATFORM_MAX_PATH, sound);
        for (int i = MaxClients; i; --i) 
        {
            if (!IsClientInGame(i))
                continue;
#if defined _clientprefs_included
            if (JailFighter(i).bNoMusic)
                continue;
#endif

            EmitSoundToClient(i, sound, _, _, SNDLEVEL_NORMAL, SND_NOFLAGS, vol, 100, _, NULL_VECTOR, NULL_VECTOR, false, 0.0);
        }
    }
    if (time != -1.0)
        gamemode.flMusicTime = currtime + time;
} 


ManageMusic() works through variables to see which song to play...

Spoiler

PHP Code:

public Action ManageMusic(char song[PLATFORM_MAX_PATH], float & time)
{
    switch (gamemode.iLRType)
    {
        case -1:
        {
            song = "";
            time = -1.0;
            return Plugin_Continue; // No bug/error thing for -1
        }
        default:return Call_OnPlayMusic(song, time); // Forward
    }
    return Plugin_Handled;
} 


To the forward...

Spoiler

PHP Code:

g_hForwards[OnPlayMusic] = new PrivateForward( CreateForward(ET_Hook, Param_String, Param_FloatByRef) ); // Using a methodmap < Handle

~~~~~~~~~~~~~~~~~~

Action Call_OnPlayMusic(char song[PLATFORM_MAX_PATH], float & time)
{
    Action result = Plugin_Handled;
    g_hForwards[OnPlayMusic].Start();
    Call_PushStringEx(song, PLATFORM_MAX_PATH, 0, SM_PARAM_COPYBACK);
    Call_PushFloatRef(time);
    Call_Finish(result);
    CPrintToChatAll("song = \"%s\"; time = %0.1f; %s", song, time, result == Plugin_Handled ? "Handled" : "???"); // Always got "???"
    return result;
}

~~~~~~~~~~~~~~~~~~ // As seen in include...

    // OnPlayMusic
    function Action (char song[PLATFORM_MAX_PATH], float & time); // Under a typeset, SDKHooks-style 


Song was either that question mark symbol or "instanced_scripted_scene". ALWAYS returned -1.0. ALWAYS returned something other than Plugin_Handled.
I also tried it with void/ET_Ignore but got the same issue. I genuinely dunno.
For now I just cheesed it to where if time is -1.0 the entire _MusicPlay() function just returns.

[Scag]

I managed to solve it myself. Fortunately it only took about an hour of trial and error.
To the forward function...

PHP Code:

Action Call_OnPlayMusic(char song[PLATFORM_MAX_PATH], float & time)
{
    Action result = Plugin_Handled;
    g_hForwards[OnPlayMusic].Start();
    Call_PushStringEx(song, PLATFORM_MAX_PATH, SM_PARAM_STRING_BINARY|SM_PARAM_STRING_UTF8|SM_PARAM_STRING_COPY, SM_PARAM_COPYBACK); // Moar flags!
    Call_PushFloatRef(time);
    Call_Finish(result);
    CPrintToChatAll("song = \"%s\"; time = %0.1f; %s", song, time, result == Plugin_Handled ? "Handled" : "???");
    return result;
} 


In case anyone else has this problem, here ya go :^)