[ricksfishin]

Need plugin or Something where tank can get through Safe room door at start of map, When it's closed
Thanks

[Marttt]

You can try this,

https://forums.alliedmods.net/showthread.php?p=2700212

[ricksfishin]

Thanks Marttt I am already using that plugin. wanting tank to break through saferoom door for players who might not open the door and just farm tanks. I only have tanks on my server maps'

[Marttt]

You mean that the tanks spawns before the saferoom opens?
Well you might just take a look in the Silvers code and force the same behavior on player_spawn (maybe)

[Bacardi]

Now I have test much.

*edit
*edit
*edit
*edit
Updated code.

Checkpoint Exit Door will be forced to open after 30 seconds at round start.
- To get door open automatically, there should be bots or players in team survivor.

PHP Code:

#include <sdktools>

Handle TimerCheckpointDoor;
bool DoOnce;

public void OnPluginStart()
{
    HookEventEx("round_freeze_end", round_freeze_end);
    HookEventEx("player_first_spawn", player_first_spawn);
}


public void round_freeze_end(Event event, const char[] name, bool dontBroadcast)
{
    // when map start

    DoOnce = false;

    if(TimerCheckpointDoor == null) return;

    delete TimerCheckpointDoor;
}


public void player_first_spawn(Event event, const char[] name, bool dontBroadcast)
{
    // Timer already executed
    if(DoOnce || TimerCheckpointDoor != null) return;


    int client = GetClientOfUserId(event.GetInt("userid"));
    
    // Don't check unnecessary events. Only players in team survivor
    if(client == 0 || !IsClientInGame(client) || GetClientTeam(client) != 2) return;

    char doorname[30];
    int door = -1;


    int entity = -1;
    
    while( (entity = FindEntityByClassname(entity, "prop_door_rotating_checkpoint")) != -1 )
    {
        //PrintToServer("m_hasUnlockSequence %i,   %i", GetEntProp(entity, Prop_Data, "m_hasUnlockSequence"), entity);
        GetEntPropString(entity, Prop_Data, "m_iName", doorname, sizeof(doorname));
        
        if(StrEqual(doorname, "checkpoint_exit", false))
        {
            // yes
            door = entity;
            break;
        }
        else if(StrEqual(doorname, "checkpoint_entrance", false))
        {
            // skip
            continue;
        }
        else if(GetEntProp(entity, Prop_Data, "m_hasUnlockSequence") == 1)
        {
            // empty targetname ex. Look door m_hasUnlockSequence
            door = entity;
            break;
        }
    }


    if(door == -1) return;


    SetVariantString("OnOpen !self:Lock::0.1:1");
    AcceptEntityInput(door, "AddOutput");
    
    SetVariantString("OnUser1 !self:playeropen::0.1:1");
    AcceptEntityInput(door, "AddOutput");

    SetVariantString("OnUser1 !self:playeropen::1.0:1");
    AcceptEntityInput(door, "AddOutput");
    
    PrintToChatAll("\x05[SM] \x04Checkpoint Exit Door \x05will be forced open in 30 seconds");

    DoOnce = true;
    TimerCheckpointDoor = CreateTimer(30.0, OpenDoor, EntIndexToEntRef(door));
}

public Action OpenDoor(Handle timer, int ref)
{
    TimerCheckpointDoor = null;

    int door = EntRefToEntIndex(ref);

    if(door != -1)
    {
        for(int i = 1; i <= MaxClients; i++)
        {
            if(!IsClientInGame(i) || GetClientTeam(i) != 2) continue;

            AcceptEntityInput(door, "FireUser1", i);
            PrintToChatAll("\x05[SM] \x04Checkpoint Exit Door \x05will be forced open!");
            break;
        }
    }
} 


[ricksfishin]

Bacardi compiled fine I did restart of server and made a few map changes But the door never opened.

[Bacardi]

In which map ?
*edit
Ouh, I think it is event round_freeze_end. It works only mp_restartgame.

[ricksfishin]

Sorry forgot all maps are finale maps. Tank only server Tried on c2m5_concert,c4m5_milltown_escape and c3m4_plantation

[Bacardi]

Ok, good you tell those maps.

- c4m5_milltown_escape map didn't event trigger event player_entered_checkpoint until player step out room.
- some maps don't have targetname.
- and in my previous code, timer work too early. I changed to common, player_spawn event.

Try plugin again, from my previous post.

It should work.

[ricksfishin]

Thank you Bacardi works great. If i may ask when you restart game mp_restartgame it doesn't work
And if possible could you change PrintToChatAll to PrintCenterText Exit door will be forced open in 30 seconds.Thanks