[headline]

[Multi-1v1] Challenge Plugin

NO LONGER SUPPORTED! NEW ONE HERE

ABOUT:
This plugin is a "!challenge" plugin made to work ONLY inside of the Multi-1v1 Plugin made by Splewis. If you are not running this mod, this plugin WILL NOT WORK. This plugin allows players to type !challenge to challenge their buddies which places them into a private arena where they can then fight each other. Once the challenge duel is over, the players get put back into their old arena locations.


COMMANDS:

 - sm_challenge / !challenge 
 - sm_chal / !chal

SERVERS:




SOURCE CODE:

Spoiler

PHP Code:

#include <sourcemod>
#include <multi1v1>
#include <cstrike>
#include <autoexecconfig>

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_VERSION "1.2.4"

/* Bools */
bool g_bLateLoad;
bool ga_bIsInChallenge[MAXPLAYERS + 1] = {false, ...};
bool ga_bIsInChallengeQueue[MAXPLAYERS + 1] = {false, ...};
bool g_bAllowChallenge = true;

/* Handles */
Handle g_hArray = null;

/* Integers */
int g_iRound = 1;
int ga_iCooldown[MAXPLAYERS + 1] = {-1, ...};
int ga_iOldArena[MAXPLAYERS + 1] = {-1, ...};
int ga_iChallengePartner[MAXPLAYERS + 1] = {0, ...};

/* ConVars */
ConVar gcv_bPluginEnabled = null;
ConVar gcv_iCooldownAmmount = null;
ConVar gcv_bBlockRatingChanges = null;
ConVar gcv_iRoundDelay = null;

public APLRes AskPluginLoad2(Handle hMyself, bool bLate, char[] sError, int err_max)
{
    g_bLateLoad = bLate;
    
    return APLRes_Success;
}

public Plugin myinfo =    
{
    name = "[Multi-1v1] Challenge",
    author = "Headline",
    description = "Allows players to challenge their friends",
    version = PLUGIN_VERSION,
    url = "http://www.Colosseum-Gaming.com"
}

public void OnPluginStart()
{
    LoadTranslations("common.phrases");
    AutoExecConfig_SetFile("hl_challenge");
    AutoExecConfig_CreateConVar("hl_challenge_version", PLUGIN_VERSION, "Headline's Challenge Plugin Version", FCVAR_DONTRECORD|FCVAR_PLUGIN);
    
    gcv_bPluginEnabled = AutoExecConfig_CreateConVar("hl_challenge_enabled", "1", "Enable the plugin? \n 1 = Enabled");
    
    gcv_iCooldownAmmount = AutoExecConfig_CreateConVar("hl_challenge_cooldown", "2", "Cooldown Ammount? \n Set 0 to disable");
    
    gcv_bBlockRatingChanges = AutoExecConfig_CreateConVar("hl_challenge_rating", "0", "Allow rating changes during challenges? \n 0 to block rating changes");
    
    gcv_iRoundDelay = AutoExecConfig_CreateConVar("hl_challenge_delay", "1", "Ammount of rounds to keep someone in challenge queue?\n This is the delay after a challenge has been accepted.");
    
    AutoExecConfig_ExecuteFile();
    AutoExecConfig_CleanFile();

    RegConsoleCmd("sm_challenge", Command_Challenge, "Allows users to challenge their friends!");
    RegConsoleCmd("sm_chal", Command_Challenge, "Allows users to challenge their friends!");
    
    HookEvent("round_start", Event_RoundStart);
    HookEvent("round_end", Event_RoundEnd);
    HookEvent("player_death", Event_PlayerDeath);
    
    g_hArray = CreateArray(128);
    ClearArray(g_hArray);
    
    if(g_bLateLoad)
    {
        g_iRound = 1;
        g_bAllowChallenge = true;
        for (int i = 1; i <= MaxClients; i++)
        if (IsValidClient(i))
        {
            OnClientConnected(i);
        }
    }
}

public void OnMapStart()
{
    ClearArray(g_hArray);
    g_iRound = 1;
}

