[TrullSin]

What is the best way to kill the timer at round end? I dont even know if this is the best way to make like a timer. But with this code when the map is changing there is like a crash idk

PHP Code:

#include <sourcemod>

public void OnPluginStart()
{
    HookEvent("round_start", OnRoundStart);
}

public OnRoundStart(Handle event, const char[]name , bool dontBroadcast)
{
      CreateTimer(905.0, something);
}
public Action something(Handle Timer)
{
    stuff
} 


[Ilusion9]

PHP Code:

#include <sourcemod>

Handle timer;

public void OnPluginStart()
{
    HookEvent("round_start", OnRoundStart);
}

public OnRoundStart(Handle event, const char[]name , bool dontBroadcast)
{
      timer = CreateTimer(905.0, something);
}
public Action something(Handle Timer)
{
    stuff
}
on round end:
{
    delete timer;
} 


[TrullSin]

Well I think it works, but I have another problem, sometimes the timer does the action before the specifc time, and do the action multiple times but it should do it only one time

[Bacardi]

...ok. It depends, how you would use timer.
What if take simple example, using commands for testing purpose.

And when you store created timer in global Handle, you should keep track on it, for check is timer still active to avoid errors.

example 1 - one timer at time

In this example there is two commands
sm_test for creating 10 sec timer, and it can create only one timer at time.
sm_test2 is for stop active timer when you like.

PHP Code:

Handle mytimer; // Keep track of timer

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", test); // create timer
    RegConsoleCmd("sm_test2", test2); // stop active timer
}

public Action test(int client, int args)
{

    if(mytimer != null)
    {
        // If 'mytimer' is not clear, we assume timer is still ticking.

        PrintToServer("Timer '%d' already running/active", mytimer);
        return Plugin_Handled;
    }


    // When 'mytimer' is clear, we can create new timer

    mytimer = CreateTimer(10.0, timer_callback);
    PrintToServer(" 10sec Timer '%d' created", mytimer);



    return Plugin_Handled;
}

public Action test2(int client, int args)
{

    if(mytimer != null)
    {
        // if 'mytimer' again is not clear, we assume timer is active.

        PrintToServer("Delete Timer '%d'", mytimer);
        delete mytimer; // delete will stop timer and clear Handle 'mytimer' to null

        return Plugin_Handled;
    }

    // When 'mytimer' is clear, no timer active
    PrintToServer("There is no timer to delete");

    return Plugin_Handled;
}

public Action timer_callback(Handle timer)
{
    PrintToServer("Timer '%d' executed", mytimer);

    mytimer = null; // When you know timer ends, clear global Handle also as a sign.



    // Do stuff

    return Plugin_Continue;
} 


example 2 - reset timer

With one command sm_test, create or reset 10 sec timer

PHP Code:

Handle mytimer; // Keep track of timer

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", test); // create/reset timer
}

public Action test(int client, int args)
{

    if(mytimer != null)
    {
        // If 'mytimer' is not clear, we assume timer is still ticking.

        // We will reset timer (delete/create)
        PrintToServer("Delete Timer '%d'", mytimer);
        delete mytimer;

    }


    // Create new timer

    mytimer = CreateTimer(10.0, timer_callback);
    PrintToServer(" 10sec Timer '%d' created", mytimer);



    return Plugin_Handled;
}


public Action timer_callback(Handle timer)
{
    PrintToServer("Timer '%d' executed", mytimer);

    mytimer = null; // When you know timer ends, clear global Handle also as a sign.



    // Do stuff

    return Plugin_Continue;
} 


example 2 - repeated timer

With one command sm_test, create or reset 2 sec repeating timer x 10 times.

PHP Code:

Handle mytimer; // Keep track of timer

public void OnPluginStart()
{
    RegConsoleCmd("sm_test", test); // create/reset timer
}

public Action test(int client, int args)
{

    // Create new timer

    mytimer = CreateTimer(2.0, timer_callback, _, TIMER_REPEAT);
    PrintToServer(" 2sec repeated timer '%d' created", mytimer);



    return Plugin_Handled;
}


public Action timer_callback(Handle timer)
{

    static int counter;

    if(mytimer != timer)
    {
        // When Handles mismatch, stop this specific "old" timer
        counter = 0;
        return Plugin_Stop; // stop repeating timer
    }


    counter++

    PrintToServer("Repeated timer '%d' executed %i", mytimer, counter);


    if(counter >= 10)
    {
        counter = 0;
        return Plugin_Stop; // stop repeating timer
    }


    return Plugin_Continue; // continue repeat
} 


[TrullSin]

Well I wanted to at that certain time in the round, it will make something, not activated by command but for round time

[Bacardi]

...those are examples. Scripting is like puzzle. Try and figure it out. Learn.

[ThatOneGuy]

I've certainly stored timer handles, similar to the examples above. However, my preference anymore is just to pass a validation ID to the timer and check it in the callback - avoids direct use of the handles altogether. The validation variable ensures it doesnt fire when it shouldnt.

Repeat Timer Example

PHP Code:

int g_iTimerValidation;

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_Post);
}

public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast)
{
    g_iTimerValidation++;
    CreateTimer(10.0, TimerCB_DoSomething, g_iTimerValidation, TIMER_REPEAT);
}

public Action TimerCB_DoSomething(Handle hTimer, int iTimerValidation)
{
    if(iTimerValidation == g_iTimerValidation)        //Only fire if still valid
    {
        //Do stuff
        return Plugin_Continue;        //continue repeating
    }
    return Plugin_Stop;        //stop repeating
} 


Non-Repeat Timer Example

PHP Code:

int g_iTimerValidation;

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_Post);
}

public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast)
{
    g_iTimerValidation++;
    CreateTimer(10.0, TimerCB_DoSomething, g_iTimerValidation);
}

public Action TimerCB_DoSomething(Handle hTimer, int iTimerValidation)
{
    if(iTimerValidation == g_iTimerValidation)        //Only fire if still valid
    {
        //Do stuff
    }
} 


[XiLuo]

The trick for these friends above is just to show you how to make sure that a timer doesn't repeat itself.But you have to know,from your code,a timer will be activated after 905s, so if 'round start' again
before this timer is activated,it will created a timer again and be activated 905s later.
These friends's timers solve this problem.
when round end or mapend if you want to kill this timer that is created on round start ，I suggest the following two methods
For round end:you can follow above friends's ways to kill timer on round end
For map end:you can also use the above method or use flag for a timer
for example:
CreateTime(905.0,CallBackTimer,_,TIMER_FLAG_N O_MAPCHANGE);
TIMER_FLAG_NO_MAPCHANGE specifies that the timer will not be passed to the next map
onMapEnd() this timer will be destroyed automatically
There are several official parameters you can use when you need
TIMER_REPEAT /**< Timer will repeat until it returns Plugin_Stop */
TIMER_FLAG_NO_MAPCHANGE /**< Timer will not carry over mapchanges */
TIMER_HNDL_CLOSE /**< Deprecated define, replaced by below */
TIMER_DATA_HNDL_CLOSE /**< Timer will automatically call CloseHandle() on its data when finished */

Multiple flags can also be used simultaneously like this
CreateTimer(1.0,CallBackTimer,_,TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE)

I wish I could help you,excuse my poor English,thanks