[N1bey]

Hello guys,

i own a nospread server and i'm tired of leg shots and i really need to find a plugin that make awp 1 shot and i can't find it. Can anyone solve my problem? i just want the awp to deal more damage, not other guns

thanks for everyone that tries to help me !

[PinHeaDi]

PHP Code:

//Pragma
#pragma semicolon 1
#pragma newdecls required

//Sourcemod Includes
#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

public void OnPluginStart()
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            OnClientPutInServer(i);
        }
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)
{
    if (attacker == 0 || attacker > MaxClients)
    {
        return Plugin_Continue;
    }

    int active = GetEntPropEnt(attacker, Prop_Send, "m_hActiveWeapon");

    if (!IsValidEntity(active))
    {
        return Plugin_Continue;
    }

    char sClassname1[32];
    GetEntityClassname(active, sClassname1, sizeof(sClassname1));

    if (StrContains(sClassname1, "weapon_awp") != -1)
    {
        damage *= 1.5;
        return Plugin_Changed;
    }

    return Plugin_Continue;
} 


[N1bey]

thank u so much !