[LondoN]

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < regex >
#include < httpx >

new g_CurrentVotes, g_LastStoredVotes;

public plugin_init ( )
{
	register_plugin ( "Vote and get bonus", "2.0", "LondoN eXtream" );
	register_clcmd ( "say /vote", "Func_VoteServer" );
}

public Func_VoteServer ( id )
{
	HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "StoreVotes" );

	show_motd ( id, "www.csservers.ro/voteaza/zm.darkland.ro" );

	set_task ( 10.0, "CheckAgainVotes", id );
}

public StoreVotes ( id )
{
	new Buffer [ 1024 ], len;
	new szError [ 50 ], iNum;
	new Regex: FindVote;

	while ( ( len = HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) ) )
	{
		FindVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );

		if ( FindVote )
		{
			new szVotes [ 16 ];
			regex_substr ( FindVote, 1, szVotes, charsmax ( szVotes ) );
			server_print ( "Votes right now: %d", str_to_num ( szVotes ) );
			g_LastStoredVotes = str_to_num ( szVotes );
			regex_free ( FindVote );
		}
	}
}

public CheckAgainVotes ( id )
{
	HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "CheckAgainVotes" );
}

public CheckAgainVotes ( id )
{
	new Buffer [ 1024 ], len;
	new szError [ 50 ], iNum;
	new Regex: NewVote;

	while ( ( len = HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) ) )
	{
		NewVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );

		if ( NewVote )
		{
			new szVotes [ 16 ];
			regex_substr ( NewVote, 1, szVotes, charsmax ( szVotes ) );
			server_print ( "Votes now: %d", str_to_num ( szVotes ) );

			g_CurrentVotes = str_to_num ( szVotes );

			if ( g_CurrentVotes > g_LastStoredVotes )
			{
				cs_set_user_money ( id, 16000 );
				client_print ( id, print_chat, "You voted the server!" );
			}
		}
	}
}

i've tried, no good result.

[JocAnis]

you dont get this printed?

server_print ( "Votes right now: %d", str_to_num ( szVotes ) );

[LondoN]

len is assignet to a value it's never used, compiler says.

[Black Rose]

Can't test fully because the site only accepts IP addresses from Romania.

But...

Just remove "len", you obviously don't use it.



You have multiple functions with the same name, you need to change the name of one of them.

public CheckAgainVotes ( id )
{
    HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "CheckAgainVotesResult" );
}

public CheckAgainVotesResult ( id )
// ... 

I also had to change

show_motd ( id, "www.csservers.ro/voteaza/zm.darkland.ro" );

->

show_motd ( id, "http://www.csservers.ro/voteaza/zm.darkland.ro" );

Otherwise it would just open a window with the the text.

[Bugsy]

May be worthwhile to use len, just in case the page is retrieved in multiple chunks. Would need to make the buffer & len variables static, or better as global so you can reset len to 0 when a new request is made.

PHP Code:

while ( ( iPacketLen = HTTPX_GetData ( Buffer[ len ], charsmax ( Buffer ) - len ) ) )
{
    len += iPacketLen; 


[LondoN]

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < regex >
#include < httpx >

new g_CurrentVotes, g_LastStoredVotes;

public plugin_init ( )
{
	register_plugin ( "Vote and get bonus", "2.0", "LondoN eXtream" );
	register_clcmd ( "say /vote", "Func_VoteServer" );
	HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "StoreVotes" );
}

public Func_VoteServer ( id )
{
	HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "StoreVotes" );

	show_motd ( id, "www.csservers.ro/voteaza/zm.darkland.ro" );

	set_task ( 10.0, "CheckAgainVotes", id );
}

public StoreVotes ( id )
{
	new Buffer [ 1024 ];
	new szError [ 50 ], iNum;
	new Regex: FindVote;

	while ( HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) )
	{
		FindVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );

		if ( FindVote )
		{
			new szVotes [ 16 ];
			regex_substr ( FindVote, 1, szVotes, charsmax ( szVotes ) );
			server_print ( "Votes right now: %d", str_to_num ( szVotes ) );
			g_LastStoredVotes = str_to_num ( szVotes );
			regex_free ( FindVote );
		}
	}
}

public CheckAgainVotes ( id )
{
	HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "CheckAgainVotes123" );
}

public CheckAgainVotes123 ( id )
{
	new Buffer [ 1024 ];
	new szError [ 50 ], iNum;
	new Regex: NewVote;

	while ( HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) ) 
	{
		NewVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );

		if ( NewVote )
		{
			new szVotes [ 16 ];
			regex_substr ( NewVote, 1, szVotes, charsmax ( szVotes ) );
			server_print ( "Votes now: %d", str_to_num ( szVotes ) );

			g_CurrentVotes = str_to_num ( szVotes );

			if ( g_CurrentVotes > g_LastStoredVotes )
			{
				cs_set_user_money ( id, 16000 );
				client_print ( id, print_chat, "You voted the server!" );
			}

			regex_free ( NewVote );
		}
	}
}

I've tried that..no print to the server.

[Black Rose]

Run it once.
Post the complete output. (The file in your server folder called "YOURPLUGINNAME_debug.log")
Also, please post the debug .htm files called "DEBUG1.htm" and "DEBUG2.htm" from the same folder.

Also, note the highlighted changes. You had the download id and the player id mixed up.

Spoiler

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < regex >
#include < httpx >

#define DEBUG_CHAT      1
#define DEBUG_CL_CONSOLE    2
#define DEBUG_SRV_CONSOLE   4
#define DEBUG_FILE      8

#define DebugMessageFile(%0) DebugMessage(DEBUG_FILE,%0)

new g_CurrentVotes, g_LastStoredVotes;

