[Diegorkable]

Hey guys,
Is there any possibility to script a code that sets the round time so it takes effect right away? so for example imagine the time goes like:
1:21
1:20
1:19
...
*typing /resettime that i scripted a command for it, that it sets it back to 5*
5:00
4:59
...

Is it possible?

[Sylwester]

You can change displayed round time using RoundTime message. You can block / force round end using plugins: infinite round, round terminator.

[Diegorkable]

I tried installing the infinite_round.amxx plugin on my server, and it didnt block it still.
I am asking, if can I change the value of the time left on a round, not just by visual "changing the displayed round time" but not changing the actual round time value.
How do I change the round time value so it changes at the moment and not in next round?

[Sylwester]

There probably is some way to actually change the round time using orpheu, but until someone finds out how to do it, the only thing you can do is to emulate it using RoundTime message + infinite round + round terminator.

[Exolent[jNr]]

mp_timelimit is not the round time, but the map time.
mp_roundtime is the round time in minutes.

[Diegorkable]

I don't get it then, what can I do to make a round not END? because infinite_round didnt do it at all.

[Exolent[jNr]]

Originally Posted by Sylwester the only thing you can do is to emulate it using RoundTime message + infinite round + round terminator.

[Arkshine]

Round time is calculated this way with these CGameRules offsets : g_pGameRules->m_iRoundTimeSecs - gpGlobals->time + g_pGameRules->m_flRoundCount.

If purpose is to update timer without restarting the round, all you need to do is to set m_iRoundTimeSecs to your value and m_flRoundCount to current time. Also sending a RoundTime message to update the timer.

(Will make the plugin after eating)

[Diegorkable]

What? I dont understand a word you guys say... can you please explain better? =\
@Exolent - Yeah, but how do I do that? Im confused.
@Arkshine - Yeah, and how do I set those values?

[Arkshine]

Here a basic exemple, with say /resettime as stated in your first post :

PHP Code:

#include <amxmodx>
#include <orpheu>
#include <orpheu_memory>

new const PluginName   [] = "Set Round Time";
new const PluginVersion[] = "1.0";
new const PluginAuthor [] = "Arkshine";

const YourRoundTimeValue = 5 * 60; // 5 min in seconds.

enum GameRulesMembers 
{ 
    m_iRoundTimeSecs, 
    m_flRoundCount 
};

new const GameRulesMI[ GameRulesMembers ][] = 
{ 
    "m_iRoundTimeSecs", 
    "m_flRoundCount" 
};
    
new g_pGameRules;

#define set_mp_pdata(%1,%2)  ( OrpheuMemorySetAtAddress( g_pGameRules, GameRulesMI[ %1 ], 1, %2 ) )
#define get_mp_pdata(%1)     ( OrpheuMemoryGetAtAddress( g_pGameRules, GameRulesMI[ %1 ] ) )

public plugin_precache()
{
    OrpheuRegisterHook( OrpheuGetFunction( "InstallGameRules" ), "OnInstallGameRules", OrpheuHookPost );
}

public OnInstallGameRules()
{
    g_pGameRules = OrpheuGetReturn();
}

public plugin_init()
{
    register_plugin( PluginName, PluginVersion, PluginAuthor );

    register_clcmd( "say /resettime", "ClientCommand_ResetRoundTime" );
}

public ClientCommand_ResetRoundTime( const client )
{
    setRoundTime( YourRoundTimeValue );
    return PLUGIN_HANDLED;
}

setRoundTime( const newTime )
{
    set_mp_pdata( m_iRoundTimeSecs, newTime );
    set_mp_pdata( m_flRoundCount, get_gametime() );
    
    static msgIndexRoundTime;
    
    if( msgIndexRoundTime || ( msgIndexRoundTime = get_user_msgid( "RoundTime" ) ) )
    {
        message_begin( MSG_ALL, msgIndexRoundTime );
        write_short( newTime );
        message_end();
    }
} 


Installation :

1. Make sure Orpheu is installed. If not, unzip that in your amxmodx/ directory.
2. Unzip the provided package in your amxmodx/ directory, overwrite if need.
3. Restart.