[jonny1990]

Hello! looking for a plugin, when the team won the round, the screen turns red or blue depending on which team won CT, TT as in the screenfade effect

[ZaX]

#include <amxmodx>

#define CT 1
#define T 2

new g_iWinnerTeam

public plugin_init()
{
    register_logevent("CTWin", 6, "3=CTs_Win", "3=All_Hostages_Rescued")
    register_logevent("TWin" , 6, "3=Terrorists_Win", "3=Target_Bombed")
}

public CTWin()
{
    g_iWinnerTeam = CT;
    ScreenFadeAll();
}

public TWin()
{
    g_iWinnerTeam = T;
    ScreenFadeAll();
}

public ScreenFadeAll()
{
    switch(g_iWinnerTeam)
    {
        case CT: ScreenFade(0 , 3.0, 0, 0, 255 , 50);
        case T: ScreenFade(0 , 3.0, 255, 0, 0 , 50);
    }
}

stock ScreenFade(plr, Float:fDuration, red, green, blue, alpha)
{
    new i = plr ? plr : get_maxplayers();
    if( !i )
    {
        return 0;
    }
    
    message_begin(plr ? MSG_ONE : MSG_ALL, get_user_msgid( "ScreenFade"), {0, 0, 0}, plr);
    write_short(floatround(4096.0 * fDuration, floatround_round));
    write_short(floatround(4096.0 * fDuration, floatround_round));
    write_short(4096);
    write_byte(red);
    write_byte(green);
    write_byte(blue);
    write_byte(alpha);
    message_end();
    
    return 1;
}

[DruGzOG]

PHP Code:

//-=CVARS=-/////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////
//win_both_teams <0|1>
//0 = only winning team is screen faded of team winner's color
//1 = both teams are screen faded of team winner's color

//win_fade_color_t <red> <green> <blue> <alpha>
//The fade color for when terrorists win
//Set alpha to 0 to not show any color
//
//win_fade_color_ct <red> <green> <blue> <alpha>
//The fade color for when counter-terrorists win
//Set alpha to 0 to not show any color
//
//win_fade_time_t <seconds>
//The time of the fade color on the screen for when terrorists win
//Set time to 0 to not show any color
//
//win_fade_time_ct <seconds>
//The time of the fade color on the screen for when counter-terrorists win   
//Set time to 0 to not show any color                                        
//                                                                          
////////////////////////////////////////////////////////////////////////////

#include < amxmodx >
#include < cstrike >

#define FFADE_IN 0x0000
#define FFADE_OUT 0x0001

// the fade type for the color
// FFADE_IN goes from color to normal
// FFADE_OUT goes from normal to color
#define FADE_TYPE FFADE_OUT

new pCvar_BothTeams;
new pCvar_Color[ CsTeams ];
new pCvar_Time[ CsTeams ];

new g_iMsgId_ScreenFade;

public plugin_init( ) {
    register_plugin( "Round End Fade Color", "0.0.1", "Exolent" );
    
    register_event( "SendAudio", "EventTWin", "a", "2=%!MRAD_terwin" );
    register_event( "SendAudio", "EventCTWin", "a", "2=%!MRAD_ctwin" );
    register_event( "SendAudio", "EventCTWin", "a", "2&%!MRAD_ROUNDDRAW")
    register_event( "SendAudio", "EventTWin", "a", "2&%!MRAD_ROUNDDRAW" )
    
    pCvar_BothTeams = register_cvar( "win_both_teams", "1" );
    pCvar_Color[ CS_TEAM_T ] = register_cvar( "win_fade_color_t", "255 255 255 255" );
    pCvar_Color[ CS_TEAM_CT ] = register_cvar( "win_fade_color_ct", "255 255 255 255" );
    pCvar_Time[ CS_TEAM_T ] = register_cvar( "win_fade_time_t", "5" );
    pCvar_Time[ CS_TEAM_CT ] = register_cvar( "win_fade_time_ct", "5" );
    
    g_iMsgId_ScreenFade = get_user_msgid( "ScreenFade" );
}

public EventTWin( ) {
    HandleRoundEnd( CS_TEAM_T );
}

public EventCTWin( ) {
    HandleRoundEnd( CS_TEAM_CT );
}

HandleRoundEnd( CsTeams:iWinner ) {
    new iSeconds = get_pcvar_num( pCvar_Time[ iWinner ] );
    if( !iSeconds ) {
        return;
    }
    
    new szColor[ 16 ];
    get_pcvar_string( pCvar_Color[ iWinner ], szColor, 15 );
    
    new szRed[ 4 ], szGreen[ 4 ], szBlue[ 4 ], szAlpha[ 4 ];
    parse( szColor, szRed, 3, szGreen, 3, szBlue, 3, szAlpha, 3 );
    
    new iAlpha = str_to_num( szAlpha );
    if( !iAlpha ) {
        return;
    }
    
    new iRed = str_to_num( szRed );
    new iGreen = str_to_num( szGreen );
    new iBlue = str_to_num( szBlue );
    
    new iUnits = clamp( ( iSeconds * ( 1 << 12 ) ), 0, 0xFFFF );
    
    new iPlayers[ 32 ], iNum;
    if( get_pcvar_num( pCvar_BothTeams ) ) {
        get_players( iPlayers, iNum );
    } else {
        get_players( iPlayers, iNum, "e", iWinner == CS_TEAM_T ? "TERRORIST" : "CT" );
    }
    
    for( new i = 0; i < iNum; i++ ) {
        message_begin( MSG_ONE_UNRELIABLE, g_iMsgId_ScreenFade, _, iPlayers[ i ] );
        write_short( iUnits );
        write_short( iUnits );
        write_short( FADE_TYPE );
        write_byte( iRed );
        write_byte( iGreen );
        write_byte( iBlue );
        write_byte( iAlpha );
        message_end( );
    }
} 


[jonny1990]

Originally Posted by DruGzOG "255 255 255 255"

why are there four settings in rgb color

[+ARUKARI-]

It is RGBA color. The last one is an alpha value.

[jonny1990]

all thanks

[DruGzOG]

Originally Posted by jonny1990 why are there four settings in rgb color

Originally Posted by +ARUKARI- It is RGBA color. The last one is an alpha value.

As mentioned, there will be always.

I would recommend this to get an idea. https://www.hexcolortool.com/#181051