[dFF]

Hello. Here is my partial code:

PHP Code:

register_forward( FM_ClientUserInfoChanged, "Fm_ClientUserInfoChangedPre" )

[...]

public client_putinserver( id )
{
    get_user_name( id, g_szName, charsmax( g_szName[ ] ) )
}

public Fm_ClientUserInfoChangedPre( id, szInfo )
{
    if( !IsConnected( id ) )
        return FMRES_IGNORED
    
    static szNewname[ 32 ]
    engfunc( EngFunc_InfoKeyValue, szInfo, "name", szNewname, charsmax( szNewname ) )
    
    if( equal( szNewname, g_szName[ id ] ) )
        return FMRES_IGNORED
    
    engfunc( EngFunc_SetClientKeyValue, id, szInfo, "name", g_szName[ id ] )
    client_cmd( id, "name ^"%s^";setinfo name ^"%s^"", g_szName[ id ], g_szName[ id ] )
    
    ColorChat( id, "Change name restrict on this server!" )
    
    return FMRES_SUPERCEDE
} 


Also I use galileo plugin from map changes, and where galileo start the map change (countdown) and player connected in the that moment will receive the 'overflow' message.

Any suggestions will welcome.

[ConnorMcLeod]

Any reason you use fakemeta instead of client_userinfochanged, get_user_info and set_user_info ?

Also, you have to change :

get_user_name( id, g_szName, charsmax( g_szName[ ] ) )

with

get_user_name( id, g_szName[id], charsmax( g_szName[ ] ) )

[dFF]

Ok, tried without fakemeta:

PHP Code:

#include < amxmodx >

public client_infochanged( id )
{
    if( !is_user_connected( id ) )
        return PLUGIN_CONTINUE
        
    static szNewName[ 32 ]
    get_user_info( id, "name", szNewName, charsmax( szNewName ) )
    
    static szName[ 32 ]
    get_user_name( id, szName, charsmax( szName ) )
    
    if( equal( szNewName, szName ) == -1 )
        return PLUGIN_CONTINUE
        
    set_user_info( id, "name", szName )
    
    client_print( id, 3, "Change name restrict on this server!" )
    
    return PLUGIN_HANDLED
} 


name blocked, but not properly (see image)


And, after first spawn I received message: "Change name restrict on this server!"

[ConnorMcLeod]

Try :

PHP Code:

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.0.1"

public plugin_init()
{
    register_plugin("Block Name", VERSION, "ConnorMcLeod");

    register_forward(FM_SetClientKeyValue, "SetClientKeyValue");
}

public SetClientKeyValue(id, const szInfoBuffer[], const szKey[]/*, const szValue[]*/)
{
    if( is_user_connected(id) && equal(szKey, "name") )
    {
        return FMRES_SUPERCEDE
    }
    return FMRES_IGNORED
} 


[dFF]

Nope, not blocked.

Edit:

Here is worked version:

PHP Code:

#include < amxmodx >

public plugin_init()
{
    register_message( get_user_msgid( "SayText" ) , "Message_SayText" )
    
    register_clcmd( "test", "test" )
}

public test( id )
{
    new szName[ 32 ]
    get_user_name( id, szName, charsmax( szName ) )

    console_print( id, "Name: %s", szName )
}

public client_infochanged( id )
{
    if( !is_user_connected( id ) )
        return PLUGIN_CONTINUE
        
    static szNewName[ 32 ]
    get_user_info( id, "name", szNewName, charsmax( szNewName ) )
    
    static szName[ 32 ]
    get_user_name( id, szName, charsmax( szName ) )
    
    if( !equal( szNewName, szName ) )
    {    
        set_user_info( id, "name", szName )
    
        client_print( id, 3, "Change name restrict on this server!" )
    
        return PLUGIN_HANDLED
    }
    
    return PLUGIN_CONTINUE
}

public Message_SayText( iMsgId, iMsgDest, id )
{
    static szMsg[ 64 ]
    get_msg_arg_string( 2, szMsg, charsmax( szMsg ) )
    
    if( equal( szMsg, "#Cstrike_Name_Change" ) != -1 || equal( szMsg, "#Name_change_at_respawn" ) != -1 )
        return PLUGIN_HANDLED
        
    return PLUGIN_CONTINUE
} 


Not best method, but worked during the test on server.