[marcelowzd]

Originally Posted by Bugsy Maybe SQL_ThreadQuery() isn't able to handle an enumerator-sized array that contains string(s). I've personally passed data in the past using the below. Try doing a test, eliminating the string portion of your enumerator and see if it works. If it does, we can probably figure out a workaround. Edit: I just tested it myself and enum sized arrays, that include strings, pass to the callback handler perfectly. PHP Code: enum QueryTypes {     qtPlayerConnected,     qtPlayerDisconnected,     qtGetNewAdmins,     qtGetNewPermAdmins,     qtSetPlayerAsAdmin,     qtRemoveAllAdmins,     qtPruneDatabase,     qtShowStats,     qtShowTop15 } enum _:QueryInfo {     QueryTypes:qiQueryType,     qiPlayerID } new QueryData[ QueryInfo ]; QueryData[ qiQueryType ] = qtPlayerConnected; QueryData[ qiPlayerID ] = id; formatex( g_szBuffer , charsmax( g_szBuffer ) , Query_PlayerConnected , pdData[ id ][ pdAuthID ] ); SQL_ThreadQuery( g_SQLTuple , "QueryHandle" , g_szBuffer , QueryData , sizeof( QueryData ) );

Hi, thanks for the reply. So, i removed the string part and still got wrong values. Also, i reinstalled HLDS (download stuff again with steamcmd) and AMXX just to be sure, but still got wrong values. I'll try in another machine because, honestly, i have no idea what else to try. I'll try tomorrow to do a simple plugin with other values to test more.

[Bugsy]

Make a small test plugin to see if you can get it to work. If you can, then you know it's some coding issue in your plugin and not something wrong with your game/amx-x/modules etc.

[marcelowzd]

PHP Code:

#include < amxmodx >
#include < sqlx >

new Handle:g_hSqlTuple;

enum _:eImportant
{
    INTEGER,
    Float:FLOAT,
    STRING[ 32 ]
};

public plugin_init( )
{
    new const szPlugin[ ] = "Test SQL";
    new const szVersion[ ] = "0.0.1";
    new const szAuthor[ ] = "Test";

    register_plugin( szPlugin, szVersion, szAuthor );

    register_clcmd( "test_sql", "OnSqlTest" );
}

public plugin_precache( )
{
    g_hSqlTuple = SQL_MakeDbTuple( "localhost", "root", "root", "Servidor" );
}

public OnSqlTest( iClient )
{
    new aData[ eImportant ];

    aData[ INTEGER ] = 3;
    aData[ FLOAT ] = 3.0;
    copy( aData[ STRING ], charsmax( aData[ STRING ] ), "MyTest" );

    log_amx( "Let's see --> %i --> %f --> %s", aData[ INTEGER ], aData[ FLOAT ], aData[ STRING ] );

    FunctionTest( aData );

    SQL_ThreadQuery( g_hSqlTuple, "SqlHandler", "SELECT * FROM Tops", aData, sizeof( aData ) );
}

public FunctionTest( aData[ eImportant ] )
{
    log_amx( "Function Test --> %i --> %f --> %s", aData[ INTEGER ], aData[ FLOAT ], aData[ STRING ] );
}

public SqlHandler( iFailState, Handle:hQuery, szError[ ], aData[ eImportant ], iSize )
{
    log_amx( "Sql Handler --> %i --> %f --> %s", aData[ INTEGER ], aData[ FLOAT ], aData[ STRING ] );
} 


and the output...

L 10/08/2019 - 20:06:06: [NewTest.amxx] Let's see --> 3 --> 3.000000 --> MyTest
L 10/08/2019 - 20:06:06: [NewTest.amxx] Function Test --> 3 --> 3.000000 --> MyTest
L 10/08/2019 - 20:06:07: [NewTest.amxx] Sql Handler --> 12 --> 0.000000 -->

Also tried using it like this (same output)

PHP Code:

public SqlHandler( iFailState, Handle:hQuery, szError[ ], aData[ ], iSize )
{
    log_amx( "Sql Handler --> %i --> %f --> %s", aData[ INTEGER ], aData[ FLOAT ], aData[ STRING ] );
} 


UPDATE: Ok so i decided to test it with AMXX 1.8.2 and metamod v1.21p37 and i got interesting results
First is that i received a "Tag Mismatch" warning while compiling the plugin in AMXX 1.8.2 in line aData[ FLOAT ] = 3.0, but the output is more
interesting

L 10/08/2019 - 20:21:13: [NewTest.amxx] Let's see --> 3 --> 3.000000 --> MyTest
L 10/08/2019 - 20:21:13: [NewTest.amxx] Function Test --> 3 --> 3.000000 --> MyTest
L 10/08/2019 - 20:21:13: [NewTest.amxx] Sql Handler --> 1 --> 0.000000 --> est SQL

For some reason, it appears to have taken the plugin's name (well, 90% of it at least)

Just as info, it's a brand new server, AMXX has the package core + cstrike addons and i'm using metamod v1.21p37 for all tests

[Bugsy]

Your query callback is missing the integer error code parameter.

public QueryHandle( FailState , Handle:Query , const Error[] , Errcode , const Data[ QueryInfo ] , DataSize )

[marcelowzd]

Originally Posted by Bugsy Your query callback is missing the integer error code parameter. public QueryHandle( FailState , Handle:Query , const Error[] , Errcode , const Data[ QueryInfo ] , DataSize )

True, stupid error, i'll redo the tests.

[Bugsy]

This has to be the cause, everything else in the test plugin is perfect. Your plugin from the OP is also missing this.

[marcelowzd]

Originally Posted by Bugsy This has to be the cause, everything else in the test plugin is perfect. Your plugin from the OP is also missing this.

You're my hero, it is working, and i'm stupid, but at least it works now, much appreciated.