[Solved] I need help in (player_disconnect)

dr_lex · **Author**

Good time of day
Need help with the player_disconnect event

Little is known about the events themselves
Can someone provide a sample code to study and understand

1. How to find out why a player left the server?
Attempt 1:

Code:

#pragma semicolon 1
#include <sourcemod>
#pragma newdecls required

char sg_log[160];

public void OnPluginStart()
{
    HookEvent("player_disconnect", Event_PlayerDisconnect);
    BuildPath(Path_SM, sg_log, sizeof(sg_log)-1, "logs/hm_disconnect.log");
}

public Action Event_PlayerDisconnect(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));
    if ((client != 0) && !IsFakeClient(client))
    {
        char reason[100];
        event.GetString("reason", reason, sizeof(reason));
        if (StrContains(reason, "self", false) != -1)
        {
            strcopy(reason, sizeof(reason), "self");
            LogToFileEx(sg_log, "self");
        }
        else if (StrContains(reason, "kick", false) != -1)
        {
            strcopy(reason, sizeof(reason), "kick");
            LogToFileEx(sg_log, "Kicked");
        }
        else if (StrContains(reason, "ban", false) != -1)
        {
            strcopy(reason, sizeof(reason), "ban");
            LogToFileEx(sg_log, "ban");
        }
        else if (StrContains(reason, "cheat", false) != -1)
        {
            strcopy(reason, sizeof(reason), "cheat");
            LogToFileEx(sg_log, "cheat");
        }
        else if (StrContains(reason, "error", false) != -1)
        {
            strcopy(reason, sizeof(reason), "error");
            LogToFileEx(sg_log, "error");
        }
        else
        {
            strcopy(reason, sizeof(reason), "???");
            LogToFileEx(sg_log, "???");
        }
     
        char player_name[MAX_NAME_LENGTH];
        event.GetString("name", player_name, sizeof(player_name));
        LogToFileEx(sg_log, "[%s] Disconnect (%s)", player_name, reason);
        if (!dontBroadcast)
        {
            SetEventBroadcast(event, true);
        }
    }
    return Plugin_Continue;
}

Attempt 2:

Code:

#pragma semicolon 1
#include <sourcemod>
#pragma newdecls required

char sg_log[160];

public void OnPluginStart()
{
	HookEvent("player_disconnect", Event_PlayerDisconnect);
	BuildPath(Path_SM, sg_log, sizeof(sg_log)-1, "logs/hm_disconnect.log");
}

