[fdxx]

I want the player to directly enter: 6ht, 7ht, 8ht .... in the chat to change the hunter's limit, but this does not work

PHP Code:

#include <sourcemod>

new Handle:h_HunterLimit;
new HunterLimit;

public void OnAllPluginsLoaded()
{
    h_HunterLimit = FindConVar("l4d_infectedbots_hunter_limit");
    HunterLimit = GetConVarInt(h_HunterLimit);
    HookConVarChange(h_HunterLimit, CVar_HunterLimit);
}

public void OnClientSayCommand_Post(int client, const char[] command, const char[] sArgs)
{
    if (IsValidClient(client) && GetClientTeam(client) == 2)
    {
        char tmpnumber[32];
        char htcommand[32];
        Format(htcommand, sizeof(htcommand), "%sht", tmpnumber);
        if (strcmp(sArgs, htcommand, false) == 0)
        {
            GetCmdArg(0, tmpnumber, sizeof(tmpnumber));
            int number = StringToInt(tmpnumber);
            int MaxSI = number + 1;
            ServerCommand("sm_cvar l4d_infectedbots_hunter_limit %i", number)
            ServerCommand("sm_cvar l4d_infectedbots_max_specials %i", MaxSI)
            CreateTimer(0.3, TimerShowCurrentMode);
        }
    }
}

public Action:TimerShowCurrentMode(Handle timer, int client)
{
    PrintToChatAll("\x05Hunter change to %i", HunterLimit);
}

public CVar_HunterLimit(Handle:cvar, String:oldValue[], String:newValue[])
{
    HunterLimit = GetConVarInt(h_HunterLimit);
}

bool IsValidClient(client)
{ 
    if (client > 0 && client < MaxClients && IsClientConnected(client) && IsClientInGame(client) && IsPlayerAlive(client)) return true; 
    return false;
} 


Can someone help me? I am a newbie in programming, thank you in advance for your help.

[Psyk0tik]

I noticed three things wrong with your code.

1. You're comparing your formatted string to the args of the command rather than the command itself.
2. The output of Format(htcommand, sizeof(htcommand), "%sht", tmpnumber); is "ht" because the string buffer you're passing is "tmpnumber" which has only been initialized to "\0".
3. You're only storing the command into "tmpnumber" inside your if statement, which will never execute due to what I said in #2.

[fdxx]

Thank you, but I don’t know how to modify

[Dragokas]

fdxx, I would write it as:

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>

ConVar l4d_infectedbots_hunter_limit;
ConVar l4d_infectedbots_max_specials;

public void OnAllPluginsLoaded()
{
    l4d_infectedbots_hunter_limit = FindConVar("l4d_infectedbots_hunter_limit");
    l4d_infectedbots_max_specials = FindConVar("l4d_infectedbots_max_specials");
}

public Action OnClientSayCommand(int client, const char[] command, const char[] sArgs)
{
    int iNum;
    if( ParseCmd(sArgs, "ht", iNum) )
    {
        SetCvarSilentInt(l4d_infectedbots_hunter_limit, iNum);
        SetCvarSilentInt(l4d_infectedbots_max_specials, iNum + 1);
        
        if( client )
            PrintToChat(client, "New limit: %i", iNum);
            
        return Plugin_Stop;
    }
    return Plugin_Continue;
}

bool ParseCmd(const char[] cmdSource, char[] cmdSample, int &iNum) // examples: 1ht, 16ht
{
    const int NUM_MIN = 1;
    const int NUM_MAX = 16;
    const int NUMLEN_MAX = 2;
    
    int lenSrc = strlen(cmdSource);
    int CMDLEN = strlen(cmdSample);
    
    if( CMDLEN + 1 <= lenSrc <= CMDLEN + NUMLEN_MAX )
    {
        if( strcmp( cmdSource[lenSrc-CMDLEN], cmdSample, true ) == 0 )
        {
            iNum = StringToInt(cmdSource);
            if( NUM_MIN <= iNum <= NUM_MAX )
            {
                return true;
            }
        }
    }
    return false;
}

stock bool SetCvarSilentInt( ConVar cv, int value )
{
    if( !cv )
    {
        return false;
    }
    int flags = cv.Flags;
    cv.Flags &= ~FCVAR_NOTIFY;
    cv.SetInt(value, true, false);
    cv.Flags = flags;
    return true;
} 


[fdxx]

Dragokas, thank you very much, do you have a PayPal account? I want to buy you coffee

[Dragokas]

I think Patreon can. I added "Donate" link in my signature.

[fdxx]

Originally Posted by Dragokas I think Patreon can. I added "Donate" link in my signature.

Already sponsored, It seems that payment will not be made until January 1.

[plug344]

sorry, regarding the following part, I don't quite understand

if( strcmp( cmdSource[lenSrc-CMDLEN], cmdSample, true ) == 0 )

Could this part be rewritten as eg: ?

if( !strcmp( cmdSource[lenSrc-CMDLEN], cmdSample[0], true ) && !strcmp( cmdSource[lenSrc-CMDLEN+1], cmdSample[1], true ))

Because I think strcmp == 0 and !strcmp are similar, and if it is "1ht", cmdSource[1] seems to be 'h' and cmdSample is "ht", which seems to be compare cmdSource[1] and cmdSample[0] for equality, and compare again cmdSource[2] 't' and cmdSample[1]

[Dragokas]

You can rewrite it that way, but it has no sense, because:
1) If you mean by that an optimization purposes, strcmp + string[x] behaves differently than you think.
strcmp( a[1], b[0] ) is passing an entire "b" string to comparator. It's a same as strcmp( a[1], b ). So your second part is not required.
2) To compare a single char of string, use ==, e.g. if( a[1] == b[0] ) or strncmp, e.g. if( !strncmp(a[1], b[0], 1).
3) Even if you use comparing by single char, I think strcmp is already enough optimized to cover the case when the first char is not match, to prevent comparing all the remaining characters in passed string.
4) If we mean universal "ParseCmd" stock, than hardcoding +1 offset in cmdSource[lenSrc-CMDLEN+1] is not good, because function will access the memory outside the array bounds in case you would want to check for e.g.: ParseCmd(sArgs, "h", iNum).

The only improvement I would add is to make it recognize larger numbers, like > 16 and < 1, so the final code looks so:

PHP Code:

/*
    Extracts the number iNum from source if it is followed by string passed as sample.
    
    @param cmdSource - string to analyze
    @param cmdSample - string next to the number.
    @param iNum - buffer to store resulting number.
    
    @return True, if analyzed string contains data in correct format and iNum filled with number.
            False - otherwise.
*/
stock bool ParseCmd(const char[] cmdSource, char[] cmdSample, int &iNum) // examples: 1ht, 16ht
{
    const int MAX_INT_LEN = 11;
    
    int lenSrc = strlen(cmdSource);
    int cmdLen = strlen(cmdSample);
    
    if( cmdLen + 1 <= lenSrc <= cmdLen + MAX_INT_LEN )
    {
        if( strncmp( cmdSource[lenSrc-cmdLen], cmdSample, cmdLen ) == 0 )
        {
            iNum = StringToInt(cmdSource);
            return true;
        }
    }
    return false;
} 


[plug344]

thank you Dragokas taking the time out of your busy schedule to reply to me, I have benefited a lot from your code and posts, I am researching how to use patreon in my country for show my thanks to you