[PinHeaDi]

So, I need a plugin that will give a random number of credits (1-100) every fifth round to a random player in server.

[Nexicon]

Nice idea! Would love to see that too

[xines]

Mixed this together, give it a try.

Spoiler

PHP Code:

#include <sourcemod>
#include <store>

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
}

public Action Event_RoundStart(Event event, const char[] name, bool dontBroadcast)
{
    static int roundcount;
    if(++roundcount >= 5)
    {
        int randomclient = GetRandomClient();
        if(IsValidClient(randomclient))
        {
            int randomcredits = GetRandomInt(1, 100);
            Store_SetClientCredits(randomclient, Store_GetClientCredits(randomclient) + randomcredits);
            PrintToChatAll("%N got %i random credits!", randomclient, randomcredits);
        }
        roundcount = 0;
    }
    
    return Plugin_Continue;
}

int GetRandomClient()
{
    //Clear variables 
    int iCount = 0;
    int[] clients = new int[MaxClients+1];
    
    //Do loop and return selected client
    for (int i = 1; i <= MaxClients; i++)
        if(IsValidClient(i)) clients[iCount++] = i;
    
    return (iCount == 0) ? -1 : clients[GetRandomInt(0, iCount-1)];
}

stock bool IsValidClient(int client)
{
    return (1 <= client <= MaxClients && IsClientInGame(client));
} 


[PinHeaDi]

That seemed to worked, I edited it with my needs.

[Nexicon]

Originally Posted by xines Mixed this together, give it a try. Spoiler PHP Code: #include <sourcemod> #include <store> public void OnPluginStart() {     HookEvent("round_start", Event_RoundStart); } public Action Event_RoundStart(Event event, const char[] name, bool dontBroadcast) {     static int roundcount;     if(++roundcount >= 5)     {         int randomclient = GetRandomClient();         if(IsValidClient(randomclient))         {             int randomcredits = GetRandomInt(1, 100);             Store_SetClientCredits(randomclient, Store_GetClientCredits(randomclient) + randomcredits);             PrintToChatAll("%N got %i random credits!", randomclient, randomcredits);         }         roundcount = 0;     }          return Plugin_Continue; } int GetRandomClient() {     //Clear variables      int iCount = 0;     int[] clients = new int[MaxClients+1];          //Do loop and return selected client     for (int i = 1; i <= MaxClients; i++)         if(IsValidClient(i)) clients[iCount++] = i;          return (iCount == 0) ? -1 : clients[GetRandomInt(0, iCount-1)]; } stock bool IsValidClient(int client) {     return (1 <= client <= MaxClients && IsClientInGame(client)); }

Does this work to Store by Zephyrus?

[xines]

Originally Posted by Nexicon Does this work to Store by Zephyrus?

Yes.

[PinHeaDi]

Originally Posted by Nexicon Does this work to Store by Zephyrus?

I use it with another shop, but yes it will. Marked as solved anyways.