public plugin_init ( )
{
    DebugMessageFile("plugin_init(): called");
    register_plugin ( "Vote and get bonus", "2.0", "LondoN eXtream" );
    register_clcmd ( "say /vote", "Func_VoteServer" );
    HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", "DEBUG1.htm", _, "StoreVotes" );
    DebugMessageFile("plugin_init(): finished");
}

public Func_VoteServer ( id )
{
    DebugMessageFile("Func_VoteServer(%d): called", id);
    HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", _, _, "StoreVotes" );

    show_motd ( id, "www.csservers.ro/voteaza/zm.darkland.ro" );

    set_task ( 10.0, "CheckAgainVotes", id );
    DebugMessageFile("Func_VoteServer(): finished");
}

public StoreVotes ( DownloadID )
{
    DebugMessageFile("StoreVotes(%d): called", DownloadID);
    new Buffer [ 1024 ];
    new szError [ 50 ], iNum;
    new Regex: FindVote;

    DebugMessageFile("Download: %dB/%dB, +%dB^n", HTTPX_GetBytesReceived(DownloadID), HTTPX_GetFilesize(DownloadID), HTTPX_GetNewBytesReceived())

    while ( HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) )
    {
        DebugMessageFile("HTTPX_GetData(): %d^n^n%s^n^n", strlen(Buffer), Buffer);
        FindVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );
        DebugMessageFile("FindVote = %d", FindVote);

        if ( FindVote )
        {
            new szVotes [ 16 ];
            regex_substr ( FindVote, 1, szVotes, charsmax ( szVotes ) );
            DebugMessageFile("regex_substr(FindVote): %s^n", szVotes);
            server_print ( "Votes right now: %d", str_to_num ( szVotes ) );
            g_LastStoredVotes = str_to_num ( szVotes );
            regex_free ( FindVote );
        }
    }
    DebugMessageFile("StoreVotes(): finished");
}

public CheckAgainVotes ( id )
{
    new DownloadID = HTTPX_Download ( "www.csservers.ro/evidenta/zm.darkland.ro", "DEBUG2.htm", _, "CheckAgainVotes123" );
    HTTPX_SetCustom(DownloadID, id);
}

public CheckAgainVotes123 ( DownloadID )
{
    new Buffer [ 1024 ];
    new szError [ 50 ], iNum;
    new Regex: NewVote;

    while ( HTTPX_GetData ( Buffer, charsmax ( Buffer ) ) ) 
    {
        NewVote = regex_match ( Buffer, "voturi-azi^">(.*?)</a>", iNum, szError, charsmax ( szError ) );

        if ( NewVote )
        {
            new szVotes [ 16 ];
            regex_substr ( NewVote, 1, szVotes, charsmax ( szVotes ) );
            server_print ( "Votes now: %d", str_to_num ( szVotes ) );

            g_CurrentVotes = str_to_num ( szVotes );

            if ( g_CurrentVotes > g_LastStoredVotes )
            {
                new id = HTTPX_GetCustom(DownloadID);
                if ( is_user_connected(id) ) {
                    cs_set_user_money ( id, 16000 );
                    client_print ( id, print_chat, "You voted the server!" );
                }
            }

            regex_free ( NewVote );
        }
    }
}

stock DebugMessage(PrintTo = DEBUG_SRV_CONSOLE|DEBUG_FILE, const fmt[], any:...) {

    static _DebugMessageOutput[1024], _DebugMessagePluginName[64];

    vformat(_DebugMessageOutput, charsmax(_DebugMessageOutput), fmt, 3);

    get_plugin(-1, _DebugMessagePluginName, charsmax(_DebugMessagePluginName));

    if ( PrintTo & (DEBUG_CHAT|DEBUG_CL_CONSOLE) ) {

        new Players[32], Playercount, bool:AdminOnline;
        get_players(Players, Playercount);

        for ( new i ; i < Playercount ; i++ ) {
            if ( is_user_admin(Players[i]) ) {
                AdminOnline = true;
                break;
            }
        }

        for ( new i ; i < Playercount ; i++ ) {

            if ( AdminOnline && ! is_user_admin(Players[i]) )
                continue;

            if ( PrintTo & DEBUG_CHAT )
                client_print(Players[i], print_chat, "[%s] %s", _DebugMessagePluginName, _DebugMessageOutput);

            if ( PrintTo & DEBUG_CL_CONSOLE )
                client_print(Players[i], print_console, "[%s] %s", _DebugMessagePluginName, _DebugMessageOutput);
        }
    }

    if ( PrintTo & DEBUG_SRV_CONSOLE ) {
        server_print("[%s] %s", _DebugMessagePluginName, _DebugMessageOutput);
    }

    if ( PrintTo & DEBUG_FILE ) {
        add(_DebugMessagePluginName, charsmax(_DebugMessagePluginName), "_debug.log");

        new hFile = fopen(_DebugMessagePluginName, "a");

        if ( ! hFile )
            return;

        new Timestamp[21];
        get_time("%Y-%m-%d, %H:%M:%S", Timestamp, charsmax(Timestamp));
        fprintf(hFile, "%s: %s^n", Timestamp, _DebugMessageOutput);
        fclose(hFile);
    }
}

[LondoN]

Thank's a lot BlackRose, now it's working fine!


L 12/30/2018 - 23:04:04: -------- Mapchange to de_dust2 --------
Votes right now: 3

[Black Rose]

Originally Posted by LondoN Thank's a lot BlackRose, now it's working fine! L 12/30/2018 - 23:04:04: -------- Mapchange to de_dust2 -------- Votes right now: 3

I didn't change anything that would affect the outcome of the print, only the receiving of money.
But hey, great.

[LondoN]

Yes, i see, the money give doesn't work, but i resolve this with creating global PlayerID and when func_vote called PlayerID = id then check votes.