public void OnClientConnected(int client)
{
    ga_bIsInChallenge[client] = false;
    ga_bIsInChallengeQueue[client] = false;
    ga_iChallengePartner[client] = -1;
    ga_iCooldown[client] = -1;
    ga_iOldArena[client] = -1;
}

public void OnClientDisconnect(int client)
{
    if (ga_bIsInChallengeQueue[client])
    {
        RemoveFromChallengeQueue(client);
    }
    
    if (ga_bIsInChallenge[client])
    {
        PrintToChatAll("[\x05Multi1v1\x01] \x03%N\x01 has lost their challange against \x03%N\x01!", client, GetClientOfUserId(ga_iChallengePartner[client]));
        ga_bIsInChallenge[GetClientOfUserId(ga_iChallengePartner[client])] = false;
        ga_iChallengePartner[GetClientOfUserId(ga_iChallengePartner[client])] = 0;
    }
    
    ga_bIsInChallenge[client] = false;
    ga_bIsInChallengeQueue[client] = false;
    ga_iChallengePartner[client] = -1;
    ga_iCooldown[client] = -1;
    ga_iOldArena[client] = -1;
}

public Action Event_PlayerDeath(Handle hEvent, const char[] sName, bool bDontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(hEvent, "userid"));
    int attacker = GetClientOfUserId(GetEventInt(hEvent, "attacker"));
    
    if(ga_bIsInChallenge[client])
    {
        PrintToChatAll("[\x05Multi1v1\x01] \x03%N\x01 has lost their challange against \x03%N\x01!", client, attacker);
        ga_bIsInChallenge[client] = false;
        ga_bIsInChallenge[attacker] = false;
        
        ga_iChallengePartner[client] = 0;
        ga_iChallengePartner[attacker] = 0;
        
        ga_iCooldown[client] = g_iRound + gcv_iCooldownAmmount.IntValue;
        ga_iCooldown[attacker] = g_iRound + gcv_iCooldownAmmount.IntValue;
        if (gcv_bBlockRatingChanges.BoolValue)
        {
            Multi1v1_UnblockRatingChanges(client);
            Multi1v1_UnblockRatingChanges(attacker);
        }
    }
}
    
public Action Event_RoundStart(Handle hEvent, const char[] sName, bool bDontBroadcast)
{
    if (GetPlayerCount() >= 4)
    {
        g_bAllowChallenge = true;
    }
    else
    {
        g_bAllowChallenge = false;
    }
}

public Action Event_RoundEnd(Handle hEvent, const char[] sName, bool bDontBroadcast)
{
    g_iRound++;
}

public Action Command_Challenge(int client, int args)
{
    if (!gcv_bPluginEnabled.BoolValue)
    {
        ReplyToCommand(client, "[SM] This plugin is disabled!");
        return Plugin_Handled;
    }
    if (!IsValidClient(client))
    {
        ReplyToCommand(client, "[SM] You must be in-game to use this command!");
        return Plugin_Handled;
    }
    if (ga_bIsInChallenge[client])
    {
        ReplyToCommand(client, "[SM] You are already in a challenge!");
        return Plugin_Handled;
    }
    if (ga_bIsInChallengeQueue[client])
    {
        ReplyToCommand(client, "[SM] You are already in a queue for a challenge!");
        return Plugin_Handled;
    }
    if (!g_bAllowChallenge)
    {
        ReplyToCommand(client, "[SM] There needs to be more than 4 people to use this command!");
        return Plugin_Handled;
    }
    if (ga_iCooldown[client] > g_iRound)
    {
        ReplyToCommand(client, "[SM] You must wait %i round(s) before you challenge again!", ga_iCooldown[client] - g_iRound);
        return Plugin_Handled;
    }
    if (args == 1)
    {
        char sArg1[MAX_TARGET_LENGTH];
        GetCmdArg(1, sArg1, sizeof(sArg1));
        int target = FindTarget(client, sArg1, true, false);
        if (IsValidClient(target))
        {
            if (target != client)
            {
                OpenRequestMenu(target, client);
            }
            else
            {
                ReplyToCommand(client, "[SM] You cannot target yourself!");
            }
        }
    }
    else if (args == 0)
    {
        OpenChallengeMenu(client);
    }
    else
    {
        ReplyToCommand(client, "[SM] Usage : sm_challenge");
        return Plugin_Handled;
    }
    return Plugin_Handled;
}

