[OXYD]

Hello there!

I get these errors. Can someone help me?

// F:\ASX\carantina\Update 1808\.vRAC_AntiRush.sp(2407) : error 100: function prototypes do not match
// F:\ASX\carantina\Update 1808\.vRAC_AntiRush.sp(2429) : error 100: function prototypes do not match

PHP Code:

stock SpawnTriggerMultipleInBox(iZoneIndex)
{
    new Float:fMiddle[3], Float:fMins[3], Float:fMaxs[3];
    
    decl String:sZoneName[128];
    new Handle:hZone = GetArrayCell(g_hZones, iZoneIndex);
    GetArrayString(hZone, 0, sZoneName, sizeof(sZoneName));
    GetArrayArray(hZone, 1, fMins, 3);
    GetArrayArray(hZone, 2, fMaxs, 3);
    
    new iEnt = CreateEntityByName("trigger_multiple");
    
    DispatchKeyValue(iEnt, "spawnflags", "64");
    Format(sZoneName, sizeof(sZoneName), "sm_zone %s", sZoneName);
    DispatchKeyValue(iEnt, "targetname", sZoneName);
    DispatchKeyValue(iEnt, "wait", "0");
    
    DispatchSpawn(iEnt);
    ActivateEntity(iEnt);
    SetEntProp(iEnt, Prop_Data, "m_spawnflags", 64 );
    
    GetMiddleOfABox(fMins, fMaxs, fMiddle);
    
    TeleportEntity(iEnt, fMiddle, NULL_VECTOR, NULL_VECTOR);
    SetEntityModel(iEnt, "models/items/car_battery01.mdl");
    
    // Have the mins always be negative
    fMins[0] = fMins[0] - fMiddle[0];
    if(fMins[0] > 0.0)
        fMins[0] *= -1.0;
    fMins[1] = fMins[1] - fMiddle[1];
    if(fMins[1] > 0.0)
        fMins[1] *= -1.0;
    fMins[2] = fMins[2] - fMiddle[2];
    if(fMins[2] > 0.0)
        fMins[2] *= -1.0;
    
    // And the maxs always be positive
    fMaxs[0] = fMaxs[0] - fMiddle[0];
    if(fMaxs[0] < 0.0)
        fMaxs[0] *= -1.0;
    fMaxs[1] = fMaxs[1] - fMiddle[1];
    if(fMaxs[1] < 0.0)
        fMaxs[1] *= -1.0;
    fMaxs[2] = fMaxs[2] - fMiddle[2];
    if(fMaxs[2] < 0.0)
        fMaxs[2] *= -1.0;
    
    SetEntPropVector(iEnt, Prop_Send, "m_vecMins", fMins);
    SetEntPropVector(iEnt, Prop_Send, "m_vecMaxs", fMaxs);
    SetEntProp(iEnt, Prop_Send, "m_nSolidType", 2);
    
    new iEffects = GetEntProp(iEnt, Prop_Send, "m_fEffects");
    iEffects |= 32;
    SetEntProp(iEnt, Prop_Send, "m_fEffects", iEffects);
    
    HookSingleEntityOutput(iEnt, "OnStartTouch", EntOut_OnStartTouch); //ERROR 1 HERE
}

stock KillTriggerEntity(iZoneIndex)
{
    new Handle:hZone;
    decl String:sZoneName[128];
    hZone = GetArrayCell(g_hZones, iZoneIndex);
    GetArrayString(hZone, 0, sZoneName, sizeof(sZoneName));
    Format(sZoneName, sizeof(sZoneName), "sm_zone %s", sZoneName);
    
    new iEnts = GetMaxEntities();
    decl String:sClassName[256];
    for(new i=MaxClients;i<iEnts;i++)
    {
        if(IsValidEntity(i)
        && IsValidEdict(i)
        && GetEdictClassname(i, sClassName, sizeof(sClassName))
        && StrContains(sClassName, "trigger_multiple") != -1
        && GetEntPropString(i, Prop_Data, "m_iName", sClassName, sizeof(sClassName))
        && StrEqual(sClassName, sZoneName, false))
        {
            UnhookSingleEntityOutput(i, "OnStartTouch", EntOut_OnStartTouch); //ERROR 2 HERE
            AcceptEntityInput(i, "Kill");
            break;
        }
    }
} 


[nosoop]

Originally Posted by OXYD Hello there! I get these errors. Can someone help me? // F:\ASX\carantina\Update 1808\.vRAC_AntiRush.sp(2407) : error 100: function prototypes do not match // F:\ASX\carantina\Update 1808\.vRAC_AntiRush.sp(2429) : error 100: function prototypes do not match

The error means that your function's callback doesn't match what the compiler expects it to be.

HookSingleEntityOutput(iEnt, "OnStartTouch", EntOut_OnStartTouch); //ERROR 1 HERE

