[FatalisDK]

How would I search an entire file (a map bsp in this case) in binary mode, and search for a given string?

[VEN]

Here is the function:

stock contain_binfile(const filename[], const string[], start = 0) {
        new file = fopen(filename, "rb")
        if (!file)
                return -1

        if (start > 0)
                fseek(file, start, SEEK_SET)

        new data, pos = 0, len = strlen(string)
        while (!feof(file)) {
                fread(file, data, BLOCK_CHAR)
                if (data != string[pos])
                        pos = 0
                else if (++pos == len) {
                        new cur = ftell(file)
                        fclose(file)
                        return cur - pos
                }
        }

        fclose(file)

        return -1
}

Here is the usage example:

new pos = 0
while ((pos = contain_binfile(filename, string, pos)) != -1)
        server_print("^"%s^" string position in the ^"%s^" file is %d", string, filename, pos++)
// 

[FatalisDK]

Thanks.

[VEN]

By the way, is your string is related to the entities data?
In this case it's possible to greatly improve a performance.

stock get_bsp_entdata_offset(const filename[], &datasize = 0) {
        new file = fopen(filename, "rb")
        if (!file)
                return -1

        new offset
        fseek(file, 4, SEEK_SET)
        fread(file, offset, BLOCK_INT)
        fread(file, datasize, BLOCK_INT)
        fclose(file)

        return offset
}

// instead of new pos = 0
new pos = get_bsp_entdata_offset(filename)