public void OpenChallengeMenu(int client) 
{ 
    char sDisplayBuffer[128], sInfoBuffer[16], sTitle[64];
    Format(sTitle, sizeof(sTitle), "Select a Player :");
    Menu MainMenu = new Menu(MainMenu_CallBack, MenuAction_Select | MenuAction_End); 
    MainMenu.SetTitle(sTitle); 
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsValidClient(i) && i != client)
        {
            Format(sDisplayBuffer, sizeof(sDisplayBuffer), "%N", i);
            Format(sInfoBuffer, sizeof(sInfoBuffer), "%i", GetClientUserId(i));
            MainMenu.AddItem(sInfoBuffer, sDisplayBuffer);
        }
    }
    DisplayMenu(MainMenu, client, MENU_TIME_FOREVER); 
}

public int MainMenu_CallBack(Menu MainMenu, MenuAction action, int param1, int param2) 
{
    switch (action)
    {
        case MenuAction_Select:
        {
            char sInfo[128];
            GetMenuItem(MainMenu, param2, sInfo, sizeof(sInfo));
            int iTarget = GetClientOfUserId(StringToInt(sInfo));
            if (ga_bIsInChallenge[iTarget])
            {
                ReplyToCommand(param1, "[SM] They are already in a challenge!");
                return;
            }
            if (ga_bIsInChallengeQueue[iTarget])
            {
                ReplyToCommand(param1, "[SM] They are already in a queue for a challenge!");
                return;
            }
            if (ga_bIsInChallenge[param1])
            {
                ReplyToCommand(param1, "[SM] You are already in a challenge!");
                return;
            }
            if (ga_bIsInChallengeQueue[param1])
            {
                ReplyToCommand(param1, "[SM] You are already in a queue for a challenge!");
                return;
            }
            OpenRequestMenu(iTarget, param1);
            PrintToChatAll("[\x05Multi1v1\x01] \x03%N\x01 has challenged \x03%N\x01!", param1, iTarget);
        }
        case MenuAction_End:
        {
            CloseHandle(MainMenu);
        }
    }
}

public void OpenRequestMenu(int reciever, int sender) 
{ 
    char sInfoBuffer[128], sTitle[128];
    Format(sTitle, sizeof(sTitle), "%N Has Challenged You!", sender);
    Menu MainMenu = new Menu(RequestMenu_CallBack, MenuAction_Select | MenuAction_End); 
    MainMenu.SetTitle(sTitle); 
    
    MainMenu.AddItem("", "By Accepting this challenge, you agree that you will ", ITEMDRAW_DISABLED);
    MainMenu.AddItem("", "be placed into a private arena to face your challenger.", ITEMDRAW_DISABLED);
    MainMenu.AddItem("", "", ITEMDRAW_DISABLED);
    
    Format(sInfoBuffer, sizeof(sInfoBuffer), "yes;%i", sender);
    MainMenu.AddItem(sInfoBuffer, "Accept");
    
    Format(sInfoBuffer, sizeof(sInfoBuffer), "no;%i", sender);
    MainMenu.AddItem(sInfoBuffer, "Decline");
    
    DisplayMenu(MainMenu, reciever, 15); 
}

