[krysteksulek]

Hi.
I found plugin which bloks using HE:

#include < amxmodx >
#include < hamsandwich >
#include < fakemeta >

const XO_WEAPONS = 4;
const m_flNextPrimaryAttack = 46;

public plugin_init( )
{
    RegisterHam( Ham_Item_Deploy, "weapon_hegrenade", "Block", 1 );
}

public Block( ent )
{
    set_pdata_float( ent, m_flNextPrimaryAttack, 9999.0, XO_WEAPONS );
    return HAM_SUPERCEDE;
}

It's working great. I want someone to edit it for me, to block hegrenade for 15 sec after roundstart + print chat with timer (example in plugin below)

I have plugin which uses client_PreThink. It's working too, but when i'm trying to throw hegrenade (when it's bloked of course), it flashes for a few seconds:

#include <amxmodx>
#include <fakemeta>

#define m_flNextAttack 83

new pCvarTime, blocktime;

public plugin_init()
{
    register_plugin("Block HE", "9", "QTM. Peyote");
    register_logevent("Start", 2, "1=Round_Start"); 
    register_forward(FM_PlayerPreThink, "client_PreThink");
    
    pCvarTime = register_cvar("cod_he", "15");
}

public client_PreThink(id)
{
    if(task_exists(-44) && get_user_weapon(id) == CSW_HEGRENADE)
    {
        client_print(id, print_center, "He will be enabled in %i second's.", blocktime);
        set_pdata_float(id, m_flNextAttack, 0.1 , 5);
    }
}
public Start()
    set_task(1.0, "Unlock", -44, _, _, "a", blocktime = get_pcvar_num(pCvarTime));

public Unlock()
    blocktime--;

I hope you will help me

[krysteksulek]

Refresh

[krysteksulek]

Refresh

[ConnorMcLeod]

PHP Code:

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

#pragma semicolon 1

#define PLUGIN "He Grenades Delay"
#define VERSION "0.0.1"

#define cm(%0)    ( sizeof(%0) - 1 )

const XO_CBASEPLAYERITEM = 4;
const m_pPlayer = 41;

const XO_CBASEPLAYERWEAPON = 4;
 const m_flNextPrimaryAttack = 46;

new g_pcvarHeGrenadeDelay;
new Float:g_flEnableHeGrenadesTime;

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );

    g_pcvarHeGrenadeDelay = register_cvar("amx_he_grenade_delay", "15.0");
    register_logevent("LogEvent_Round_Start", 2, "1=Round_Start");

    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_hegrenade", "CHEGrenade_PrimaryAttack", false);
}

public LogEvent_Round_Start()
{
    g_flEnableHeGrenadesTime = get_gametime() + get_pcvar_float(g_pcvarHeGrenadeDelay);
}

public CHEGrenade_PrimaryAttack( he )
{
    new Float:diff = g_flEnableHeGrenadesTime - get_gametime();
    if( diff > 0.0 )
    {
        set_pdata_float(he, m_flNextPrimaryAttack, diff > 1.0 ? 1.0 : diff, XO_CBASEPLAYERWEAPON);
        new id = get_pdata_cbase(he, m_pPlayer, XO_CBASEPLAYERITEM);
        client_print(id, print_center, "HeGrenades will be enabled in %.1f second's.", diff);
        return HAM_SUPERCEDE;
    }
    return HAM_IGNORED;
} 


[Bos93]

ConnorMcLeod,

Pre hook.