[farawayf]

Hello. Got into a stupid situation.
I can't make the damage top 3 players.
The first place works, on 2 and 3 place a random player takes both places with zero damage.

PHP Code:



#include <sourcemod>
#include <sdktools>

new Damage[65];
new String:DamageP[16] = "dmg_health";



public void OnPluginStart()
{
    HookEvent("player_hurt", hurt, EventHookMode_Post);
    HookEvent("round_end", RoundEnd, EventHookMode_PostNoCopy);
}


public hurt(Handle:event, const String:name[], bool:dontBroadcast)
{
    new dmg = GetClientOfUserId(GetEventInt(event,"attacker"));    
    if (dmg) 
    {
        Damage[dmg] += GetEventInt(event,DamageP);
    }
    
}

public RoundEnd(Handle:event, const String:name[], bool:dontBroadcast)
{
    new first = 0, second = 0, third = 0;
    
    Damage[0] = 0;
    
    
    for (new i = 1; i <= MaxClients; i++)
    if (IsClientInGame(i))
    {
        if (Damage[i] > Damage[first]) first = i;
        else if (Damage[i] == Damage[first]) first = i;    
    }
    
    for (new i = 1; i <= MaxClients; i++)
    if (IsClientInGame(i))
    {
        if (Damage[i] < Damage[first]) second = i;
        else if ((Damage[i] == Damage[second]) && (Damage[second] < Damage[first])) second = i;
    }
    
    for (new i = 1; i <= MaxClients; i++)
    if (IsClientInGame(i))
    {
        if (Damage[i] < Damage[second]) third = i;
        else if ((Damage[i] == Damage[third]) && (Damage[third] < Damage[second])) third = i;
    }
    
    decl String:firstName[257];
    decl String:secondName[257];
    decl String:thirdName[257];
    
    
    GetClientName(first, firstName, 50);
    GetClientName(second, secondName, 50);
    GetClientName(third, thirdName, 50);
    
    PrintToChatAll("1 %s - dmg %i", firstName, Damage[first]);
    PrintToChatAll("2 %s - dmg %i", secondName, Damage[second]);
    PrintToChatAll("3 %s - dmg %i", thirdName, Damage[third]);
    
    for (int i = 1; i <= MaxClients; i++) 
    {
        Damage[i] = 0;
    }        
} 


[impossible_cc]

Not tested but should work fine

PHP Code:

#include <sourcemod>
#include <sdktools>

int Damage[MAXPLAYERS + 1];
#define DamageP "dmg_health"



public void OnPluginStart()
{
    HookEvent("player_hurt", Event_Hurt, EventHookMode_Post);
    HookEvent("round_end", RoundEnd, EventHookMode_PostNoCopy);
}


public void Event_Hurt(Event event, char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("attacker"));    
    if (client)
    {
        Damage[client] += event.GetInt(DamageP);
    }
    
}

public void RoundEnd(Event event, char[] name, bool dontBroadcast)
{
    int first, second, third;
    
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && Damage[i] >= Damage[first])
        {
            first = i;
        }
    }
    
    if(first)
    {
        PrintToChatAll("1 %N - dmg %i", first, Damage[first]);
        
        for (int i = 1; i <= MaxClients; i++)
        {
            if (i != first && IsClientInGame(i) && Damage[i] >= Damage[second])
            {
                second = i;
            }
        }
        
        if(second)
        {
            PrintToChatAll("2 %N - dmg %i", second, Damage[second]);
            
            for (int i = 1; i <= MaxClients; i++)
            {
                if (i != first && i != second && IsClientInGame(i) && Damage[i] >= Damage[third])
                {
                    third = i;
                }
            }
            if(third)
            {
                PrintToChatAll("3 %N - dmg %i", third, Damage[third]);
            }
        }
    }
    
    for (int i = 1; i <= MaxClients; i++) 
    {
        Damage[i] = 0;
    }        
} 


[farawayf]

It works, thank you.