public int RequestMenu_CallBack(Menu MainMenu, MenuAction action, int param1, int param2) 
{
    switch (action)
    {
        case MenuAction_Select:
        {
            char sInfo[128], sTempArray[2][128];
            GetMenuItem(MainMenu, param2, sInfo, sizeof(sInfo));
            ExplodeString(sInfo, ";", sTempArray, 2, sizeof(sTempArray[]));
            int iSender = StringToInt(sTempArray[1]);
            if (StrEqual(sTempArray[0], "yes"))
            {
                if (ga_bIsInChallenge[iSender])
                {
                    ReplyToCommand(param1, "[SM] They are already in a challenge!");
                    return;
                }
                if (ga_bIsInChallengeQueue[iSender])
                {
                    ReplyToCommand(param1, "[SM] They are already in a queue for a challenge!");
                    return;
                }
                if (ga_bIsInChallenge[param1])
                {
                    ReplyToCommand(param1, "[SM] You are already in a challenge!");
                    return;
                }
                if (ga_bIsInChallengeQueue[param1])
                {
                    ReplyToCommand(param1, "[SM] You are already in a queue for a challenge!");
                    return;
                }
                PutInChallengeQueue(StringToInt(sTempArray[1]), param1);
                PrintToChatAll( "[\x05Multi1v1\x01] \x03%N\x01 has accepted \x03%N\x01's challenge!", param1, iSender);
                PrintToChat(param1, "[\x05Multi1v1\x01] \x04You\x01 will be placed into a challenge next round!");
                PrintToChat(iSender, "[\x05Multi1v1\x01] \x04You\x01 will be placed into a challenge next round!");
                
            }
            else
            {
                PrintToChat(iSender, "[\x05Multi1v1\x01] \x03%N \x01has denied \x04your\x01 request!", param1);
            }
        }
        case MenuAction_End:
        {
            CloseHandle(MainMenu);
        }
    }
}

stock void PutInChallengeQueue(int player1, int player2)
{
    if (g_bAllowChallenge)
    {
        ga_bIsInChallengeQueue[player1] = true;
        ga_bIsInChallengeQueue[player2] = true;
        char sBuffer[256];
        int round = g_iRound + gcv_iRoundDelay.IntValue;
        Format(sBuffer, sizeof(sBuffer), "%i;%i;%i", GetClientUserId(player1), GetClientUserId(player2), round);
        PushArrayString(g_hArray, sBuffer);
    }
}

stock void RemoveFromChallengeQueue(int player)
{
    char sBuffer[256];
    for (int i = 0; i < GetArraySize(g_hArray); i++)
    {
        char sTempArray[3][64];
        GetArrayString(g_hArray, i, sBuffer, sizeof(sBuffer));
        ExplodeString(sBuffer, ";", sTempArray, 3, sizeof(sTempArray[]));
        int iUserID1 = StringToInt(sTempArray[0]);
        int iUserID2 = StringToInt(sTempArray[1]);
        int iPlayerUserID = GetClientUserId(player);
        if (iPlayerUserID == iUserID1 || iPlayerUserID == iUserID2)
        {
            RemoveFromArray(g_hArray, i);
            break;
        }
    }
}

