[ConnorMcLeod]

You may want to use this : http://forums.alliedmods.net/showpos...1&postcount=14

[Gosc]

Can i use this to modify Server commands that are showed for example like this? I've seen that has radio command edited to show with other colors than ^1 can i have an example for how to use it like that... Thanks

How !?
But it is impossible to be two team colors in one string!

[Exolent[jNr]]

Originally Posted by Gosc How !? But it is impossible to be two team colors in one string!

That is white (from con_color "255 255 255"), not the gray you get from spectator color.

[Javivi]

Im trying to get colored messages trough rcon but I've got some problems.

After executing rcon saycolor "^3Just ^1a ^4test" and rcon saycolor2 I got that output:


And both of them should be the same.

Test plugin, using a edited version of the stock :

PHP Code:

#include < amxmodx >

enum _:Colors 
{ 
    DONT_CHANGE, 
    TERRORIST, 
    CT, 
    SPECTATOR 
}

new g_SayText, g_TeamInfo

public plugin_init( )
{
    register_plugin( "Color test", "", "" )
    
    register_srvcmd( "saycolor", "saycolor" )
    register_srvcmd( "saycolor2", "saycolor2" )
    
    g_SayText = get_user_msgid( "SayText" )
    g_TeamInfo = get_user_msgid( "TeamInfo" )
}

// rcon saycolor "^3Just ^1a ^4test"
public saycolor( )
{
    new message[ 192 ]
    read_argv( 1, message, charsmax( message ) )

    client_print( 0, print_chat, "%s", message )
    client_print_color( 0, TERRORIST, "%s", message )
}

// rcon saycolor2
public saycolor2( )
{
    new message[ ] = "^3Just ^1a ^4test"
    
    client_print( 0, print_chat, "%s", message )
    client_print_color( 0, TERRORIST, "%s", message )
}

stock const g_TeamName[Colors][] = 
{
    "UNASSIGNED",
    "TERRORIST",
    "CT",
    "SPECTATOR"
}

stock client_print_color(id, color = DONT_CHANGE, const msg[], any:...)
{
    // check if id is different from 0
    if( id && !is_user_connected(id) )
    {
        return 0;
    }

    if( color > SPECTATOR )
    {
        color = DONT_CHANGE;
    }

    new message[192];
    
    if( color == DONT_CHANGE )
    {
        message[0] = 0x04;
    }
    else
    {
        message[0] = 0x03;
    }

    new params = numargs();
    // Specific player code
    if(id)
    {
        if( params == 3 )
        {
            copy(message[1], charsmax(message)-1, msg);
        }
        else
        {
            vformat(message[1], charsmax(message)-1, msg, 4);
        }

        if( color )
        {
            new team[11]; // store current team so we can restore it
            get_user_team(id, team, charsmax(team));

            // set id TeamInfo in consequence
            // so SayText msg gonna show the right color
            Send_TeamInfo(id, id, g_TeamName[color]);

            // Send the message
            Send_SayText(id, id, message);

            // restore TeamInfo
            Send_TeamInfo(id, id, team);
        }
        else
        {
            Send_SayText(id, id, message);
        }
    } 
    // Send message to all players
    else
    {
        // Figure out if at least 1 player is connected
        // so we don't send useless message if not
        // and we gonna use that player as team reference (aka SayText message sender) for color change
        new players[32], num;
        get_players(players, num, "ch");
        if( !num )
        {
            return 0;
        }

        new dummy = players[0];

        if( params == 3 )
        {
            copy(message[1], charsmax(message)-1, msg);
        }
        else
        {
            vformat(message[1], charsmax(message)-1, msg, 4);
        }

        if( color )
        {
            new team[11];
            get_user_team(dummy, team, charsmax(team));
            Send_TeamInfo(0, dummy, g_TeamName[color]);
            Send_SayText(0, dummy, message);
            Send_TeamInfo(0, dummy, team);
        }
        else
        {
            Send_SayText(0, dummy, message);
        }
    }
    return 1;
}

stock Send_TeamInfo(receiver, id, team[])
{
    message_begin(receiver ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_TeamInfo, .player=receiver);
    write_byte(id);
    write_string(team);
    message_end();
}

stock Send_SayText(receiver, id, message[])
{
    message_begin(receiver ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_SayText, .player=receiver);
    write_byte(id);
    write_string(message);
    message_end();
} 


Any ideas about how I can fix that or get my purpose ?

Thanks

[Exolent[jNr]]

Originally Posted by Javivi Im trying to get colored messages trough rcon but I've got some problems. After executing rcon saycolor "^3Just ^1a ^4test" and rcon saycolor2 I got that output: And both of them should be the same. Any ideas about how I can fix that or get my purpose ? Thanks

You don't understand that ^ are escaped at compile time and not run time.
Therefore, any input string that is not compiled will not recognize ^ as an escape character.
You have to escape the input yourself:

replace_all(input, charsmax(input), "^^3", "^3");

That will replace all "^3" from an input string with the 0x03 character.

[fysiks]

The escape character only works in code not when passed as an argument (it's just plain text at that point).

[Javivi]

Oh, my bad, I didn't knew that ^ was escaped at compile time.

Fixed, thanks.

[isotonic]

[QUOTE=ConnorMcLeod;851160]
DON'T USE STOCK VERSION, SEEMS TO HAVE PROBLEM WITH ML
I think I found workaround. I use that code and have no problems:

PHP Code:

formatex(msg, 127, "%L", LANG_PLAYER, "DICTIONARY_ITEM")
ColorChat(0, GREEN, msg) 


--

Also please explain to me what is it: Pro, Con, 'Module Version' and 'real native'?

[ConnorMcLeod]

Use the module version, or the fake native, i don't support the stock.

[isotonic]

Ok. Could you explain when I should prefer one version to another?