[eyal282]

I discovered it's a pain in the ass to hook melee damage, a single melee weapon can produce 3 damage types that aren't included in the default damage types. How to hook melee damage?

[backwards]

Are you wanting to hook damage only of the knife to another player or does it have to include entity objects and world? If it's just for other players you can hook player_hurt game event and check against the weapon name to see if it was a weapon_knife.

Edit: didn't see it was for l4d2, I'm not sure if they use the event system for weapon events in a similar way or not so my bad.

[Lux]

Not really sure,

Try using SDKHooks OnTakeDamage

and checking this prop data of the melee weapon they are using
m_strMapSetScriptName (Offset 6116) (Save|Key)(4 Bytes) - melee_script_name

GetEntPropString(iWeapon, Prop_Data, "m_strMapSetScriptName", sBuffer, sizeof(sBuffer));


And i think this is where the weapons them self
Because checking the entity classname will always return weapon_melee

[Uncle Jessie]

It does not matter traceattack or takedamage. It's just what I'm using

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

static const String:ENTPROP_MELEE_STRING[]    = "m_strMapSetScriptName";
static const String:CLASSNAME_MELEE_WPN[]     = "weapon_melee";

/*
public Action:OnTakeDamage(victim, &attacker, &inflictor, &Float:damage, &damageType, &weapon, Float:damageForce[3], Float:damagePosition[3]) 
{
    if (!IsSurvivor(victim) || !IsSurvivor(attacker))
        return Plugin_Continue;

    decl String:meleeweapon[128];
    GetEdictClassname(inflictor, meleeweapon, sizeof(meleeweapon)); 
    
    if (StrEqual(meleeweapon, "weapon_melee"))
    {
        GetEntPropString(GetPlayerWeaponSlot(attacker, 1), Prop_Data, "m_strMapSetScriptName", meleeweapon, sizeof(meleeweapon));
    }
    
    if(StrEqual(meleeweapon, "baseball_bat"))
    {
        damage = 600.0;
        return Plugin_Changed;
    }
    
    return Plugin_Continue;
}
*/

public OnClientPostAdminCheck(client)
{
    SDKHook(client, SDKHook_TraceAttack, OnTraceMeleeAttack);
}

public OnClientDisconnect(client)
{
    SDKUnhook(client, SDKHook_TraceAttack, OnTraceMeleeAttack);
}

public Action:OnTraceMeleeAttack(victim, &attacker, &inflictor, &Float:damage, &damagetype, &ammotype, hitbox, hitgroup)
{
    if (!IsSurvivor(victim) || !IsSurvivor(attacker) || IsFakeClient(attacker))
        return Plugin_Continue;
    
    decl String:meleeweapon[128];
    GetEdictClassname(inflictor, meleeweapon, sizeof(meleeweapon));
    
    if (StrEqual(meleeweapon, CLASSNAME_MELEE_WPN))
    {
        GetEntPropString(GetPlayerWeaponSlot(attacker, 1), Prop_Data, ENTPROP_MELEE_STRING, meleeweapon, sizeof(meleeweapon));
    }
    
    if (hitgroup > 0) 
    {
        if(StrEqual(meleeweapon, "baseball_bat")) 
        {
            damage = 9000.0;
            return Plugin_Changed;
        }
    }
    
    return Plugin_Continue;
}

stock bool:IsSurvivor(client)
{
    if (client > 0 && client <= MaxClients && IsClientInGame(client) && GetClientTeam(client) == 2)
    {
        return true;
    }
    return false;
} 


[eyal282]

Solved, found it in player_hurt event:

new String:WepName[50];	
GetEventString(hEvent, "weapon", WepName, sizeof(WepName));

if(StrEqual(WepName, "melee"))
{
// Do stuff
}