public void Multi1v1_OnPostArenaRankingsSet(Handle rankingQueue)
{
    if (g_bAllowChallenge)
    {
        char sBuffer[128], sTempArray[3][128];
        for (int i = 0; i < GetArraySize(g_hArray); i++)
        {
            GetArrayString(g_hArray, i, sBuffer, sizeof(sBuffer));
            ExplodeString(sBuffer, ";", sTempArray, 3, sizeof(sTempArray[]));
            int player1 = GetClientOfUserId(StringToInt(sTempArray[0]));
            int player2 = GetClientOfUserId(StringToInt(sTempArray[1]));
            int round = StringToInt(sTempArray[2]);
            if(round == g_iRound)
            {
                if (IsValidClient(player1) && IsValidClient(player2))
                {
                    if (gcv_bBlockRatingChanges.BoolValue)
                    {
                        Multi1v1_BlockRatingChanges(player1);
                        Multi1v1_BlockRatingChanges(player2);
                    }
                    
                    ga_iOldArena[player1] = FindValueInArray(rankingQueue, player1);
                    ga_iOldArena[player2] = FindValueInArray(rankingQueue, player2);
                    
                    RemoveFromArray(rankingQueue, FindValueInArray(rankingQueue, player1));
                    RemoveFromArray(rankingQueue, FindValueInArray(rankingQueue, player2));
                }
                else
                {
                    ga_bIsInChallenge[player1] = false;
                    ga_bIsInChallenge[player2] = false;
                    ga_bIsInChallengeQueue[player1] = false;
                    ga_bIsInChallengeQueue[player2] = false;
                    RemoveFromArray(g_hArray, i);
                    return;
                }
                int iLastValue = GetArraySize(rankingQueue) % 10;

                switch (iLastValue)
                {
                    case 1, 3, 5, 7, 9:
                    {
                        int iRemainder = GetArrayCell(rankingQueue, GetArraySize(rankingQueue) - 1);

                        RemoveFromArray(rankingQueue, FindValueInArray(rankingQueue, iRemainder));
                        
                        PushArrayCell(rankingQueue, player1);
                        PushArrayCell(rankingQueue, player2);
                        
                        PushArrayCell(rankingQueue, iRemainder);
                    }
                    case 2, 4, 6, 8, 0:
                    {
                        PushArrayCell(rankingQueue, player1);
                        PushArrayCell(rankingQueue, player2);
                    }
                }
                ga_bIsInChallengeQueue[player1] = false;
                ga_bIsInChallengeQueue[player2] = false;
                ga_bIsInChallenge[player1] = true;
                ga_bIsInChallenge[player2] = true;
                
                ga_iChallengePartner[player1] = GetClientUserId(player2);
                ga_iChallengePartner[player2] = GetClientUserId(player1);
                
                PrintToChat(player1, "[\x05Multi1v1\x01] \x04You\x01 are now in a challenge against \x03%N", player2);
                PrintToChat(player2, "[\x05Multi1v1\x01] \x04You\x01 are now in a challenge against \x03%N", player1);
                
                CreateTimer(0.1, Timer_SetClanTag, player1, TIMER_FLAG_NO_MAPCHANGE);
                CreateTimer(0.1, Timer_SetClanTag, player2, TIMER_FLAG_NO_MAPCHANGE);
            }
            else if (round == g_iRound - 1)
            {
                if (IsValidClient(player1) && ga_iOldArena[player1] != -1)
                {
                    RemoveFromArray(rankingQueue, FindValueInArray(rankingQueue, player1));
                    
                    if (ga_iOldArena[player1] >= GetArraySize(rankingQueue))
                    {
                        PushArrayCell(rankingQueue, player1);
                        ga_iOldArena[player1] = -1;
                    }
                    else
                    {
                        ShiftArrayUp(rankingQueue, ga_iOldArena[player1]);
                        SetArrayCell(rankingQueue, ga_iOldArena[player1], player1);
                        ga_iOldArena[player1] = -1;
                    }
                }
                
                if (IsValidClient(player2) && ga_iOldArena[player2] != -1)
                {
                    RemoveFromArray(rankingQueue, FindValueInArray(rankingQueue, player2));
                    
                    if (ga_iOldArena[player2] >= GetArraySize(rankingQueue))
                    {
                        PushArrayCell(rankingQueue, player2);
                        ga_iOldArena[player2] = -1;
                    }
                    else
                    {
                        ShiftArrayUp(rankingQueue, ga_iOldArena[player2]);
                        SetArrayCell(rankingQueue, ga_iOldArena[player2], player2);
                        ga_iOldArena[player2] = -1;
                    }
                }
                
                ga_bIsInChallenge[player1] = false;
                ga_bIsInChallenge[player2] = false;
                ga_bIsInChallengeQueue[player1] = false;
                ga_bIsInChallengeQueue[player2] = false;
                RemoveFromArray(g_hArray, i);
            }
            else if (round < g_iRound)
            {
                ga_bIsInChallenge[player1] = false;
                ga_bIsInChallenge[player2] = false;
                ga_bIsInChallengeQueue[player1] = false;
                ga_bIsInChallengeQueue[player2] = false;
                RemoveFromArray(g_hArray, i);
            }
        }
    }
}

public Action Timer_SetClanTag(Handle hTimer, int client)
{
    if (IsValidClient(client))
    {
        CS_SetClientContributionScore(client, -1);
        CS_SetClientClanTag(client, "[CHALLENGE]");
    }
}