public Action Event_PlayerDisconnect(Event event, const char[] name, bool dontBroadcast)
{
	int client = GetClientOfUserId(event.GetInt("userid"));
	if ((client != 0) && !IsFakeClient(client))
	{
		char reason[100];
		event.GetString("reason", reason, sizeof(reason));
		if(StrContains(reason, "connection rejected", false) != -1)
		{
			strcopy(reason, sizeof(reason), "connection rejected");
		}
		else if(StrContains(reason, "timed out", false) != -1)
		{
			strcopy(reason, sizeof(reason), "timed out");
		}
		else if(StrContains(reason, "by console", false) != -1)
		{
			strcopy(reason, sizeof(reason), "by console");
		}
		else if(StrContains(reason, "by user", false) != -1)
		{
			strcopy(reason, sizeof(reason), "by user");
		}
		else if(StrContains(reason, "ping is too high", false) != -1)
		{
			strcopy(reason, sizeof(reason), "ping is too high");
		}
		else if(StrContains(reason, "No Steam logon", false) != -1)
		{
			strcopy(reason, sizeof(reason), "No Steam logon);
		}
		else if(StrContains(reason, "Steam account is being used in another", false) != -1)
		{
			strcopy(reason, sizeof(reason), "Steam account is being used in another");
		}
		else if(StrContains(reason, "Steam Connection lost", false) != -1)
		{
			strcopy(reason, sizeof(reason), "Steam Connection lost");
		}
		else if(StrContains(reason, "This Steam account does not own this game", false) != -1)
		{
			strcopy(reason, sizeof(reason), "This Steam account does not own this game");
		}
		else if(StrContains(reason, "Validation Rejected", false) != -1)
		{
			strcopy(reason, sizeof(reason), "Validation Rejected");
		}
		else if(StrContains(reason, "Certificate Length", false) != -1)
		{
			strcopy(reason, sizeof(reason), "Certificate Length");
		}
		else if(StrContains(reason, "Pure server", false) != -1)
		{
			strcopy(reason, sizeof(reason), "Pure server");
		}
		else
		{
			strcopy(reason, sizeof(reason), "???");
		}
		
		char player_name[MAX_NAME_LENGTH];
		event.GetString("name", player_name, sizeof(player_name));
		LogToFileEx(sg_log, "[%s] Disconnect (%s)", player_name, reason);
		if (!dontBroadcast)
		{
			SetEventBroadcast(event, true);
		}
	}
	return Plugin_Continue;
}

2. How to know player xvid?

Code:

"xuid"        "uint64"    // player xuid

PC Gamer · 11-30-2020 , 01:27 Re: I need help in (player_disconnect)

Here's information on the player disconnect event: https://wiki.alliedmods.net/Generic_...yer_disconnect

The information you want to log is available during the event (player name, steamid, reason for disconnect).

dr_lex · 11-30-2020 , 06:21 Re: I need help in (player_disconnect)

Quote:

Originally Posted by PC Gamer

Here's information on the player disconnect event: https://wiki.alliedmods.net/Generic_...yer_disconnect

New information (in l4d2):

Code:

    "player_disconnect"            // a client was disconnected
    {
        "userid"    "short"        // user ID on server
        "reason"    "string"    // "self", "kick", "ban", "cheat", "error"
        "name"        "string"    // player name
        "xuid"        "uint64"    // player xuid
        "networkid"    "string"    // player network (i.e steam) id
        "bot"        "bool"        // is this a bot
        "reliable"  "1"            // this event is reliable
    }

Quote:

Originally Posted by PC Gamer

The information you want to log is available during the event (player name, steamid, reason for disconnect).

I know, and I want to use "reason" for information about the reason for the player's exit

The hlmod forum gave me this example:

Code:

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("player_disconnect", Event_Disconnect);
}

public void Event_Disconnect(Event event, const char[] name, bool dontBroadcast)
{
    if(event.GetBool("bot")) return;

    static char path[PLATFORM_MAX_PATH], reason[PLATFORM_MAX_PATH], nick[PLATFORM_MAX_PATH], netid[PLATFORM_MAX_PATH];

    if(!path[0]) BuildPath(Path_SM, path, sizeof(path), "logs/hm_disconnect.log");

    event.GetString("name", nick, sizeof(nick));
    event.GetString("networkid", netid, sizeof(netid));
    event.GetString("reason", reason, sizeof(reason));
    LogToFileEx(path, "'%s' (%s) disconnected (reason: '%s')", nick, netid, reason);
}

But it also does not show the reason for the exit in the logs

Code:

L 11/29/2020 - 'dr lex' (STEAM_1:1:**************) disconnected (reason: '')

MAGNAT2645 · *Last edited by MAGNAT2645; 11-30-2020 at 06:39.*

Try to use EventHookMode_Pre:

Code:

HookEvent( "player_disconnect", Event_Disconnect, EventHookMode_Pre );

public Action Event_Disconnect(Event event, const char[] name, bool dontBroadcast)
{
    if(event.GetBool("bot")) return Plugin_Continue;

    static char path[PLATFORM_MAX_PATH], reason[PLATFORM_MAX_PATH], nick[PLATFORM_MAX_PATH], netid[PLATFORM_MAX_PATH];

    if(!path[0]) BuildPath(Path_SM, path, sizeof(path), "logs/hm_disconnect.log");

    event.GetString("name", nick, sizeof(nick));
    event.GetString("networkid", netid, sizeof(netid));
    event.GetString("reason", reason, sizeof(reason));
    LogToFileEx(path, "'%s' (%s) disconnected (reason: '%s')", nick, netid, reason);
    return Plugin_Continue;
}

if this wouldn't help then probably your mod doesn't support "reason" key for this event.

dr_lex · 11-30-2020 , 06:59 Re: I need help in (player_disconnect)

Quote:

Originally Posted by MAGNAT2645

Try to use EventHookMode_Pre:

Code:

HookEvent( "player_disconnect", Event_Disconnect, EventHookMode_Pre );

