[Powerlord]

Originally Posted by Leonardo PHP Code: public Action:TF2Items_OnGiveNamedItem( iClient, String:strClassname[], iItemDefinitionIndex, &Handle:hItem ) {     if( StrContains( strClassname, "tf_wearable", false ) == 0 )     {         return Plugin_Handled;     }     return Plugin_Continue; }

That'd also block hats and misc items.

[ReFlexPoison]

BTW Powerlord, your way works correctly. I don't understand why it doesn't work with RemoveWeaponSlot or RemoveAllWeapons

[Powerlord]

Originally Posted by ReFlexPoison BTW Powerlord, your way works correctly. I don't understand why it doesn't work with RemoveWeaponSlot or RemoveAllWeapons

Valve's code doesn't consider them weapons is why.

Instead, they're stored in the m_hMyWearables list-type thingy along with hats and miscs. Sadly, this isn't accessible via the player entity; m_hMyWearables shows up as offset 0. It's a shame, since it's presumably just a list of entity references.

[FlaminSarge]

stock RemovePlayerTarge(client)
{
    new edict = MaxClients+1;
    while((edict = FindEntityByClassname2(edict, "tf_wearable_demoshield")) != -1)
    {
        new idx = GetEntProp(edict, Prop_Send, "m_iItemDefinitionIndex");
        if ((idx == 131 || idx == 406) && GetEntPropEnt(edict, Prop_Send, "m_hOwnerEntity") == client && !GetEntProp(edict, Prop_Send, "m_bDisguiseWearable"))
        {
            AcceptEntityInput(edict, "Kill");
        }
    }
}
stock FindPlayerTarge(client)
{
    new edict = MaxClients+1;
    while((edict = FindEntityByClassname2(edict, "tf_wearable_demoshield")) != -1)
    {
        new idx = GetEntProp(edict, Prop_Send, "m_iItemDefinitionIndex");
        if ((idx == 131 || idx == 406) && GetEntPropEnt(edict, Prop_Send, "m_hOwnerEntity") == client && !GetEntProp(edict, Prop_Send, "m_bDisguiseWearable"))
        {
            return edict;
        }
    }
    return -1;
}
stock GetPlayerWeaponSlot_Wearable(client, slot)
{
    new edict = MaxClients+1;
    if (slot == TFWeaponSlot_Secondary)
    {
        while((edict = FindEntityByClassname2(edict, "tf_wearable_demoshield")) != -1)
        {
            new idx = GetEntProp(edict, Prop_Send, "m_iItemDefinitionIndex");
            if ((idx == 131 || idx == 406) && GetEntPropEnt(edict, Prop_Send, "m_hOwnerEntity") == client && !GetEntProp(edict, Prop_Send, "m_bDisguiseWearable"))
            {
                return edict;
            }
        }
    }
    edict = MaxClients+1;
    while((edict = FindEntityByClassname2(edict, "tf_wearable")) != -1)
    {
        decl String:netclass[32];
        if (GetEntityNetClass(edict, netclass, sizeof(netclass)) && StrEqual(netclass, "CTFWearable"))
        {
            new idx = GetEntProp(edict, Prop_Send, "m_iItemDefinitionIndex");
            if (((slot == TFWeaponSlot_Primary && (idx == 405 || idx == 608)) || (slot == TFWeaponSlot_Secondary && (idx == 57 || idx == 133 || idx == 231 || idx == 444))) && GetEntPropEnt(edict, Prop_Send, "m_hOwnerEntity") == client && !GetEntProp(edict, Prop_Send, "m_bDisguiseWearable"))
            {
                return edict;
            }
        }
    }
    return -1;
}
stock FindEntityByClassname2(startEnt, const String:classname[])
{
    /* If startEnt isn't valid shifting it back to the nearest valid one */
    while (startEnt > -1 && !IsValidEntity(startEnt)) startEnt--;
    return FindEntityByClassname(startEnt, classname);
}

There's others e.g. ones tuned to non-demoshield wearable weapons, but you can figure those out easily.