[reinert]

- TITLE -

How to do that ?

[jim_yang]

orpheu, two way
1. jump cross the code of resetting team scores (efficient)
2. save scores, hook round restart, set it back. (less efficient than #1)

[reinert]

What you mean with first method ?

[jim_yang]

find the asm codes which do the reset stuff, mempatch a jmp bytes before it.

[reinert]

Found this: g_OfSwapAllPlayers
Which swaps player teams and swaps team scores, but after swaping, people still got weapons they had, money they had

[Arkshine]

You want only team scores ? Because there are others things resetted.

[reinert]

Yeah I need to switch teams, switch team scores, then do restart, set scores back.

[Arkshine]

You can test that.
Unzip in amxmodx/ directory.

What it does :

1/ Hook when a round restart is triggered
2/ Retrieve current team scores
3/ Block coming TeamScore message (because it's updated right away)
4/ Switch team scores
5/ Update scores on scoreboard.

PHP Code:

#include <amxmodx>
#include <orpheu>
#include <orpheu_memory>

/*
    │ PLUGIN
*/
    new const PluginName   [] = "Switch Team Score On Restart";
    new const PluginVersion[] = "1.0";
    new const PluginAuhtor [] = "Arkshine";

/*
    | RESTART HANDLING
*/
    enum GameRulesMembers
    {
        m_iNumTerroristWins,
        m_iNumCTWins,
        m_bCompleteReset,
        m_bFirstConnected,
    };

    new const GameRulesMI[ GameRulesMembers ][] =
    {
        "m_iNumTerroristWins",
        "m_iNumCTWins",
        "m_bCompleteReset",
        "m_bFirstConnected"
    };

    new g_pGameRules;

    #define set_mp_pdata(%1,%2)  ( OrpheuMemorySetAtAddress( g_pGameRules, GameRulesMI[ %1 ], 1, %2 ) )
    #define get_mp_pdata(%1)     ( OrpheuMemoryGetAtAddress( g_pGameRules, GameRulesMI[ %1 ] ) )

    new CurrentTerroristWins;
    new CurrentCTWins;
    
    new TeamScoreMessageIndex;
    
    new bool:ReadyToSwitch;


public plugin_precache()
{
    OrpheuRegisterHook( OrpheuGetFunction( "InstallGameRules" ), "OnInstallGameRules", OrpheuHookPost );
}

public OnInstallGameRules()
{
    g_pGameRules = OrpheuGetReturn();
}

public plugin_init()
{
    register_plugin( PluginName, PluginVersion, PluginAuhtor );
    
    handleForward();
}

public plugin_cfg()
{
    TeamScoreMessageIndex = get_user_msgid( "TeamScore" );
}

handleForward()
{
    new OrpheuFunction:handleFunc = OrpheuGetFunctionFromObject( g_pGameRules, "RestartRound", "CGameRules" );

    OrpheuRegisterHook( handleFunc, "OnRestartRound_Pre" , OrpheuHookPre );
    OrpheuRegisterHook( handleFunc, "OnRestartRound_Post" , OrpheuHookPost );
}

public OnRestartRound_Pre( const handleGameRules )
{
    if( get_mp_pdata( m_bCompleteReset ) )
    {
        CurrentTerroristWins = get_mp_pdata( m_iNumTerroristWins );
        CurrentCTWins        = get_mp_pdata( m_iNumCTWins );

        set_msg_block( TeamScoreMessageIndex, BLOCK_SET );

        ReadyToSwitch = true;
    }
}

public OnRestartRound_Post( const handleGameRules )
{
    if( ReadyToSwitch )
    {
        ReadyToSwitch = false;

        set_mp_pdata( m_iNumTerroristWins, CurrentCTWins );
        set_mp_pdata( m_iNumCTWins, CurrentTerroristWins );

        set_msg_block( TeamScoreMessageIndex, BLOCK_NOT );
        updateTeamScore();
    }
}

updateTeamScore()
{
    static OrpheuFunction:handleFunc; handleFunc || ( handleFunc = OrpheuGetFunction( "UpdateTeamScores", "CHalfLifeMultiplay" ) );
    OrpheuCallSuper( handleFunc, g_pGameRules );
} 


[colossus]

Originally Posted by Arkshine You can test that. Unzip in amxmodx/ directory. What it does : 1/ Hook when a round restart is triggered 2/ Retrieve current team scores 3/ Block coming TeamScore message (because it's updated right away) 4/ Switch team scores 5/ Update scores on scoreboard. PHP Code: #include <amxmodx> #include <orpheu> #include <orpheu_memory> /*     │ PLUGIN */     new const PluginName   [] = "Switch Team Score On Restart";     new const PluginVersion[] = "1.0";     new const PluginAuhtor [] = "Arkshine"; /*     | RESTART HANDLING */     enum GameRulesMembers     {         m_iNumTerroristWins,         m_iNumCTWins,         m_bCompleteReset,         m_bFirstConnected,     };     new const GameRulesMI[ GameRulesMembers ][] =     {         "m_iNumTerroristWins",         "m_iNumCTWins",         "m_bCompleteReset",         "m_bFirstConnected"     };     new g_pGameRules;     #define set_mp_pdata(%1,%2)  ( OrpheuMemorySetAtAddress( g_pGameRules, GameRulesMI[ %1 ], 1, %2 ) )     #define get_mp_pdata(%1)     ( OrpheuMemoryGetAtAddress( g_pGameRules, GameRulesMI[ %1 ] ) )     new CurrentTerroristWins;     new CurrentCTWins;          new TeamScoreMessageIndex;          new bool:GameCommencing;     new bool:ReadyToSwitch; public plugin_precache() {     OrpheuRegisterHook( OrpheuGetFunction( "InstallGameRules" ), "OnInstallGameRules", OrpheuHookPost ); } public OnInstallGameRules() {     g_pGameRules = OrpheuGetReturn(); } public plugin_init() {     register_plugin( PluginName, PluginVersion, PluginAuhtor );          handleForward(); } public plugin_cfg() {     TeamScoreMessageIndex = get_user_msgid( "TeamScore" ); } handleForward() {     register_event( "TextMsg", "OnGameCommencing", "a", "2=#Game_Commencing" );     new OrpheuFunction:handleFunc = OrpheuGetFunctionFromObject( g_pGameRules, "RestartRound", "CGameRules" );     OrpheuRegisterHook( handleFunc, "OnRestartRound_Pre" , OrpheuHookPre );     OrpheuRegisterHook( handleFunc, "OnRestartRound_Post" , OrpheuHookPost ); } public OnGameCommencing() {     GameCommencing = true; } public OnRestartRound_Pre( const handleGameRules ) {     if( GameCommencing )     {         GameCommencing = false;         return;     }     if( get_mp_pdata( m_bCompleteReset ) )     {         CurrentTerroristWins = get_mp_pdata( m_iNumTerroristWins );         CurrentCTWins        = get_mp_pdata( m_iNumCTWins );         set_msg_block( TeamScoreMessageIndex, BLOCK_SET );         ReadyToSwitch = true;     } } public OnRestartRound_Post( const handleGameRules ) {     if( ReadyToSwitch )     {         ReadyToSwitch = false;         set_mp_pdata( m_iNumTerroristWins, CurrentCTWins );         set_mp_pdata( m_iNumCTWins, CurrentTerroristWins );         set_msg_block( TeamScoreMessageIndex, BLOCK_NOT );         updateTeamScore();     } } updateTeamScore() {     static OrpheuFunction:handleFunc; handleFunc || ( handleFunc = OrpheuGetFunction( "UpdateTeamScores", "CHalfLifeMultiplay" ) );     OrpheuCallSuper( handleFunc, g_pGameRules ); }

RoundRestart Pre don't work
the score is reset before RoundRestart Pre Hook

the correct way is to get CurrentTerroristWins and CurrentCTWins is in TextMsg

PHP Code:

register_message(get_user_msgid("TextMsg"), "message_textmsg")

public message_textmsg()
{
    static textmsg[22]
    
    get_msg_arg_string(2, textmsg, charsmax(textmsg))
    
    if (equal(textmsg, "#Game_will_restart_in"))
    {
        g_iNumTerroristWins = get_mp_pdata( m_iNumTerroristWins )
        g_iNumCTWins = get_mp_pdata( m_iNumCTWins )
    }
} 


[Arkshine]

No, score is reset inside RestartRound, but I'm not sure why I'm checking against GameCommencing and returning. It's likely wrong, it should not return.
You can remove anything related to GameCommencing, it's not needed. since when round is restarting (so when Game Commencing is triggered), m_bCompleteReset is set to true.