public Action Event_Disconnect(Event event, const char[] name, bool dontBroadcast)
{
    if(event.GetBool("bot")) return Plugin_Continue;

    static char path[PLATFORM_MAX_PATH], reason[PLATFORM_MAX_PATH], nick[PLATFORM_MAX_PATH], netid[PLATFORM_MAX_PATH];

    if(!path[0]) BuildPath(Path_SM, path, sizeof(path), "logs/hm_disconnect.log");

    event.GetString("name", nick, sizeof(nick));
    event.GetString("networkid", netid, sizeof(netid));
    event.GetString("reason", reason, sizeof(reason));
    LogToFileEx(path, "'%s' (%s) disconnected (reason: '%s')", nick, netid, reason);
    return Plugin_Continue;
}

if this wouldn't help then probably your mod doesn't support "reason" key for this event.

nothing has changed

MAGNAT2645 · 12-01-2020 , 09:25 Re: I need help in (player_disconnect)

Add default value for reason:

Code:

event.GetString("reason", reason, sizeof(reason), "_NOREASON_");

If you will see "_NOREASON_" as reason in logs then probably your game doesn't support this key for player_disconnect event.

dr_lex · 12-02-2020 , 08:48 Re: I need help in (player_disconnect)

Quote:

Originally Posted by MAGNAT2645

Add default value for reason:

Code:

event.GetString("reason", reason, sizeof(reason), "_NOREASON_");

If you will see "_NOREASON_" as reason in logs then probably your game doesn't support this key for player_disconnect event.

It also doesn't show anything. Rather, I agree that the game does not support this feature.

Balimbanana · 12-02-2020 , 12:09 Re: I need help in (player_disconnect)

You could always try running on the server

Code:

developer 4

and join, then disconnect, it will show each of the events running and the I/O. You will want to change it back to 0 right after as it is a bit spammy. You should be able to find relevant events with 4.

It looks like L4D2 also uses the event "player_team" for disconnects, but there is no reason attached:

PHP Code:


			
"player_team"                // player change his team

{

    "userid"    "short"        // user ID on server

    "team"        "byte"        // team id

    "oldteam" "byte"        // old team id

    "disconnect" "bool"    // team change because player disconnects

    "name"    "string"

    "isbot"    "bool"

}

It is odd that player_disconnect doesn't show a reason, do you have any plugins that modify join/disconnect messages? I can test a few things on a vanilla SM server later on today and see if I get any info.

dr_lex · 12-02-2020 , 14:10 Re: I need help in (player_disconnect)

Quote:

Originally Posted by Balimbanana

You could always try running on the server

Code:

developer 4

and join, then disconnect, it will show each of the events running and the I/O. You will want to change it back to 0 right after as it is a bit spammy. You should be able to find relevant events with 4.

It looks like L4D2 also uses the event "player_team" for disconnects, but there is no reason attached:

PHP Code:


			
"player_team"                // player change his team

{

    "userid"    "short"        // user ID on server

    "team"        "byte"        // team id

    "oldteam" "byte"        // old team id

    "disconnect" "bool"    // team change because player disconnects

    "name"    "string"

    "isbot"    "bool"

}

It is odd that player_disconnect doesn't show a reason, do you have any plugins that modify join/disconnect messages? I can test a few things on a vanilla SM server later on today and see if I get any info.

Most likely, there is another plugin that hides the display of messages in the chat.

If it is not difficult to check (L4D2 game)

Dragokas · *Last edited by Dragokas; 12-02-2020 at 14:26.*

I think we can do it by hooking CBaseClient:: PerformDisconnection, responsible for logging the message in console.log:

PHP Code:


			
CBaseClient *__cdecl CBaseClient::PerformDisconnection(CBaseClient *this, const char *a2)
{
...
ConMsg("Dropped %s from server (%s)\n", v5, a2);

But I don't know how to do it correctly. Maybe, somebody help?

My attempt:

Spoiler

Code:

"Games"
{
	"left4dead2"
	{
		"Functions"
		{
			"CBaseClient::PerformDisconnection"
			{
				"signature"		"CBaseClient::PerformDisconnection"
				"callconv"		"cdecl"
				"return"		"int"
				"this"			"address"
				"arguments"
				{
					"a2"
					{
						"type"	"charptr"
					}
				}
			}
		}
		"Signatures"
		{
			"CBaseClient::PerformDisconnection"
			{
				"library"		"engine"
				"linux"			"@_ZN11CBaseClient20PerformDisconnectionEPKc"
				/* Found by "Dropped %s from server" */
				"windows"		""
			}
		}
	}
}

PHP Code:


			
#define PLUGIN_VERSION        "1.0"

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <dhooks>

#define DEBUG 0
#define GAMEDATA        "disconnection.gamedata"

public Plugin myinfo =
{
    name = "[L4D2] Get Disconnection Reason",
    author = "Dragokas",
    description = "Catches player's disconnection reason",
    version = PLUGIN_VERSION,
    url = "https://github.com/dragokas"
}

Handle hDetour;

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
    EngineVersion test = GetEngineVersion();
    if( test != Engine_Left4Dead2 )
    {
        strcopy(error, err_max, "Plugin only supports Left 4 Dead 2.");
        return APLRes_SilentFailure;
    }
    return APLRes_Success;
}

