[GoldNux]

I would like to request a plugin that displays the number of enemy players that are still alive.
Players has to be able to enable/disable this feature, and it should be disabled by default.

It should look something like this, but I dont want the color to be blue.
I think its less invasive if it matches the rest of the HUD.

It would be much appreciated!



edit: This is what I was able to put together, it does not work.

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>

#define PLUGIN "gn_enemiesleft"
#define VERSION "0.1"
#define AUTHOR "GoldNux"

public plugin_init()
{
    set_hudmessage(0, 255, 0, 0.009, 0.00, 0, 6.0, 105.0, 0.3, 0.3, 1)
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event("HLTV", "eventNewRound", "a", "1=0", "2=0")
    register_event( "DeathMsg" , "registerDeath" , "a" );
}

new playersT[32]
new playersCT[32]

new playerCount_T
new playerCount_CT

new playersAliveT
new playersAliveCT

public eventNewRound()
{
    get_players(playersCT, playerCount_CT, "e", "CT")
    get_players(playersT, playerCount_T, "e", "T")
    playersAliveT = playerCount_T
    playersAliveCT = playerCount_CT

    new iCT
    for (iCT = 0; iCT < playerCount_CT; iCT++)
    show_hudmessage(playersCT[iCT], "%d", playersAliveT)

    new iT
    for (iT = 0; iT < playerCount_T; iT++)
    show_hudmessage(playersT[iT], "%d", playersAliveCT)
}

public registerDeath()
{
    new victim = read_data(2);
    if (get_user_team(victim) == CS_TEAM_T)
    {
        playersAliveT--
        updateCT_HUD
    }
    if (get_user_team(victim) == CS_TEAM_CT)
    {
        playersAliveCT--
        updateT_HUD
    }
}

public updateCT_HUD()
    {
        new i
        for (i = 0; i < playerCount_CT; i++)
        show_hudmessage(playersCT[i], "%d", playersAliveT)
    }

public updateT_HUD()
    {
        new i
        for (i = 0; i < playerCount_T; i++)
        show_hudmessage(playersT[i], "%d", playersAliveCT)
    }

[marcelowzd]

Try.

Type /hud to enabled/disable hud.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>

new const g_sPlugin[ ] = "Show Alive";
new const g_sVersion[ ] = "0.0.1";
new const g_sAuthor[ ] = "wizard";

new const g_szEntClass[ ] = "HudThinker";

new const Float:g_fEntityTime = 6.0; // Change this to lower if you wish the HUD to update faster

new g_iMsgSync;

new bool:g_bUserHud[ 33 ] = { false, ... };

new bool:g_bHideCMD = false; // Change to true if you wish to block /hud from showing on chat

public plugin_init() 
{
    register_plugin( g_sPlugin, g_sVersion, g_sAuthor );
        
    register_logevent( "OnRoundStart", 2, "1=Round_Start" );
    
    RegisterHam( Ham_Think, "info_target", "OnEntityThink", 1 );
    
    register_event( "DeathMsg", "OnClientDeath", "a" );
    
    register_clcmd( "say /hud", "ClCmdHud" );
    
    g_iMsgSync = CreateHudSyncObj( );
}

public ClCmdHud( iClient )
{
    g_bUserHud[ iClient ] = !g_bUserHud[ iClient ];
    
    client_print( iClient, print_chat, "Your HUD is now %s", g_bUserHud[ iClient ] ? "enabled" : "disabled" );
    
    return ( g_bHideCMD == true ? PLUGIN_HANDLED : PLUGIN_CONTINUE );
}

public plugin_precache( )
{
    new iEnt = engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString, "info_target" ) );
    
    set_pev( iEnt, pev_classname, g_szEntClass );
    set_pev( iEnt, pev_nextthink, get_gametime( ) + 0.1 );
}

public client_putinserver( iClient )
{
    g_bUserHud[ iClient ] = false;
}

public OnEntityThink( iEnt )
{
    if( !pev_valid( iEnt ) )
        return HAM_IGNORED;
        
    static szClassname[ 32 ];
    
    pev( iEnt, pev_classname, szClassname, charsmax( szClassname ) );
    
    if( !equali( szClassname, g_szEntClass ) )
        return HAM_IGNORED;
        
    MakeHudAct( );    
    
    set_pev( iEnt, pev_nextthink, get_gametime( ) + g_fEntityTime );
    
    return HAM_IGNORED;
}

public OnRoundStart( )
{    
    MakeHudAct( );
}

public OnClientDeath( )
{
    MakeHudAct( );
}

MakeHudAct( )
{    
    static iPlayersCT[ 32 ], iNumCT;
    static iPlayersTR[ 32 ], iNumTR;
    static iTotalPlayers[ 32 ], iTotal;
    
    new iClient, iCSTeam, szMessage[ 16 ];
    
    get_players( iPlayersCT, iNumCT, "ae", "CT" );
    get_players( iPlayersTR, iNumTR, "ae", "TERRORIST" );
    get_players( iTotalPlayers, iTotal );
    
    set_hudmessage( 255, 0, 0, -1.0, 0.2, 0, 6.0, 12.0 );
    
    for( new i = 0; i < iTotal; i++ )
    {
        iClient = iTotalPlayers[ i ];
        
        if( !g_bUserHud[ iClient ] )
            continue;
            
        iCSTeam = cs_get_user_team( iClient );
                
        ClearSyncHud( iClient, g_iMsgSync );
        
        switch( iCSTeam )
        {
            case CS_TEAM_CT: formatex( szMessage, charsmax( szMessage ), "Enemies: %i", iNumTR );
            case CS_TEAM_T:  formatex( szMessage, charsmax( szMessage ), "Enemies: %i", iNumCT );
            case CS_TEAM_UNASSIGNED, CS_TEAM_SPECTATOR: formatex( szMessage, charsmax( szMessage ), "" );
        }
            
        ShowSyncHudMsg( iClient, g_iMsgSync, szMessage );
    }
} 


[karimoo97]

Hey,
you know what would be great ? Having it for both teams,and ofc the option to turn it off

RED NUMBER FOR ALIVE Ts - or / AND A BLEU ONE FOR CT's


It's just an idea,don't mind me it's his request

[marcelowzd]

Originally Posted by karimoo97 Hey, you know what would be great ? Having it for both teams,and ofc the option to turn it off RED NUMBER FOR ALIVE Ts - or / AND A BLEU ONE FOR CT's It's just an idea,don't mind me it's his request

I did exactly like this first but then i read again what OP wanted.

Anyway, if you really want this create a new request. (i'm not sure if i can post in this one)

[karimoo97]

Originally Posted by karimoo97 It's just an idea,don't mind me it's his request

You are right sir, as i said,it's his request not mine,i just wanted to support his idea.

Greetings

[4ever16]

Not exactly what you where searching for but maybe you can use it: https://forums.alliedmods.net/showthread.php?t=291624

Check all the pages there are many versions of this plugin.

You can remove health.
People can turn it on and off.
Red and blue colors.

https://www.youtube.com/watch?v=ARNFHC3Mw9k