[freanky]

i have this error in my sourcemod log:

L 12/15/2013 - 17:48:14: [SM] Displaying call stack trace for plugin "sm_infirmerie.smx":
L 12/15/2013 - 17:48:14: [SM]   [0]  Line 36, C:\Program Files (x86)\Steam\steamapps\marcamy\counter-strike source\cstrike\addons\sourcemod\scripting\sm_infirmerie.sp::Event_round_End()
L 12/15/2013 - 17:49:21: [SM] Native "KillTimer" reported: Invalid timer handle fdf30a08 (error 1)

Line 25 to 52 . ligne 36 is: KillTimer(g_Timer);

public OnPluginStart()
{
    RegConsoleCmd("sm_infirm", Command_Infirmerie);
	HookEvent("round_start", Event_round_Start);
	HookEvent("round_end", Event_round_End);
}

public Action:Event_round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
	if(g_Timer != INVALID_HANDLE)
	{
		KillTimer(g_Timer);
	}
}

public Action:Event_round_Start(Handle:event, const String:name[], bool:dontBroadcast)
{
	for (new i = 0; i < 26; i++)
	{
		userids[i] = 0;
	}
	position = 1;
	compteur = 30;
	nombreVotes = 0;
	possible = 1;
	infirmeriePermise = 1;
	return Plugin_Continue;
}

[shavit]

Make sure you set g_Timer to INVALID_HANDLE after you kill him.
A little bird (alongub) told me in the past that you should use CloseHandle for killing timers, try that.

[freanky]

not work, or i do not correctly?

[Bacardi]

If you create and store timer with timer flag TIMER_FLAG_NO_MAPCHANGE in handle
-Clear that handle OnMapEnd()
-Because this timer flag stop timer without "clearing" that handle to INVALID
-Or don't use this timer flag help's alot.

PHP Code:

public OnMapEnd()
{
    g_Timer = INVALID_HANDLE;
} 


And remember clear handle when timer make action

PHP Code:

public Action:mytimer(Handle:timer, any:data)
{
    // Important! Very first to do this!
    g_Timer = INVALID_HANDLE;

    // Do your code
} 


And it's good idea clear handle after killing it.

PHP Code:

    if(g_Timer != INVALID_HANDLE)
    {
        KillTimer(g_Timer);
        g_Timer = INVALID_HANDLE;
        
    } 


TIMER_FLAG_NO_MAPCHANGE or Clearing Handle?

[GsiX]

I m not aware of the clearing handle OnMapEnd ().
Thanks for the info.

[freanky]

this line is ok thank you
now:
/home/groups/sourcemod/upload_tmp/phpV2vhC8.sp(169) : warning 219: local variable "g_Timer" shadows a variable at a preceding level

Line 169 to 210

public Action:CompteurInfirmerie(Handle:g_Timer)
{
	if (compteur == 30)
	{
		PrintCenterTextAll("La sortie vers l'infirmerie commence!");
	}
	else if (compteur == 20)
	{
		for (new i = 1; i <= MaxClients; i++)
		{
			if (IsClientInGame(i) && !IsClientObserver(i))
			{
				if(GetClientTeam(i) == CS_TEAM_T && IsPlayerAlive(i))
				{
					new HPJOUEUR = GetClientHealth(i);
					if (HPJOUEUR != 100)
						{
							SetEntityRenderColor(i, 150, 0, 0);
						}
				}
			}
		}
	}
	else if (compteur > 0 && compteur < 30)
	{
		PrintCenterTextAll("Il reste %d secondes a la sortie vers l'infirmerie", compteur);
	}
	else
	{
		PrintCenterTextAll("La sortie est finie");
		for (new i = 1; i <= MaxClients; i++)
		{
			if (IsClientInGame(i) && !IsClientObserver(i) && IsPlayerAlive(i))
			{
				SetEntityRenderColor(i, 255, 255, 255);
			}
		}
		return Plugin_Stop;
	}
	compteur--;
	return Plugin_Continue;
}

Line 32 to 40

public Action:Event_round_End(Handle:event, const String:name[], bool:dontBroadcast)
{
    if(g_Timer != INVALID_HANDLE)
    {
        KillTimer(g_Timer);
        g_Timer = INVALID_HANDLE;
        
    }
}

[TnTSCS]

public Action:CompteurInfirmerie(Handle:g_Timer)

to

public Action:CompteurInfirmerie(Handle:timer)

Also, don't forget to set g_Timer to INVALID_HANDLE when you're done with it, otherwise, KillTimer will throw an error trying to kill a timer that isn't valid.