[einsfuhrer]

Hay, is there any plugin that makes the bans you get when you get vote kicked added to Sourcebans instead? When you get vote kicked you get a ban for like 15 minutes and I would like to have it on Sourcebans for 15 minutes instead.

If it doesn’t exists that would be a cool thing to have, if someone is willing to code it, I would really appreciate it. Thanks in advance!

[freak.exe_uLow]

Originally Posted by einsfuhrer Hay, is there any plugin that makes the bans you get when you get vote kicked added to Sourcebans instead? When you get vote kicked you get a ban for like 15 minutes and I would like to have it on Sourcebans for 15 minutes instead. If it doesn’t exists that would be a cool thing to have, if someone is willing to code it, I would really appreciate it. Thanks in advance!

Working with:
Sourcebans++

https://forums.alliedmods.net/showthread.php?p=1778032

[einsfuhrer]

I don't mean a menu. I mean the default votekick system. "Esc>Start A Vote>Votekick". That those bans, instead of saving in "cfg/banned_user.cfg", it is being added to SourceBans instead.

Is there a plugin for that? Or is someone willing to code it?

[dustinandband]

This will probably work. I don't have a test server with sourcebans installed - but I thought that the default ban command would add a ban to sourcebans automatically - if not you'd just need to replace the 'BanClient' part with one of the functions from the sourcebans include file.

Spoiler

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "Ban on vote kick",
    author      = "dustin",
    description = "",
    version     = "0.0.0",
    url         = ""
};

public void OnPluginStart()
{
    HookEvent("player_disconnect", playerDisconnect, EventHookMode_Pre);
}

public Action playerDisconnect(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    if ( 0 < client <= MaxClients)
    {
        if (IsClientInGame(client) && !IsFakeClient(client))
        {
            char sReason[52];
            GetEventString(event, "reason", sReason, sizeof(sReason));
            
            if (StrContains(sReason, "Kicked by Console", false) != -1)
            {
                BanClient(client, 15, BANFLAG_AUTO, "[SM] Vote kicked from server.", "[SM] Vote kicked from server.");
            }
        }
    }
    
    return Plugin_Continue;
} 


[einsfuhrer]

Thanks, I will take a look and test it later on. I will message the results here

[einsfuhrer]

Originally Posted by dustinandband This will probably work. I don't have a test server with sourcebans installed - but I thought that the default ban command would add a ban to sourcebans automatically - if not you'd just need to replace the 'BanClient' part with one of the functions from the sourcebans include file. Spoiler PHP Code: #include <sourcemod> #pragma semicolon 1 #pragma newdecls required public Plugin myinfo = {     name        = "Ban on vote kick",     author      = "dustin",     description = "",     version     = "0.0.0",     url         = "" }; public void OnPluginStart() {     HookEvent("player_disconnect", playerDisconnect, EventHookMode_Pre); } public Action playerDisconnect(Event event, const char[] name, bool dontBroadcast) {     int client = GetClientOfUserId(GetEventInt(event, "userid"));     if ( 0 < client <= MaxClients)     {         if (IsClientInGame(client) && !IsFakeClient(client))         {             char sReason[52];             GetEventString(event, "reason", sReason, sizeof(sReason));                          if (StrContains(sReason, "Kicked by Console", false) != -1)             {                 BanClient(client, 15, BANFLAG_AUTO, "[SM] Vote kicked from server.", "[SM] Vote kicked from server.");             }         }     }          return Plugin_Continue; }

I got banned on the server, for 15 minutes, but didnt get added on Sourcebans. However, the thing Sourceban is using is BanClient (Check here: https://github.com/sbpp/sourcebans-p...g/sbpp_main.sp search for "BanClient).

So I get banned but not added to Sourcebans while Sourcebans and this plugin is using the same way to ban. Is this something you can fix?

[dustinandband]

if this doesn't work add me so we can get it working (discord: dustin#9028 ).

needs sourcebanspp.inc to compile
https://github.com/sbpp/sourcebans-p...urcebanspp.inc

Spoiler

PHP Code:

#include <sourcemod>
#include <sourcebanspp>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "Ban on vote kick",
    author      = "dustin",
    description = "",
    version     = "0.0.0",
    url         = ""
};

public void OnPluginStart()
{
    HookEvent("player_disconnect", playerDisconnect, EventHookMode_Pre);
}

public Action playerDisconnect(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    if ( 0 < client <= MaxClients)
    {
        if (IsClientInGame(client) && !IsFakeClient(client))
        {
            char sReason[52];
            GetEventString(event, "reason", sReason, sizeof(sReason));
            
            if (StrContains(sReason, "Kicked by Console", false) != -1)
            {
                SBPP_BanPlayer( 0, client, 15, "[SM] Vote kicked from server.");
            }
        }
    }
    
    return Plugin_Continue;
} 


Edit: if it doesn't work then find the sourcebans include file that came with your version of sourcebans and use the ban function.

[einsfuhrer]

Originally Posted by dustinandband if this doesn't work add me so we can get it working (discord: dustin#9028 ). needs sourcebanspp.inc to compile https://github.com/sbpp/sourcebans-p...urcebanspp.inc Spoiler PHP Code: #include <sourcemod> #include <sourcebanspp> #pragma semicolon 1 #pragma newdecls required public Plugin myinfo = {     name        = "Ban on vote kick",     author      = "dustin",     description = "",     version     = "0.0.0",     url         = "" }; public void OnPluginStart() {     HookEvent("player_disconnect", playerDisconnect, EventHookMode_Pre); } public Action playerDisconnect(Event event, const char[] name, bool dontBroadcast) {     int client = GetClientOfUserId(GetEventInt(event, "userid"));     if ( 0 < client <= MaxClients)     {         if (IsClientInGame(client) && !IsFakeClient(client))         {             char sReason[52];             GetEventString(event, "reason", sReason, sizeof(sReason));                          if (StrContains(sReason, "Kicked by Console", false) != -1)             {                 SBPP_BanPlayer( 0, client, 15, "[SM] Vote kicked from server.");             }         }     }          return Plugin_Continue; }

Sorry for a late response, I will try it out and keep in touch if it works or not!

[einsfuhrer]

Worked perfectly!