[Kia]

Hello everybody,

I want to block the possibility to buy weapons for specific players using this code by now:

PHP Code:

public Message_StatusIcon(iMsgId, iMsgDest, id)  
{
    if(g_bIsZombie[id])
    {
        static szIcon[8];  
        get_msg_arg_string(2, szIcon, charsmax(szIcon));  
        if( equal(szIcon, "buyzone") ) 
        {  
            if( get_msg_arg_int(1) )  
            {  
                set_pdata_int(id, 235, get_pdata_int(id, 235) & ~(1<<0)); 
                return PLUGIN_HANDLED;  
            }  
        }
    }
    
    return PLUGIN_CONTINUE;  
} 


This works fine, but when a Player gets infected while he is in the buyzone, he can still open the buy menu.
Any solutions for that?

[NiHiLaNTh]

I remember somewhere seeing function fm_cs_set_user_nobuy. Basically its the same as this:

set_pdata_int(id, 235, get_pdata_int(id, 235) & ~(1<<0));  

So you need to remove buyzone from player zone bitsum on infect.

[Kia]

Does not seem to work for me, they can still buy.

[r0ck]

Working for me

PHP Code:


#include <amxmodx>
#include <fakemeta>

#define m_iMapZone 235

public plugin_init()
{
    register_message(get_user_msgid("StatusIcon") , "Message_StatusIcon")
}

public Message_StatusIcon(iMsgId, MSG_DEST, id)
{
    static szIcon[5]; get_msg_arg_string(2, szIcon, charsmax(szIcon))
    
    if(szIcon[0] == 'b' && szIcon[2] == 'y' && szIcon[3] == 'z')
    {
        if(get_msg_arg_int(1))
        {
            set_pdata_int(id, m_iMapZone, get_pdata_int(id, m_iMapZone) & ~(1<<0))
            return PLUGIN_HANDLED
        }
    }
    return PLUGIN_CONTINUE
} 


[Kia]

Originally Posted by r0ck Working for me PHP Code: #include <amxmodx> #include <fakemeta> #define m_iMapZone 235 public plugin_init() {     register_message(get_user_msgid("StatusIcon") , "Message_StatusIcon") } public Message_StatusIcon(iMsgId, MSG_DEST, id) {     static szIcon[5]; get_msg_arg_string(2, szIcon, charsmax(szIcon))          if(szIcon[0] == 'b' && szIcon[2] == 'y' && szIcon[3] == 'z')     {         if(get_msg_arg_int(1))         {             set_pdata_int(id, m_iMapZone, get_pdata_int(id, m_iMapZone) & ~(1<<0))             return PLUGIN_HANDLED         }     }     return PLUGIN_CONTINUE }

I want to block the buyzone while the player is already in buyzone, that does not help me.

[r0ck]

Said test while in buyzone and i was not able to buy, though the status icon of buyzone was still there

PHP Code:


#include <amxmodx>
#include <fakemeta>

#define m_iMapZone 235
new disallow[33]

public plugin_init()
{
    register_message(get_user_msgid("StatusIcon") , "Message_StatusIcon")
    register_clcmd("say test", "testy")
    register_clcmd("say test1", "testy1")
}

public testy(id)
{
    disallow[id] = 1
    set_pdata_int(id, m_iMapZone, get_pdata_int(id, m_iMapZone) & ~(1<<0))
}
    
public testy1(id)
{
    disallow[id] = 0
}

public Message_StatusIcon(iMsgId, MSG_DEST, id)
{
    if(!disallow[id])
        return PLUGIN_CONTINUE
    
    static szIcon[5]; get_msg_arg_string(2, szIcon, charsmax(szIcon))
    
    if(szIcon[0] == 'b' && szIcon[2] == 'y' && szIcon[3] == 'z')
    {
        if(get_msg_arg_int(1))
        {
            set_pdata_int(id, m_iMapZone, get_pdata_int(id, m_iMapZone) & ~(1<<0))
            return PLUGIN_HANDLED
        }
    }
    return PLUGIN_CONTINUE
} 


[Nextra]

If you want to use the buyzone bitmask you should take a look at your zombie plugin. It probably provides a forward like "PlayerInfected" or something similar. You need to use that forward to also remove the buyzone bitflag if the player is already inside it.

The easiest way would be using CS_OnBuy from AMXX 1.8.3.

Alternatively you can use the plugin and API made by ConnorMcLeod: https://forums.alliedmods.net/showthread.php?t=149380

[r0ck]

Found a way to remove buyzone icon from screen.. hope it helps you.

PHP Code:


    message_begin(MSG_ONE, MsgStatusIcon, {0,0,0}, id)
    write_byte(0); // status (0=hide, 1=show, 2=flash)
    write_string("buyzone")
    write_byte(0)
    write_byte(0)
    write_byte(0)
    message_end() 


------->

PHP Code:


#include <amxmodx>
#include <fakemeta>

new disallow[33]
new MsgStatusIcon

public plugin_init()
{
    MsgStatusIcon = get_user_msgid("StatusIcon")
    register_message(MsgStatusIcon , "Message_StatusIcon")
    register_clcmd("say test", "testy")
    register_clcmd("say test1", "testy1")
}

public testy(id)
{
    disallow[id] = 1
    set_pdata_int(id, 235, get_pdata_int(id, 235) & ~(1<<0)) // m_iMapZone 235
    
    message_begin(MSG_ONE, MsgStatusIcon, {0,0,0}, id)
    write_byte(0); // status (0=hide, 1=show, 2=flash)
    write_string("buyzone")
    write_byte(0)
    write_byte(0)
    write_byte(0)
    message_end()
}
    
public testy1(id)
{
    disallow[id] = 0
}

public Message_StatusIcon(iMsgId, MSG_DEST, id)
{
    if(!disallow[id])
        return PLUGIN_CONTINUE
    
    static szIcon[5]; get_msg_arg_string(2, szIcon, charsmax(szIcon))
    
    if(szIcon[0] == 'b' && szIcon[2] == 'y' && szIcon[3] == 'z')
    {
        if(get_msg_arg_int(1))
        {
            set_pdata_int(id, 235, get_pdata_int(id, 235) & ~(1<<0)) // m_iMapZone 235
            return PLUGIN_HANDLED
        }
    }
    return PLUGIN_CONTINUE
} 


[meTaLiCroSS]

When user gets infected, use this:

PHP Code:

#define m_flNextMapZoneTime 233
#define m_fClientMapZone 235

stock UpdatePlayerMapZones(iId)
{
    // Make PreThink call CBasePlayer::HandleSignals at the next frame
    set_pdata_float(iId, m_flNextMapZoneTime, 0.0) 

    // Clear mask from all MapZones, this will check it's specific huds
    // In this case we will clear the related StatusIcon message for "buyzone"
    set_pdata_int(iId, m_fClientMapZone, 0)
} 


tip: Make sure you call this on infection, and disinfection, since a player can be disinfected while on buyzone and the same behavior will occur.

2 native calls v/s a lot of message related natives, wonderful

[Kia]

Will update my plugin, thanks.