[iceeedr]

Is there a way to pull a line up without leaving a space? when using "^r" there is an "invisible space on the line.

Example:

PHP Code:

i = 0

if(iFile)
{
    new szData[120], szData1[120]

    while(fgets(iFile, szData, charsmax(szData)))
    {
        i++
        switch(szData[0])
        {
            case EOS, ';', '/': continue
            default:
            {
                parse(szData, szData1, charsmax(szData1))

                if(equal(szData1, example))
                {
                    write_file(szConfig, "^r", i-1)                        
                    break
                }
            }
        }
    }

    fclose(iFile)
} 


[Bugsy]

Provide the sample output so I don't need to create a text file, compile your plugin, and test it myself.

Easiest may be just to set the last character to EOS.

[iceeedr]

The result looks like the example below:

PHP Code:

[Sector 1]
blablabla

[Sector2] 


So, in the plugin I detect the line that contains "blablabla" and use "^r"

So the text looks like this:

PHP Code:

[Sector 1]
"invisible space"

[Sector2] 


The line is not "empty" it is as if I gave a space and skipped the line.

[Bugsy]

I am having no issue. Though, I am working on very little.. you have not said what exactly you are trying to do or what the source file contents look like. If you need help, provide the problem at hand, not your troubleshooting.

PHP Code:

public a()
{
    new iFile = fopen( "abc123.txt", "rt" );
    
    new i = 0
    
    if(iFile)
    {
        new szData[120], szData1[120]
    
        while(fgets(iFile, szData, charsmax(szData)))
        {
            i++
            switch(szData[0])
            {
                case EOS, ';', '/': continue
                default:
                {
                    new iz = parse(szData, szData1, charsmax(szData1))
    
                    server_print("[%s]" , szData1)                        
                        
                
                }
            }
        }
    
        fclose(iFile)
    }
} 


Source file

Test line1
Test line2
Test line3
Test line4
Test line5
Test line6
Test line7
Test line8
T1119
T1110
T1111
T1112

Output

PHP Code:

[Test]
[Test]
[Test]
[Test]
[Test]
[Test]
[Test]
[Test]
[T1119]
[T1110]
[T1111]
[T1112] 


[iceeedr]

Originally Posted by Bugsy I am having no issue. Though, I am working on very little.. you have not said what exactly you are trying to do or what the source file contents look like. If you need help, provide the problem at hand, not your troubleshooting. PHP Code: public a() {     new iFile = fopen( "abc123.txt", "rt" );          new i = 0          if(iFile)     {         new szData[120], szData1[120]              while(fgets(iFile, szData, charsmax(szData)))         {             i++             switch(szData[0])             {                 case EOS, ';', '/': continue                 default:                 {                     new iz = parse(szData, szData1, charsmax(szData1))                          server_print("[%s]" , szData1)                                                                                   }             }         }              fclose(iFile)     } }  Source file Test line1 Test line2 Test line3 Test line4 Test line5 Test line6 Test line7 Test line8 T1119 T1110 T1111 T1112 Output PHP Code: [Test] [Test] [Test] [Test] [Test] [Test] [Test] [Test] [T1119] [T1110] [T1111] [T1112]

I'll be as clear as possible, because I don't think you understand.

Let's use the function below as a test to remove an admin for example, after finding the line with steamid I remove it ok?

PHP Code:

public RemoveAdminHandler(id)
{
    get_user_authid(g_AdminTarget[id], playerinfo, charsmax(playerinfo));

    new szConfig[MAX_FMT_LENGTH]
    get_configsdir(szConfig, charsmax(szConfig))
    add(szConfig, charsmax(szConfig), "/users.ini")

    new iFile = fopen(szConfig, "rt")

    i = 0

    if(iFile)
    {
        new szData[120], szData1[120]

        while(fgets(iFile, szData, charsmax(szData)))
        {
            i++
            switch(szData[0])
            {
                case EOS, ';', '/'. '[': continue
    
                default:
                {
                    parse(szData, szData1, charsmax(szData1))

                    if(equal(szData1, playerinfo))
                    {
                        write_file(szConfig, "^r", i-1)
                        server_cmd("amx_reloadadmins")
                        break
                    }
                }
            }
        }

        fclose(iFile)
    }

    return PLUGIN_HANDLED
} 


