[Dragos]

hi, a friend told me if I can make a respawn event, and... I make it but I don't know if it will work
Can somebody tell if I make it correct?

the hlds don't work for me anymore

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

new start,
stop,
h,
m

new bool: activate[33];

public plugin_init()
{
    register_plugin("Rspawn Event", "1.0", "Deza")
    
    start = register_cvar( "vip_start", "20" );
    stop = register_cvar( "vip_end", "23" )
    RegisterHam(Ham_Spawn, "player", "fwSpawned", 1);
    RegisterHam(Ham_Killed, "player", "fwKilled", 1);

    
    set_task( 60.0, "check", _, _, _, "b" );
    
}

public fwSpawned(id)
{
      if (activate [id]) 
      if (is_user_alive(id))
            remove_task(id);
}   
 


public fwKilled(id)
{     
      if (activate [id])
      if (!task_exists(id))
            set_task(150.0, "Respawn", id);
}

public Respawn(id)
{  
      if (activate [id])
      if (!is_user_alive(id))
            ExecuteHamB(Ham_CS_RoundRespawn, id);
}    

public client_putinserver(id)
{
    check(id)
}
public check(id)
{
    
    time( h, m, _ );
    
    if(h >= get_pcvar_num( start ) && h < get_pcvar_num( stop ))
    {        
            activate [id] = true;
        }
    else if(h < get_pcvar_num( start ) || h >= get_pcvar_num( stop ))
    {
        activate [id] = false
        }
    } 


[LearninG]

I didn't understand exactly what are you trying to do. what vip_stop , vip_start stands for ? what is m , h...explain more about what your trying to do.

[Dragos]

you know it's a event VIP free plugin on this forum and i copy hes date and modify it to respawn event

[LearninG]

dude , we can't read your mind ! explain what you need , not what you did.

[SHIELD755]

As much i understand what he wanted is that on his free vip time , he wanted to respawn the player who are killed in that period of that vip time , something like deathmatch , respawning player

[AmXDusT]

Hi, try this out:

PHP Code:

#include <amxmodx>
#include <hamsandwich>

#if AMXX_VERSION_NUM < 183
    #define client_disconnected client_disconnect
#endif 

new HamHook:HamKilled, HamHook:HamSpawn
new bool:is_active

new p_start, p_stop, p_time

public plugin_init(){
    new VERSION[] = "1.0"

    register_plugin("Respawn Event", VERSION, "DusT")
    DisableHamForward( HamKilled = RegisterHam(Ham_Killed, "player", "fw_Killed_Post", 1) )
    DisableHamForward( HamSpawn = RegisterHam(Ham_Spawn, "player", "fw_Spawned_Post", 1) )

    p_start = register_cvar("amx_respawn_start", "23")
    p_stop = register_cvar("amx_respawn_stop", "06")
    p_time = register_cvar("amx_respawn_time", "15")

    CheckRespawnToggle()
    set_task( 600.0, "CheckRespawnToggle", .flags= "b")
}


public fw_Killed_Post( id )
    if( !task_exists( id ) )
        set_task( get_pcvar_float( p_time ), "Respawn", id );

public fw_Spawned_Post( id )
    if( task_exists( id ) && is_user_alive( id ) )
        remove_task( id );


public client_putinserver( id )
    if( is_active && !task_exists( id ) && get_user_team( id ) != 0 && get_user_team( id ) != 3 )
        set_task( get_pcvar_float( p_time ), "Respawn", id );

public client_disconnected( id )
    if( task_exists( id ) )
        remove_task( id );

public Respawn( id )
    if( is_active && !is_user_alive( id ) )
            ExecuteHamB( Ham_CS_RoundRespawn, id );


public CheckRespawnToggle(){
    new h
    time( h );
    is_active = get_pcvar_num( p_start ) < get_pcvar_num( p_stop )? get_pcvar_num( p_start ) <= h < get_pcvar_num( p_stop ):( get_pcvar_num( p_start ) <= h || h < get_pcvar_num( p_stop ) )
    if( is_active ){
        EnableHamForward( HamKilled )
        EnableHamForward( HamSpawn )
    } 
    else{
        DisableHamForward( HamKilled )
        DisableHamForward( HamSpawn )
    }
}