[felhasznalo]

Is it possible to skip the knife draw animation and be able to slash/stab players instantly when switching to weapon_knife?

[CrazY.]

Execute the Ham_Weapon_PrimaryAttack/Ham_Weapon_SecondaryAttack in Ham_Item_Deploy.

[felhasznalo]

I would like to make the player to be able to execute the attack by pressing the mouse button, not attacking automatically.

I would like to skip the animation and allow the player to use the knife if they want.

[felhasznalo]

So if I'm correct, I need to do the following tasks:

- Detect when switching weapons -> I can detect this event with Ham_Item_Deploy
- Set knife viewmodel animation to idle -> I've tried set_pev(playerId, pev_weaponanim, 0) without success
- Set next attack timer to zero to allow the player to attack as soon as they want -> I've tried setting m_flNextPrimaryAttack, m_flNextSecondaryAttack without success

[HamletEagle]

IIRC the knife draw animation is played in the client (too) so even if you disable it server side it would still play for anyone with cl_lw 1(basically every player).

[CrazY.]

So set the m_flNextPrimaryAttack/m_flNextAttack to 0.0. The animation would't be removed but player would be able to attack without wait untill the idle animation.

[felhasznalo]

I set m_flNextPrimaryAttack/m_flNextAttack to 0.0, but I was unable to attack while the animation was playing.

[HamletEagle]

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <orpheu>
#include <hamsandwich>

const m_pPlayer = 41
const m_iId     = 43
const XoWeapon  = 4

enum
{
    KNIFE_IDLE,
    KNIFE_ATTACK1HIT,
    KNIFE_ATTACK2HIT,
    KNIFE_DRAW,
    KNIFE_STABHIT,
    KNIFE_STABMISS,
    KNIFE_MIDATTACK1HIT,
    KNIFE_MIDATTACK2HIT,
    KNIFE_INSPECT
}

public plugin_init()
{
    register_forward(FM_UpdateClientData, "pfnUpdateClientData", true)
    OrpheuRegisterHook(OrpheuGetFunctionFromClass("weapon_knife", "SendWeaponAnim", "CBasePlayerWeapon"), "OnSendWeaponAnim", OrpheuHookPre)
}

public pfnUpdateClientData(id, SendWeapons, CD_Handle)
{
    if(is_user_alive(id) && SendWeapons)
    {
        if(get_user_weapon(id) == CSW_KNIFE)
        {
            set_cd(CD_Handle, CD_ID, 0);         
        }
    }
}

public OrpheuHookReturn:OnSendWeaponAnim(WeaponEntity, Animation, SkipLocal)
{
    if(pev_valid(WeaponEntity))
    {
        new id = get_pdata_cbase(WeaponEntity, m_pPlayer, XoWeapon)
        if(is_user_alive(id))
        {
            new WeaponIndex = get_pdata_int(WeaponEntity, m_iId, XoWeapon)
            
            if(WeaponIndex != CSW_KNIFE)
            {
                return OrpheuIgnored
            }
            
            if(Animation != KNIFE_DRAW)
            {
                SendWeaponAnim(id, Animation)
            }

            return OrpheuSupercede
        }
    }

    return OrpheuIgnored
}

SendWeaponAnim(id, Animation)
{
    set_pev(id, pev_weaponanim, Animation)
    message_begin(MSG_ONE, SVC_WEAPONANIM, _, id)
    {
        write_byte(Animation)
        write_byte(0)
        message_end()
    }
} 


Didn't test, but maybe it will work, give it a try.

{
    "name"    : "SendWeaponAnim",
    "class"   : "CBasePlayerWeapon",
    "library" : "mod",
    "arguments" :
    [
        {
            "type" : "int"
        },
        {
            "type" : "int"
        }
    ],
    "indexes" : 
    [
        {
            "os"    : "windows",
            "mod"   : "cstrike",
            "value" : 85
        },
        {
            "os"    : "linux",
            "mod"   : "cstrike",
            "value" : 87
        }
    ]
}

Put this in \configs\orpheu\virtualFunctions\CBasePlayerW eapon

[EFFx]

A little off-topic here, but I always wanted to know if the CD_ID blocks get_user_weapon from returning the weapon ID in others plugins, am I right?