HookSingleEntityOutput takes a callback with the EntityOutput function prototype, so your EntOut_OnStartTouch function (which you haven't posted) needs to have the same parameters and return type as one of those.

[OXYD]

My Bad

PHP Code:

public EntOut_OnStartTouch(const String:output[], caller, activator, Float:delay, Handle:event)
{
    
    if(g_bIsRushAllowed || !GetConVarBool(g_hCVEnable))
    {
        return;
    }
    
    //Check if it's warmup period
    if(GameRules_GetProp("m_bWarmupPeriod") == 1 && !GetConVarBool(g_hCVWarmupEnable))
    {
        //LogMessage("Punishing disabled during warmup");
        return;
    }
    
    /*// if the touching entity is a weapon, remove it, if we strip to knife
    decl String:sClassName[64];
    if(iPunishment == 4
    && IsValidEntity(activator)
    && IsValidEdict(activator)
    && GetEdictClassname(activator, sClassName, sizeof(sClassName))
    && StrContains(sClassName, "weapon_") != -1
    && GetEntPropEnt(activator, Prop_Send, "m_hOwnerEntity") == -1)
    {
        RemoveEdict(activator);
    }*/
    
    // Ignore dead players
    if(activator < 1 || activator > MaxClients || !IsPlayerAlive(activator))
        return;
    
    // Admin immune?
    if(GetConVarBool(g_hCVAdminImmunity) && CheckCommandAccess(activator, "antirush_immune", ADMFLAG_GENERIC, true))
    {
        return;
    }
    
    decl String:sTargetName[256];
    GetEntPropString(caller, Prop_Data, "m_iName", sTargetName, sizeof(sTargetName));
    ReplaceString(sTargetName, sizeof(sTargetName), "sm_zone ", "");
    
    // Check if he's in the team, this zone blocks
    new iSize = GetArraySize(g_hZones), iZonePunishment = -1;
    new Handle:hZone;
    decl String:sZoneName[64];
    for(new i=0;i<iSize;i++)
    {
        hZone = GetArrayCell(g_hZones, i);
        GetArrayString(hZone, 0, sZoneName, sizeof(sZoneName));
        // Check the team for this zone
        if(StrEqual(sZoneName, sTargetName))
        {
            new iTeam = GetArrayCell(hZone, 3);
            iZonePunishment = GetArrayCell(hZone, 4);
            if(iTeam != 0 && GetClientTeam(activator) != iTeam)
                return;
        }
    }
    
    new iPunishment = GetConVarInt(g_hCVPunishment);
    if(iZonePunishment > 0)
        iPunishment = iZonePunishment;
    
    switch(iPunishment)
    {
        // Just tell everybody
        case 1:
        {
            decl String:sName[64];
            GetClientName(activator, sName, sizeof(sName));
            PrintToChatAll("%s%t", PREFIX, "Player Entered Zone", sName, sTargetName);
        }
        // Bounce him back
        case 2:
        {
            new Float:fVelocity[3];
            fVelocity[0] = GetEntPropFloat(activator, Prop_Send, "m_vecVelocity[0]"); 
            fVelocity[1] = GetEntPropFloat(activator, Prop_Send, "m_vecVelocity[1]"); 
            fVelocity[2] = GetEntPropFloat(activator, Prop_Send, "m_vecVelocity[2]");
            
            fVelocity[0] *= -2.0;
            fVelocity[1] *= -2.0;
            // Always bounce back with at least 200 velocity
            if(fVelocity[1] > 0.0 && fVelocity[1] < 200.0)
                fVelocity[1] = 200.0;
            else if(fVelocity[1] < 0.0 && fVelocity[1] > -200.0)
                fVelocity[1] = -200.0;
            // Never push the player up.
            if(fVelocity[2] > 0.0)
                fVelocity[2] *= -1.0;

            TeleportEntity(activator, NULL_VECTOR, NULL_VECTOR, fVelocity);
        }
        // Slay
        case 3:
        {
            ForcePlayerSuicide(activator);
            decl String:sName[64];
            GetClientName(activator, sName, sizeof(sName));
            PrintToChatAll("%s%t", PREFIX, "Player Slayed", sName, sTargetName);
        }
        // Only allow the usage of the knife
        case 4:
        {
            // Let the player hold the knife
            new iWeapon = GetPlayerWeaponSlot(activator, 2);
            decl String:sWeapon[32];
            if(iWeapon != -1)
            {
                GetEdictClassname(iWeapon, sWeapon, sizeof(sWeapon));
                FakeClientCommand(activator, "use %s", sWeapon);
            }
            
            // Don' allow the usage of other weapons but the knife
            g_bPlayerIsRushing[activator] = true;
        }
        // Allow the usage of any weapon again
        case 5:
        {
            g_bPlayerIsRushing[activator] = false;
        }
        
    }
} 


[nosoop]

Originally Posted by OXYD My Bad :) public EntOut_OnStartTouch(const String:output[], caller, activator, Float:delay, Handle:event)

In this case, you need to specify either Action or void as the return type (lack of return type is implicit int in legacy syntax), and the prototype doesn't have Handle event as one of its parameters. Check the second link in my previous post for reference.

const String:output[] is also legacy syntax. The modern way to declare that would be const char[] output, but it looks like the compiler doesn't complain about the legacy form, so while I'd encourage you to migrate to the modern syntax, there's no problem keeping that as-is.

[OXYD]

Originally Posted by nosoop In this case, you need to specify either Action or void as the return type (lack of return type is implicit int in legacy syntax), and the prototype doesn't have Handle event as one of its parameters. Check the second link in my previous post for reference. const Stringutput[] is also legacy syntax. The modern way to declare that would be const char[] output, but it looks like the compiler doesn't complain about the legacy form, so while I'd encourage you to migrate to the modern syntax, there's no problem keeping that as-is.

Thanks, i finally managed to make it work after i updated the old syntax to the new one. Apparently, more or less, the problem was coming from that Handle:event.