[raj kaul]

how can i disable zues damage for teammates.?

[Bacardi]

:/

PHP Code:


#include <cstrike>
#include <sdkhooks>

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamageAlive, OnTakeDamageAlive);
}


public Action OnTakeDamageAlive(int victim, int &attacker, int &inflictor, float &damage, int &damagetype)
{

    if(attacker >= 1 && attacker <= MaxClients && attacker == inflictor && GetClientTeam(victim) == GetClientTeam(attacker))
    {
        int weaponindex = GetEntPropEnt(attacker, Prop_Send, "m_hActiveWeapon");
        
        if(weaponindex == -1 || !HasEntProp(weaponindex, Prop_Send, "m_iItemDefinitionIndex"))
            return Plugin_Continue;

        weaponindex = GetEntProp(weaponindex, Prop_Send, "m_iItemDefinitionIndex");

        CSWeaponID weaponid = CS_ItemDefIndexToID(weaponindex);

        if(weaponid == CSWeapon_TASER)
            return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


[raj kaul]

thank you , its working fine