[ProjectSky]

any better way to detect if an entity is inside the start or end saferoom?
i am use l4d2_saferoom_detect plugins, but it need extra data and poor support for addon map.

[Marttt]

You may try hooking touch on info_changelevel entities, I don't know if it will work on all maps.
Maybe someone else has another method or know how to get it through detouring.

[BHaType]

I know 2 ways but they have their disadvantages

Method 1

PHP Code:

/* Will fail if map doesn't have navigation */
bool IsInSaferoomArea( const float vOrigin[3] )
{
    #define OFFSET 0x128 // Linux 0x12C
    Address area = view_as<Address>(L4D_GetNearestNavArea(vOrigin));
    
    if ( area == Address_Null )
        return false;
    
    int spawnattributes = LoadFromAddress(area + view_as<Address>(OFFSET), NumberType_Int32);
    
    return (spawnattributes & 2048) != 0;
} 


Method 2

PHP Code:

/* This only works for end saferoom so will probably fail on finales */
bool IsInSaferoom( const float vOrigin[3] )
{
    int info_changelevel = MaxClients + 1;
    
    while ( (info_changelevel = FindEntityByClassname(info_changelevel, "info_changelevel")) && IsValidEntity(info_changelevel) )
    {
        float vMins[3], vMaxs[3];
        GetEntPropVector(info_changelevel, Prop_Data, "m_vecMins", vMins);
        GetEntPropVector(info_changelevel, Prop_Data, "m_vecMaxs", vMaxs);
        
        if ( IsPointInBox(vOrigin, vMins, vMaxs) )
        {
            return true;
        }
    }
    
    return false;
}

//-----------------------------------------------------------------------------

bool IsPointInBox( const float pt[3], const float boxMin[3], const float boxMax[3] )
{
    if ( (pt[0] > boxMax[0]) || (pt[0] < boxMin[0]) )
        return false;
    if ( (pt[1] > boxMax[1]) || (pt[1] < boxMin[1]) )
        return false;
    if ( (pt[2] > boxMax[2]) || (pt[2] < boxMin[2]) )
        return false;
        
    return true;
} 


[sorallll]

PHP Code:

TerrorNavMesh::GetInitialCheckpoint()
TerrorNavMesh::GetLastCheckpoint()
Checkpoint::ContainsArea(TerrorNavArea *)
if(SDKCall(g_hSDKCheckpointContainsArea, SDKCall(g_hSDKGetLastCheckpoint, L4D_GetPointer(POINTER_NAVMESH), area)) 


[ProjectSky]

I'm trying nav area thing, thx everyone help.

[ProjectSky]

why get ThisPtr address cannot be null?

PHP Code:

void IsInSaferoomArea(int entity)
{
    float vOrigin[3];
    GetEntPropVector(entity, Prop_Send, "m_vecOrigin", vOrigin);
    Address area = view_as<Address>(L4D_GetNearestNavArea(vOrigin));

    Address pLastCheckpoint, pInitialCheckpoint;
    
    if (area == Address_Null) return;

    pLastCheckpoint = SDKCall(g_hGetLastCheckpoint, L4D_GetPointer(POINTER_NAVMESH));
    pInitialCheckpoint = SDKCall(g_hGetInitialCheckpoint, L4D_GetPointer(POINTER_NAVMESH));

    if (SDKCall(g_hCheckpointContainsArea, pInitialCheckpoint, area))
        PrintToChatAll("Start SafeRoom");
    else if (SDKCall(g_hCheckpointContainsArea, pLastCheckpoint, area))
        PrintToChatAll("End SafeRoom");
} 


[sorallll]

Originally Posted by ProjectSky why get ThisPtr address cannot be null? PHP Code: void IsInSaferoomArea(int entity) {     float vOrigin[3];     GetEntPropVector(entity, Prop_Send, "m_vecOrigin", vOrigin);     Address area = view_as<Address>(L4D_GetNearestNavArea(vOrigin));     Address pLastCheckpoint, pInitialCheckpoint;          if (area == Address_Null) return;     pLastCheckpoint = SDKCall(g_hGetLastCheckpoint, L4D_GetPointer(POINTER_NAVMESH));     pInitialCheckpoint = SDKCall(g_hGetInitialCheckpoint, L4D_GetPointer(POINTER_NAVMESH));     if (SDKCall(g_hCheckpointContainsArea, pInitialCheckpoint, area))         PrintToChatAll("Start SafeRoom");     else if (SDKCall(g_hCheckpointContainsArea, pLastCheckpoint, area))         PrintToChatAll("End SafeRoom"); }

pInitialCheckpoint is null in the first map, pLastCheckpoint is null in the finale map

[ProjectSky]

Originally Posted by sorallll pInitialCheckpoint is null in the first map, pLastCheckpoint is null in the finale map

cool, that explains a lot.
seem check SpawnAttributes property is a better way, other method seem less reliable, if any a better way please let me know

[sorallll]

Originally Posted by ProjectSky cool, that explains a lot. seem check SpawnAttributes property is a better way, other method seem less reliable, if any a better way please let me know

check SpawnAttributes may not be as accurate as Checkpoint::ContainsArea(TerrorNavArea *) on some maps such as c6m2 and some custom maps

[ReCreator]

Is there any way to detect same thing in L4D1?
Tried such thing with Left 4 Dhooks stuff, but it didn't work, returns 0.

int spawnattributes = L4D_GetNavArea_AttributeFlags(L4D_GetNearestNavArea(vOrigin, 100.0, false, false, false, 2));