In the attachment I put user.ini (which is the test before deletion) and users - after.ini (which is after removing the line), notice that in the 1st line of the "after" file there is an "invisible" space.

[Bugsy]

I would change your approach. Create an entirely new temp file with lines that should be there and when done, delete the original and do a rename on the temp. Backup your users.ini beforehand.

PHP Code:

public RemoveAdminHandler( id ) 
{
    get_user_authid(g_AdminTarget[id], playerinfo, charsmax(playerinfo));

    new szConfigTemp[MAX_FMT_LENGTH];
    new szConfig[MAX_FMT_LENGTH];
    get_configsdir(szConfig, charsmax(szConfig))
    add(szConfig, charsmax(szConfig), "/users.ini")
    add(szConfigTemp, charsmax(szConfigTemp), "/usersTemp.ini");
    
    new iFile = fopen(szConfig, "rt")
    
    if(iFile)
    {
        new szData[120], szData1[120]

        while(fgets(iFile, szData, charsmax(szData)))
        {
            switch(szData[0])
            {
                case EOS, ';', '/', '[': write_file(szConfigTemp, szData)
                default:
                {
                    parse(szData, szData1, charsmax(szData1))
                    
                    if(!equal(szData1, playerinfo))
                    {
                        write_file(szConfigTemp, szData1)
                    }
                }
            }
        }

        fclose(iFile)
    }
    

    delete_file( szConfig );
    rename_file( szConfigTemp , szConfig , 1 );

    server_cmd("amx_reloadadmins")

    return PLUGIN_HANDLED
} 


[fysiks]

Calling it an "invisible" space is redundant because it's just the regular space character (0x20), what you get when you press your space bar.

When I use:

PHP Code:

write_file("test.txt", "^r", 2) 


on this file:

hello
world
good
bye

I get:

hello
world

bye

Also, the fact that you're trying to edit a file with write_file() while that same file is open with fopen() is a problem in general (I'm not sure if AMX Mod X has any safe guards in place to prevent bad behavior when you do this).

[iceeedr]

Our worst enemy is fatigue, taking into account all the help and even what was punctuated by the fysiks, we arrived at the code below which is apparently functional, thanks.

PHP Code:

new szConfigTemp[MAX_FMT_LENGTH];
new szConfig[MAX_FMT_LENGTH];
get_configsdir(szConfig, charsmax(szConfig))
add(szConfig, charsmax(szConfig), "/users.ini")
add(szConfigTemp, charsmax(szConfigTemp), "/usersTemp.ini");

new iFile = fopen(szConfig, "r")
new iFile2 = fopen(szConfigTemp, "w")
if(iFile && iFile2)
{
    new szData[120], szData1[120]

    while(fgets(iFile, szData, charsmax(szData)))
    {
            switch(szData[0])
            {
                case EOS, ';', '/', '[': fputs(iFile2, szData)
                default:
                {
                    parse(szData, szData1, charsmax(szData1))

                    if(!equal(szData1, playerinfo))
                    {
                        fputs(iFile2, szData)
                    }
                }
            }
    }

    fclose(iFile)
    fclose(iFile2)
}

delete_file( szConfig );
rename_file( szConfigTemp , szConfig , 1 ); 


[Bugsy]

Cool, pretty much the proper way to code what I provided.

[iceeedr]

Originally Posted by Bugsy Cool, pretty much the proper way to code what I provided.

I am sorry because even though I am able to write and read English fluently, sometimes I do not understand when the phrase is sarcasm or real, so I will understand it as a compliment. If not, I apologize because the credit is yours and the fysiks for the help, thank you.