[vamppa]

the idea
take a screenshot on death (The victim only) around every 3 or 5 deaths.
I realize this is a global event, tho I thought it was possible to read it for victim only, wouldn't it be possible to do this command on the victim only as well?
so far

PHP Code:

#include <amxmodx>

public plugin_init()
{
register_event("DeathMsg" , "deaTHshot" , "a")
}
public deaTHshot(id)
{
    client_cmd(id, "screenshot");
    client_print( id, print_chat, "screenshot taken");    
} 


[<VeCo>]

Event functions don't have ids.
You should get the victim id with read_data(). Victim is the second parameter of DeathMsg event:

PHP Code:

new id = read_data(2) // victim 


[vamppa]

thanks, updated

PHP Code:

#include <amxmodx> 

public plugin_init() 
{ 
register_event("DeathMsg" , "deaTHshot" , "a") 
} 
public deaTHshot(id) 
{ 
    new id = read_data(2) // victim 
    client_cmd(id, "screenshot"); 
    client_print( id, print_chat, "screenshot taken");     
} 


how can I make it so it only takes a screenshot every 5 deaths?

[Diegorkable]

Remove the id paramter from the ().

And you do it like that, tell me if you understand the code:

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define SCREENSHOT_PER_DEATHS 5

new gDeaths[33]
new gMaxPlayers

public plugin_init()  
{  
    register_event("DeathMsg" , "deaTHshot" , "a")  
    gMaxPlayers = get_maxplayers()
}  

public client_connect(id)
    gDeaths[id] = 0
    
public deaTHshot()  
{  
    new attacker = read_data(1)
    new victim = read_data(2) 
    
    if ( !( 1 <= attacker <= gMaxPlayers ) || !( 1 <= victim <= gMaxPlayers ) || !is_user_connected(attacker) || !is_user_connected(victim) )
        return PLUGIN_CONTINUE
        
    gDeaths[victim]++
    
    if ( gDeaths[victim] % SCREENSHOT_PER_DEATHS == 0 )
    {    
        engclient_cmd(id, "screenshot");  
        client_print( id, print_chat, "Screenshot has been successfully taken.");      
    }
    
    return PLUGIN_CONTINUE
} 


[ConnorMcLeod]

Don't bother with all those checks.
Also engclient_cmd won't work.

PHP Code:

#include <amxmodx>

#define SCREENSHOT_PER_DEATHS 5

new gDeaths[33]

public plugin_init()
{
    register_event("DeathMsg" , "Event_DeathMsg" , "a")
}

public client_putinserver(id)
{
    gDeaths[id] = 0
}

public Event_DeathMsg()
{
    new id = read_data(2)

    if ( ! (++gDeaths[id] % SCREENSHOT_PER_DEATHS) )
    {
        client_cmd(id, "screenshot")
        client_print( id, print_chat, "Screenshot has been successfully taken.")
    }
} 


[Diegorkable]

lol I dont know why I changed it to engclient, rofl.

[vamppa]

thanks everyone, am using connors one.
works wonderful ^^