[jockersoft]

I'd like to prevent players to reach certain places of standard TF2 maps.
This could be done using BAILOPAN's Stripper but I cannot use it for performance reasons, so I'm looking for a way to create walls (visible or invisible) using a sourcemod plugin.

Is it possible? Which is the best way to do so?

I tried adding a model to the map (cp_badlands) using the following code in OnMapStart, but I must be doing something wrong since this has absolutely no effect.

decl Float:origin[3];
origin[0] = 2584.0;
origin[1] = 2780.0;
origin[2] = 140.0;
new Float:angles[3];
new ent1 = CreateEntityByName("prop_physics_override");
PrecacheModel("models/props_hydro/barricade.mdl", true);
SetEntityModel(ent1, "models/props_hydro/barricade.mdl");
SetEntityMoveType(ent1, MOVETYPE_NONE);
SetEntProp(ent1, Prop_Data, "m_CollisionGroup", 0);
SetEntProp(ent1, Prop_Data, "m_usSolidFlags", 28);
SetEntProp(ent1, Prop_Data, "m_nSolidType", 6);
DispatchSpawn(ent1);
AcceptEntityInput(ent1, "DisableShadow");
AcceptEntityInput(ent1, "DisableMotion");
TeleportEntity(ent1, origin, angles, NULL_VECTOR);
SetEntityRenderMode(ent1, RENDER_ENVIRONMENTAL);

I also wonder if there is an easier way, since an invisible rectangular wall will be perfect for my needs.

[Damizean]

It would be better if you created a dynamic instead of a physics, if you just want a static invisible wall to be collideable by the players.

PHP Code:

CreateInvisibleWall(Float:Position[3], Float:Angles[3])
{
    // Create entity
    new Entity = CreateEntityByName("prop_dynamic_override");

    // Configure and dispatch.
    DispatchKeyValue(Entity, "model",  "models/props_hydro/barricade.mdl");
    DispatchKeyValue(Entity, "solid",   "6");
    SetEntityModel(Entity, "models/props_hydro/barricade.mdl");
    DispatchSpawn(Entity);

    // Make it unable to cast shadows and set it to non-render mode.
    AcceptEntityInput(Entity, "DisableShadow");
    SetEntityRenderMode(Entity, RENDER_NONE);

    // Teleport to given position and angles
    TeleportEntity(Entity, Position, Angles, NULL_VECTOR);

    // Done
    return Entity;
} 


[Gachl]

is there a way to create a brush dynamically? So you can give it a texture, height, width, depth etc..?

[bl4nk]

No, it's not possible ATM.

[jockersoft]

Damizean, thanks for your response. I tried your code but i still can't get the wall spawning.

The following code should add a wall in front of the right door of the 1st blue spawn in cp_badlands, but does absolutely nothing apart from printing "wall added" in server console.

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#define PLUGIN_VERSION "1.0"

public Plugin:myinfo = 
{
    name = "add wall test",
    author = "",
    description = "",
    version = PLUGIN_VERSION,
    url = ""
}

public OnMapStart()
{
    decl Float:Position[3];
    decl Float:Angles[3];
    Position[0] = -271.0;
    Position[1] = -4197.0;
    Position[2] = 290.0;
    Angles[0] = 0.0;
    Angles[1] = 0.0;
    Angles[2] = 0.0;

    PrecacheModel("models/props_hydro/barricade.mdl", true);
    new Wall = CreateInvisibleWall(Position, Angles);
    PrintToServer("wall added");
}

CreateInvisibleWall(Float:Position[3], Float:Angles[3])
{
    // Create entity
    new Entity = CreateEntityByName("prop_dynamic_override");

    // Configure and dispatch.
    DispatchKeyValue(Entity, "model",  "models/props_hydro/barricade.mdl");
    DispatchKeyValue(Entity, "solid",   "6");
    SetEntityModel(Entity, "models/props_hydro/barricade.mdl");
    DispatchSpawn(Entity);

    // Make it unable to cast shadows and set it to non-render mode.
    AcceptEntityInput(Entity, "DisableShadow");
    SetEntityRenderMode(Entity, RENDER_ENVIRONMENTAL); //TODO: set back to RENDER_NONE

    // Teleport to given position and angles
    TeleportEntity(Entity, Position, Angles, NULL_VECTOR);

    // Done
    return Entity;
} 


Any idea? thanks

[Damizean]

My guess is the game destroys and recreates all entities during the round start events, so you should hook them to determine when to create the walls.

PHP Code:

// ------------------------------------------------------------------------
// OnPluginStart
// ------------------------------------------------------------------------
public OnPluginStart()
{
    HookEvent("teamplay_round_start", Event_RoundStart, EventHookMode_PostNoCopy);
    RegConsoleCmd("MyPosition", Cmd_MyPos);
}

// ------------------------------------------------------------------------
// OnMapStart
// ------------------------------------------------------------------------
public OnMapStart()
{
    PrecacheModel("models/props_hydro/barricade.mdl", true);
}

// ------------------------------------------------------------------------
// Event_RoundStart
// ------------------------------------------------------------------------
public Event_RoundStart(Handle:hEvent, String:StrName[], bool:bDontBroadcast)
{
    // Create wall
    CreateInvisibleWall(-1242.075317, -4212.376953, 192.031250, 0.0, 0.0, 0.0);
    PrintToServer("wall added");
}

// ------------------------------------------------------------------------
// CreateInvisibleWall
// ------------------------------------------------------------------------
CreateInvisibleWall(Float:X, Float:Y, Float:Z, Float:Pitch, Float:Yaw, Float:Roll)
{
    // Create entity
    new Entity = CreateEntityByName("prop_dynamic_override");

    // Configure and dispatch.
    DispatchKeyValue(Entity, "model",  "models/props_hydro/barricade.mdl");
    DispatchKeyValue(Entity, "solid",   "6");
    SetEntityModel(Entity, "models/props_hydro/barricade.mdl");
    DispatchSpawn(Entity);

    // Make it unable to cast shadows and set it to non-render mode.
    AcceptEntityInput(Entity, "DisableShadow");
    SetEntityRenderMode(Entity, RENDER_NORMAL);

    // Setup position and rotation vectors and teleport.
    new Float:Position[3];
    Position[0] = X;
    Position[1] = Y;
    Position[2] = Z;
    new Float:Angles[3];
    Angles[0] = Pitch;
    Angles[1] = Yaw;
    Angles[2] = Roll;
    TeleportEntity(Entity, Position, Angles, NULL_VECTOR);

    // Done
    return Entity;
}  

// ------------------------------------------------------------------------
// Cmd_MyPos
// ------------------------------------------------------------------------
public Action:Cmd_MyPos(Client, Args)
{
    // Retrieve position from player
    new Float:Position[3];
    GetClientAbsOrigin(Client, Position);
    
    // Show on chat
    PrintToChatAll("%f, %f, %f", Position[0], Position[1], Position[2]);
    
    // Done
    return Plugin_Handled;
} 


This code works, I've tested it out and it creates the barricade on the left door (just in case the coordinates you used were incorrect). I've also included a command to determine the position, so you can just place them where you are at.

[jockersoft]

THANKS! that did the trick

if anyone is interested: models/props_hydro/metal_barrier03.mdl is a pretty good model for a big wall

[fragnichtnach]

Originally Posted by Gachl is there a way to create a brush dynamically? So you can give it a texture, height, width, depth etc..?

is there a way to do this in 2019?

[Indarello]

https://forums.alliedmods.net/showth...=129597&page=7
Width, high, depth but no texture, just invisible