public void OnPluginStart()
{
    char sPath[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, sPath, sizeof(sPath), "gamedata/%s.txt", GAMEDATA);

    Handle hGameData = LoadGameConfigFile(GAMEDATA);
    if( hGameData == null ) SetFailState("Failed to load \"%s.txt\" gamedata.", GAMEDATA);
    
    SetupDetour(hGameData);

    delete hGameData;
}

public void OnPluginEnd()
{
    if( !DHookDisableDetour(hDetour, false, PerformDisconnection) )
        SetFailState("Failed to disable detour \"CBaseClient::PerformDisconnection\".");
}

void SetupDetour(Handle hGameData)
{
    hDetour = DHookCreateFromConf(hGameData, "CBaseClient::PerformDisconnection");
    if( !hDetour )
        SetFailState("Failed to find \"CBaseClient::PerformDisconnection\" signature.");
    if( !DHookEnableDetour(hDetour, false, PerformDisconnection) )
        SetFailState("Failed to start detour \"CBaseClient::PerformDisconnection\".");
}

public MRESReturn PerformDisconnection(Address pThis, DHookParam hParams)
{
    char reason[64];
    
    if( pThis )
    {
        // this one crashes
        int client = LoadFromAddress(pThis, NumberType_Int32);
        
        // ok, this one also wrong. Need to deref firstly.
        hParams.GetString(1, reason, sizeof(reason));
        
        LogError("Player # %i (%i) is disconnected (reason: '%s')", pThis, client, reason);
    }
    return MRES_Ignored;
}

Crashes on LoadFromAddress. Why address is incorrect?

Also, not sure what "return" type in gamedata is expected. Does Dhook Detours support class instance as a return at all? Any walkaround?

Sample of results coming to pThis:

Quote:

L 12/02/2020 - 00

1:46: [Disconnection_State.smx] Player # 2056848985 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

1:55: [Disconnection_State.smx] Player # -668268611 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:07: [Disconnection_State.smx] Player # 1310853618 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:07: [Disconnection_State.smx] Player # 1311377637 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:07: [Disconnection_State.smx] Player # 1313409263 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:07: [Disconnection_State.smx] Player # 1315506378 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:08: [Disconnection_State.smx] Player # 1569130968 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:08: [Disconnection_State.smx] Player # 1571161655 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1637545774 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1636759068 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1635972609 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1635382820 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1634793890 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1634203185 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')
L 12/02/2020 - 00

2:16: [Disconnection_State.smx] Player # -1633614274 (0) is disconnected (reason: 'шї?ў8ў?ў°ў?ў*')

Supposed struct:

PHP Code:


			
class CBaseClient : public IGameEventListener2, public IClient, public IClientMessageHandler
{
    typedef struct CustomFile_s
    {
        CRC32_t            crc;    //file CRC
        unsigned int    reqID;    // download request ID
    } CustomFile_t;

public:
    CBaseClient();
    virtual ~CBaseClient();

public:

    int            GetPlayerSlot() const { return m_nClientSlot; };
    int            GetUserID() const { return m_UserID; };
    const USERID_t    GetNetworkID() const;
    const char        *GetClientName() const { return m_Name; };
    INetChannel        *GetNetChannel() { return m_NetChannel; };
    IServer            *GetServer() { return (IServer*)m_Server; };
    const char        *GetUserSetting(const char *cvar) const;
    const char        *GetNetworkIDString() const;
...

PS. The topic is marked "Solved" when actually is not at all.

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode