[Bugsy]

So if they get kicked you expect them to reconnect? Lol.

I made it so anything but drop is excluded

[4ever16]

Oj haha. Didnt think about what i wrote.

But we say if i dont want this function i just dont install DR or what?
Cause i thinking right now people can cheat with this like turn off their PC and then get time out and skip the ban you know.

But i will still use this version cause it has reservation slots function.

I will comeback with a review later when i can test this latest version.

[Bugsy]

You do not have to use the disconnect reason part, I included instructions for how to disable that piece.

[4ever16]

How does the reservation slots work?

Cause i have tested it with few people and it doesnt seem to work.

[Bugsy]

It updates the cvar amx_reservation to match the number of players who have disconnected for less than reconnectmins.

[4ever16]

Have you tested it yourself somehow?
I will check more but it doesnt seem to work for me.

Coming with more updates in somedays!

[Bugsy]

We need to research how the AMX-X reservation system works to see if it allows real-time updating of slots. I just looked at it and it appears using sv_visiblemaxplayers should do the trick. It appears to work as I changed the cvar with the cvar running and the value changes in my CS server list when I modify the value in HLDS. I also set it to 1 with a bot on my server and it wouldn't let me connect. Try the updated code.

[4ever16]

Im just writing so i can remember which version actually worked.
I have tested all and this is the only one which worked for me.
Amxx beta 1.8.3

PHP Code:

#include <amxmodx>
#include <engine>
#include <nvault_util>

new const Version[] = "1.2";

#define MAX_PLAYERS 32

const BanQueueSize = 30;
const Float:EntityInterval = 1.0;
const MinuteSeconds = 60;

enum PlayerData
{
    pdAuthID[ 34 ],
    pdDisconnectTime,
}

new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ] , g_BanQueue[ BanQueueSize ][ PlayerData ];
new g_IgnorePlayers , g_HasAuthorized , g_Entity , g_Vault;
new g_pBanLeavers , g_pReconnectMinutes , g_pBanMinutes , g_pImmunityFlags;

public plugin_init() 
{
    register_plugin( "Ban If No Return" , Version , "bugsy" );
    
    g_pBanLeavers = register_cvar( "binr_enabled" , "1" );
    g_pReconnectMinutes = register_cvar( "binr_reconnectmin" , "5" );
    g_pBanMinutes = register_cvar( "binr_banmins" , "60" );
    g_pImmunityFlags = register_cvar( "binr_immunityflags" , "a" );
    
    LoadQueue();
    
    g_Vault = nvault_open( "ban_if_no_return" );
    nvault_prune( g_Vault , 0 , get_systime() );
    
    g_Entity = create_entity( "info_target" );
    entity_set_string( g_Entity , EV_SZ_classname , "binr_entity" );
    register_think( "binr_entity" , "EntityThink" );
    entity_set_float( g_Entity , EV_FL_nextthink , ( get_gametime() + EntityInterval ) );
}

public plugin_end()
{
    SaveQueue();
    
    call_think( g_Entity );
    nvault_close( g_Vault );
}

public client_authorized( id ) 
{
    new iTimeStamp , szKickMessage[ 96 ] , szFlags[ 26 ];
    
    get_pcvar_string( g_pImmunityFlags , szFlags , charsmax( szFlags ) );
    g_IgnorePlayers |= ( is_user_bot( id ) || is_user_hltv( id )  || ( get_user_flags( id ) & read_flags( szFlags ) ) ? 1 : 0 ) << ( id & 31 ) ;
    
    if ( !( g_IgnorePlayers & ( 1 << ( id & 31 ) ) ) )
    {
        get_user_authid( id , g_pdData[ id ][ pdAuthID ] , charsmax( g_pdData[][ pdAuthID ] ) );
        
        if ( nvault_lookup( g_Vault , g_pdData[ id ][ pdAuthID ] , "" , 0 , iTimeStamp ) )
        {
            if ( iTimeStamp > get_systime() )
            {
                formatex( szKickMessage , charsmax( szKickMessage ) , "^nYou have been banned for %d minutes for not re-joining within %d minutes." , get_pcvar_num( g_pBanMinutes ) , get_pcvar_num( g_pReconnectMinutes ) );   
                message_begin( MSG_ONE , 2 , {0,0,0} , id );     
                write_string( szKickMessage );     
                message_end(); 
            }
            else
            {
                nvault_remove( g_Vault , g_pdData[ id ][ pdAuthID ] );
            }
        }
        else
        {
            RemoveFromBanQueue( id );
        }
    }
    
    g_HasAuthorized |= ( 1 << ( id & 31 ) );
}

public client_disconnect( id ) 
{
    if ( !( g_IgnorePlayers & ( 1 << ( id & 31 ) ) ) && ( g_HasAuthorized & ( 1 << ( id & 31 ) ) ) && get_pcvar_num( g_pBanLeavers ) )
    {
        if ( !AddToBanQueue( id ) )
            set_fail_state( "Ban If No Return: Need to increase queue size." );
    }
    
    g_IgnorePlayers &= ~( 1 << ( id & 31 ) );
    g_HasAuthorized &= ~( 1 << ( id & 31 ) );
}

public EntityThink( iEntity )
{
    if( iEntity == g_Entity ) 
    {
        SetBansInQueue();                        
        entity_set_float( g_Entity , EV_FL_nextthink , ( get_gametime() + EntityInterval ) );
    }
}