stock bool IsValidClient(int client, bool bAllowBots = false, bool bAllowDead = true)
{
    if(!(1 <= client <= MaxClients) || !IsClientInGame(client) || (IsFakeClient(client) && !bAllowBots) || IsClientSourceTV(client) || IsClientReplay(client) || (!bAllowDead && !IsPlayerAlive(client)))
    {
        return false;
    }
    return true;
}

stock int GetPlayerCount()
{
    int iAmmount = 0;
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsValidClient(i))
        {
            iAmmount++;
        }
    }
    return iAmmount;
}
/*
    Change Log
    1.0
        - Initial Release
    1.1
        - Added CVARS
        - Created a shorter command "sm_chal"
    1.2
        - Fixed issue where players could target themselves
    1.2.3
        - Fixed issue where leaving players would glitch out the queue
    1.2.4
        - Cleaned up the code a little bit and hopefully fixed a few errors
*/ 


INSTALLATION:

1. Make sure you are running SourceMod Verson 1.7 or higher
2. Install hl_challenge.smx into the /plugins/ folder inside of sourcemod on your game server
3. Load the plugin manually, or change maps
4. Edit cfg/sourcemod/hl_challenge.cfg to your liking
5. Enjoy!

BUGS:
If you have any issues or bugs then you should report them either on this thread or on our GitHub!



BACKSTORY:
When I first started creating CS:GO servers, I created a Multi-1v1 Server. That server taught me a lot about SourceMod and was my first introduction into SourceMod Plugins/Scripting. This plugin right here, is the first plugin I have ever wanted to make. All of my SourceMod scripting is based around wanting to make this plugin right here! Shout out to Splewis for making this Multi-1v1 mod and a HUGE thanks to the developers of AlliedMods. I love you guys.

Spoiler

DONATE:
If you feel that I have done a good job, please consider supporting me.


SOURCEMOD 1.7+ ONLY
DOWNLOAD : HERE

[headline]

VERSION 1.0:

• Initial Release

VERSION 1.1:

• Added CVARS
• Created a smaller command "sm_chal"

VERSION 1.2:

• Fixed issue where players could challenge themselves

VERSION 1.2.3:

• Fixed issue where leaving players would glitch out the queue

VERSION 1.2.4:

• Cleaned up code a bit and hopefully fixed a few errors

[IMI_Lumi]

You are god! Thank you!

[waylander3]

Can you edit sm-command from !challenge, to !cn or !cg, etc?
Cuz this to large.

[DarkDeviL]

Originally Posted by waylander3 Can you edit sm-command from !challenge, to !cn or !cg, etc? Cuz this to large.

Imagine combinations that could be used for multiple things, that would possibly cause conflicts.

E.g. !rs which is common for "Reset Score", but it could also be used for "Roulette Spin" in gaming-related plugins, and thereby conflict or run at once, etc.

Therefore I would say such short things should be made by each individual server operator (in this case you), and not included in the original plugin.

The better alternative for you would be with a push on one of your buttons, for example "C" for "challenge":

bind C "sm_challenge"

[headline]

Originally Posted by waylander3 Can you edit sm-command from !challenge, to !cn or !cg, etc? Cuz this to large.

Updated.

[JacobThePigeon]

When you challenge yourself, it breaks the plugin and leads to players having 3 people in 1 arena the following rounds.

Please remove the function to challenge yourself, and maybe something to print in chat saying something along the lines of:

"Silly you! You can't challenge yourself!"

-Pigeon

[headline]

Originally Posted by JacobThePigeon When you challenge yourself, it breaks the plugin and leads to players having 3 people in 1 arena the following rounds. Please remove the function to challenge yourself, and maybe something to print in chat saying something along the lines of: "Silly you! You can't challenge yourself!" -Pigeon

Updated.

[m_bNightstalker]

good idea

[Chevalier]

Some maps like am_ramps, it will hold someone as a challenger for the whole map, endless rounds inside that map. So pretty much the challenger will be floating in other peoples arena, interfering/trolling.