[Doc-Holiday]

I know they dont have the "player" class name is there a specific classname for them?

After some testing This is what i got back from the code below.

Bot Class Name player
Bot Class Name player
Bot Class Name player
Bot Class Name player
Bot Class Name player

PHP Code:

public client_authorized( id )
{    
    if( !gBotsRegistered && is_user_bot( id ) )
    {
        set_task( 0.1, "register_bots", id );
    }
}

public register_bots( id )
{
    if( !gBotsRegistered && is_user_connected( id ) )
    {
        RegisterHamFromEntity( Ham_Spawn, id, "BotSpawn", 1 );
        gBotsRegistered = true;
    }
}

public BotSpawn(id)
{
    new classname[33]
    pev( id, pev_classname, classname, 32 )
    
    client_print(0, print_chat, "Bot Class Name %s", classname);
} 


If thats the case why do i have to register ham from ent ??

[ConnorMcLeod]

Works fine with orpheu but not with ham.

If you are interested, i'm using a multiforward to register bots so you don't have to exec multiple tasks through all plugins that need them.

Plugin then looks like this :

PHP Code:

#include <amxmodx>
#include <hamsandwich>

public plugin_init()
{
    register_plugin("bla","bla","bla")
}

public cz_bot_ham_registerable( id )
{
    RegisterHamFromEntity( Ham_Spawn, id, "BotSpawn", 1 )
}

public BotSpawn( id )
{
    // your code here
} 


[Doc-Holiday]

btw just so ppl dont try this and it doesnt work...

get_pcvar_num(g_pCvarBotQuota).... doesnt exist

[ConnorMcLeod]

Ops, fixed.

[Doc-Holiday]

Originally Posted by ConnorMcLeod Ops, fixed.

Question you dont have to "include" anything for your plugin it just executes all forwards in any plugin we use using that name?

[ConnorMcLeod]

I don't remember if i had to put (or not) :

forward cz_bot_ham_registerable(index);

at top of .sma, that would be equivalent to include something.


I don't think it is needed for forwards though.

[yokomo]

Hi, sorry revive this old thread, Connor i've bug on your API posted on no 2, Server crash when got another plugin using the same register_message

PHP Code:

register_message(get_user_msgid("TextMsg"), "Message_TextMsg") 


I have a plugin that using same function too. To solve this i need to comment on your API:

PHP Code:

//unregister_message(iMsgId, g_iMhTextMsg) 


Just want to know. Is that necessary to unregister back that message?

[ConnorMcLeod]

No, you can even replace register_message with register_event.

PHP Code:

#include <amxmodx>

#define VERSION "0.0.5"
#define PLUGIN "Ham Register Cz Bots"

new g_pCvarBotJoinAfterPlayer, g_pCvarBotQuota

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

    g_pCvarBotQuota = get_cvar_pointer("bot_quota")
    if( !g_pCvarBotQuota )
    {
        set_fail_state("Mode is not Condition Zero")
    }
    g_pCvarBotJoinAfterPlayer = get_cvar_pointer("bot_join_after_player")

    state deactivated
}

public client_putinserver( id ) <send_forward> {}
public client_putinserver( id ) <deactivated>
{
    if( is_user_bot(id) && get_pcvar_num(g_pCvarBotQuota) )
    {
        if( get_pcvar_num(g_pCvarBotJoinAfterPlayer) )
        {
            new iPlayers[32], iNum
            get_players(iPlayers, iNum, "ch")
            if( !iNum )
            {
                return
            }
        }

        register_event("TextMsg", "Event_TextMsg", "a")
        state send_forward
    }
}

public Event_TextMsg() <deactivated> {}
public Event_TextMsg() <send_forward>
{
    new szName[32]
    read_data(3, szName, charsmax(szName))
    new iForward = CreateMultiForward("cz_bot_ham_registerable", ET_IGNORE, FP_CELL)
    new iRet
    ExecuteForward(iForward, iRet, get_user_index(szName))
    DestroyForward(iForward)
    
    pause("a")
} 


[yokomo]

Originally Posted by ConnorMcLeod No, you can even replace register_message with register_event. PHP Code: #include <amxmodx> #define VERSION "0.0.5" #define PLUGIN "Ham Register Cz Bots" new g_pCvarBotJoinAfterPlayer, g_pCvarBotQuota public plugin_init() {     register_plugin(PLUGIN, VERSION, "ConnorMcLeod")     g_pCvarBotQuota = get_cvar_pointer("bot_quota")     if( !g_pCvarBotQuota )     {         set_fail_state("Mode is not Condition Zero")     }     g_pCvarBotJoinAfterPlayer = get_cvar_pointer("bot_join_after_player")     state deactivated } public client_putinserver( id ) <send_forward> {} public client_putinserver( id ) <deactivated> {     if( is_user_bot(id) && get_pcvar_num(g_pCvarBotQuota) )     {         if( get_pcvar_num(g_pCvarBotJoinAfterPlayer) )         {             new iPlayers[32], iNum             get_players(iPlayers, iNum, "ch")             if( !iNum )             {                 return             }         }         register_event("TextMsg", "Event_TextMsg", "a")         state send_forward     } } public Event_TextMsg() <deactivated> {} public Event_TextMsg() <send_forward> {     new szName[32]     read_data(3, szName, charsmax(szName))     new iForward = CreateMultiForward("cz_bot_ham_registerable", ET_IGNORE, FP_CELL)     new iRet     ExecuteForward(iForward, iRet, get_user_index(szName))     DestroyForward(iForward)          pause("a") }

Nice, this one works fine with no crash. Thanks.

[Doc-Holiday]

Originally Posted by yokomo Nice, this one works fine with no crash. Thanks.

Ive had issues with mass plugins using this forward... it would continue running and not register the bots... i have been using this method from rage without issue and same load of plugin


http://forums.alliedmods.net/showpos...7&postcount=41