bool:AddToBanQueue( id , DisconnectTime=0 )
{
    new bool:bSuccess;
    
    for (new iFindSlot = 0 ; iFindSlot < BanQueueSize ; iFindSlot++ )
    {
        if ( g_BanQueue[ iFindSlot ][ pdAuthID ][ 0 ] == EOS )
        {
            copy( g_BanQueue[ iFindSlot ][ pdAuthID ] , charsmax( g_BanQueue[][ pdAuthID ] ) , g_pdData[ id ][ pdAuthID ] );
            g_BanQueue[ iFindSlot ][ pdDisconnectTime ] = DisconnectTime ? DisconnectTime : get_systime();
            bSuccess = true;
            break;
        }
    }
    
    return bSuccess;
}

RemoveFromBanQueue( id )
{
    for ( new iFindSlot = 0 ; iFindSlot < BanQueueSize ; iFindSlot++ )
    {
        if ( equal( g_BanQueue[ iFindSlot ][ pdAuthID ] , g_pdData[ id ][ pdAuthID ] ) )
        {
            g_BanQueue[ iFindSlot ][ pdAuthID ][ 0 ] = EOS;
            g_BanQueue[ iFindSlot ][ pdDisconnectTime ] = 0;
            break;
        }
    }
}

SetBansInQueue()
{
    new iBanTime;
    
    for ( new iFindSlot = 0 ; iFindSlot < BanQueueSize ; iFindSlot++ )
    {
        if ( g_BanQueue[ iFindSlot ][ pdAuthID ][ 0 ] )
        {
            if ( ( get_systime() - g_BanQueue[ iFindSlot ][ pdDisconnectTime ] ) >= ( get_pcvar_num( g_pReconnectMinutes ) * MinuteSeconds ) )
            {
                nvault_set( g_Vault , g_BanQueue[ iFindSlot ][ pdAuthID ] , "1" );
                nvault_touch( g_Vault , g_BanQueue[ iFindSlot ][ pdAuthID ] , ( iBanTime = get_pcvar_num( g_pBanMinutes ) ) == 0 ? 0 : get_systime() +  ( iBanTime * MinuteSeconds ) );

                g_BanQueue[ iFindSlot ][ pdAuthID ][ 0 ] = EOS;
                g_BanQueue[ iFindSlot ][ pdDisconnectTime ] = 0;
            }
        }
    }
}

LoadQueue()
{
    new iVault , pData[ _:PlayerData ] , iPos , iCount , iItems , iTimeStamp , szKey[ 9 ];
    
    if ( ( iVault = nvault_util_open( "ban_if_no_return" ) ) )
    {
        iCount = nvault_util_count( iVault );
        
        for ( new iEntry = 0 ; iEntry < iCount ; iEntry++ )
        {
            iPos = nvault_util_read_array( iVault , iPos , szKey , charsmax( szKey ) , pData , sizeof( pData ) , iItems , iTimeStamp );
            
            if ( equal( szKey , "BanQueue" ) )
            {
                copy( g_pdData[ 0 ][ pdAuthID ] , sizeof( g_pdData[][ pdAuthID ] ) , pData[ _:pdAuthID ] );
                g_pdData[ 0 ][ pdDisconnectTime ] = pData[ _:pdDisconnectTime ];
                AddToBanQueue( 0 , g_pdData[ 0 ][ pdDisconnectTime ] );
            }
        }
    }
}

SaveQueue()
{
    new szKey[ 12 ] , iSlotIndex , pData[ _:PlayerData ];
    
    copy( szKey , charsmax( szKey ) , "BanQueue" );
    
    for ( new iSlot = 0 ; iSlot < BanQueueSize ; iSlot++ )
    {
        if ( g_BanQueue[ iSlot ][ pdDisconnectTime ] )
        {
            copy( pData[ _:pdAuthID ] , charsmax( pData[ pdAuthID ] ) , g_BanQueue[ iSlot ][ pdAuthID ] );
            pData[ _:pdDisconnectTime ] = g_BanQueue[ iSlot ][ pdDisconnectTime ];
            
            num_to_str( iSlotIndex++ , szKey[ 8 ] , charsmax( szKey ) - 8 );
            nvault_set_array( g_Vault , szKey , pData , sizeof( pData ) );
            nvault_touch( g_Vault , szKey , 1 );
        }
    }
} 


[4ever16]

Bugsy i have analized the plugin for a long time and started using it again it working good. The last code i posted atleast.

But i have a small problem.
When people have auto join function and like 3 people try to connect then 1 get succesfully connected and the other ones tries to connect but it says server full.
For those 2 connection is counted and they get banned for no reason. Just cause they allmost connected but got ''SERVER FULL'' message. You know like who has the fastest internet get the lucky one but those other ones still tries to connect and are counted as if they were connected. I hop you understand what i mean.

Only dead and alive players should be counted.
Or like you need to be connected atleast x minutes for the plugin to count you.
I think the last idea is better x minutes to be counted as connected its seems more safe proof.

And if possible without using other plugins. Cause i like stuff clean all in one.

Also if its possible without other plugins...
Can you add like timeleft for ban in ban reason?
Cause when people try reconnect it allways say like banned 4 days.
So if i try to join 2 days later it still says banned 4 days but it actually 2 days left for ban to expire.
Not a biggy but so that players knows exactly how much time its left, cause avarage human brain IQ is very low.
Its minutes not days i wrote an example only.
But if this needs another plugin then no its not needed then.

[Hectik17]

Those extra fetures would be a great adition. If anyone could implement them!! Thanks