[Abhinash]

Hello there.
So, in my server I have like more than 30 console admin commands.
My question is instead of using the delay admin flags which are like "abcdef...", How can I use flags like - @#$ ??
I means I want to use "@" as a flag. How to do it ?

[Bugsy]

Flags are stored in a bitsum in a 4-byte cell (32 bits) so you are limited to 32 flags. The way they are read using read_flags() is flags |= ( 1 << [char] - 'a') . So it's basically subtracting the ascii code for 'a' from each character you give to it, so you can go beyond character 'z' until you reach 'a' + 31.

I am not certain whether or not AMX-X uses these bits for anything, can anyone involved with AMX-X development weigh in?

Below are the characters and ASCII codes that can possibly be used as flags:
{ = 123
| = 124
} = 125
~ = 126
Char 127 (character does not display in editors or forum so I would avoid using it)
€ = 128

Can be added to your plugin:

#define ADMIN_CUSTOM1	    (1<<26) /* flag "{" */
#define ADMIN_CUSTOM2	    (1<<27) /* flag "|" */
#define ADMIN_CUSTOM3	    (1<<28) /* flag "}" */
#define ADMIN_CUSTOM4	    (1<<29) /* flag "~" */
#define ADMIN_CUSTOM5	    (1<<30) /* flag NA */
#define ADMIN_CUSTOM6	    (1<<31) /* flag "€" */

Edit: I found that the get_flags() native limits flags to between 'a' and 'z' so avoid using that with these flags. I'm not sure what else may be impacted, so I'd probably avoid using these custom flags and figuring out another way.

void UTIL_GetFlags(char* f, int a)
{
	for (int i = 'a'; i <= 'z'; ++i)
	{
		if (a & 1) *f++ = i;
		a >>= 1;
	}

	*f = 0;
}

[Abhinash]

Then update me up in this thread when you find a better way

[OciXCrom]

You'll probably need some other method for this rather than flags, because you have limited flags, but unlimited commands.

I'm currently working on a very flexible permission-based plugin/admin system that allows you to use permissions for each command instead of admin flags (e.g. for amx_slap you would need amxcmd.slap permission or amxcmd.* for all commands). Maybe you can use that when I release it.

[Bugsy]

Can do something like this, or wait for OciXCrom's plugin.

set_permission <name> <- or +> <permission #>

set_permission bugsy + 2
set_permission bugsy + 5
set_permission bugsy - 2

You will need nVault Array

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <nvault_array>

new const Version[] = "0.1";

enum Permissions
{
    Custom1 = 1,
    Custom2,
    Custom3,
    Custom4,
    Custom5
}

new g_szAuthID[ MAX_PLAYERS + 1 ][ 34 ];
new bool:g_bUserPermissions[ MAX_PLAYERS + 1 ][ Permissions ];
new g_Vault;

public plugin_init() 
{
    register_plugin( "Permissions" , Version , "bugsy" );
    
    register_concmd( "set_permission" , "SetPermission" );
    
    g_Vault = nvault_open( "permissions_vault" );
}

public plugin_end()
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    new iTS;
    get_user_authid( id , g_szAuthID[ id ] , charsmax( g_szAuthID[] ) );
    nvault_get_array( g_Vault , g_szAuthID[ id ] , g_bUserPermissions[ id ][ Permissions:0 ] , sizeof( g_bUserPermissions[] ) , iTS );
}

#if AMXX_VERSION_NUM == 190
public client_disconnected( id )
#else
public client_disconnect( id )
#endif
{
    nvault_set_array( g_Vault , g_szAuthID[ id ] , g_bUserPermissions[ id ][ Permissions:0 ] , sizeof( g_bUserPermissions[] ) );
}

public SetPermission( id )
{
    new szArgName[ 32 ] , szArgCommand[ 2 ] , szPermission[ 3 ] , iPlayer , Permissions:pPermission;
    
    if ( !( get_user_flags( id ) & ADMIN_RCON ) )
    {
        console_print( id , "* You do not have permission to use this command." );
        return PLUGIN_HANDLED;
    }

    if ( ( read_argv( 1 , szArgName , charsmax( szArgName ) ) ) && ( read_argv( 2 , szArgCommand , charsmax( szArgCommand ) ) ) && ( read_argv( 3 , szPermission , charsmax( szPermission ) ) ) )
    {
        if ( !( Custom1 <= ( pPermission = Permissions:str_to_num( szPermission ) ) < Permissions ) )
        {
            console_print( id , "* Invalid permission entered, must be between %d and %d" , Custom1 , _:Permissions - 1 );
            return PLUGIN_HANDLED;
        }
        
        if ( !( szArgCommand[ 0 ] == '+' || szArgCommand[ 0 ] == '-' ) )
        {
            console_print( id , "* Invalid command, must be - or +" );
            return PLUGIN_HANDLED;
        }
        
        if ( ( iPlayer = cmd_target( id , szArgName , 0 ) ) ) 
        {
            get_user_name( iPlayer , szArgName , charsmax( szArgName ) );
            
            if ( szArgCommand[ 0 ] == '+' && g_bUserPermissions[ iPlayer ][ pPermission ] )
            {
                console_print( id , "* %s already has permission %d" , szArgName , pPermission );
                return PLUGIN_HANDLED;
            }
            
            if ( szArgCommand[ 0 ] == '-' && !g_bUserPermissions[ iPlayer ][ pPermission ] )
            {
                console_print( id , "* %s does not currently have permission %d" , szArgName , pPermission );
                return PLUGIN_HANDLED;
            }
            
            g_bUserPermissions[ iPlayer ][ pPermission ] = bool:( szArgCommand[ 0 ] == '+' );
            
            console_print( id , "* Permission %d %s for %s" , pPermission , g_bUserPermissions[ iPlayer ][ pPermission ] ? "added" : "removed" , szArgName );
        }
    }
    else
    {
        console_print( id , "* Incorrect arguments: give_permission <player> <+ or -> <permission # %d to %d>" , Custom1 , _:Permissions - 1 );
    }
    
    return PLUGIN_HANDLED;
} 


[Abhinash]

Any better way of permission system ?

[OciXCrom]

What's wrong with our suggestions?...

[^SmileY]

Originally Posted by Abhinash Any better way of permission system ?

i Suggest you to describe better what you want for custom permission system.
Not only flags itself, since change a ~ z for symbols do not make any sense.

[Natsheh]

Originally Posted by Bugsy I am not certain whether or not AMX-X uses these bits for anything, can anyone involved with AMX-X development weigh in? [/code]

Me myself it was very helpful as no access flag in the amxx new menu system.

Heres an example

PHP Code:

    const NO_ACCESS = (1<<26);
    
    pratio ? formatex(sText, charsmax(sText), "\rPrisoner's \w( Terrorist )"):formatex(sText, charsmax(sText), "Prisoner's ( Terrorist )")
    menu_additem(iMenu, sText, "1", pratio > 0 ? 0:NO_ACCESS) 


[Abhinash]

Originally Posted by OciXCrom You'll probably need some other method for this rather than flags, because you have limited flags, but unlimited commands. I'm currently working on a very flexible permission-based plugin/admin system that allows you to use permissions for each command instead of admin flags (e.g. for amx_slap you would need amxcmd.slap permission or amxcmd.* for all commands). Maybe you can use that when I release it.

When are you going to release it ?