[GPhoenix97]

Hi there!

Is there any way I can stop plugin from going forward if condition was not met?
Like for example I'm connecting to database using threaded method and inside it's callback I'm just throwing error if database handle is null. But the problem is that plugin is still running and there are plenty of functions querying database throwing errors because connection was not established.
So what would be considered a good practice here? Stop the plugin from execution and if so - how, or just wrap queries in a control block testing whether database handle is not null?

The other question, is there any way plugin can pause it's execution so it can wait for a response from query callback (and yes I know, that neither query or callback doesn't return anything)? That wouldn't be a such a big problem for me because I could just call the query and do a proper handling of things inside of callback, right? But the thing is I wanted to create a native that would query the database and other plugins that would use that native could handle things differently rather than one and only callback.

PS.
Although I said that callback wasn't a big problem it kinda was. I was calling query from a command callback and I had to pass a Replysource data to query and then to query callback and there setting reply source so i could use ReplyToCommand. Was that a good way of dealing with that problem?

[Kolapsicle]

You can use SetFailState to stop your plugin if an important component fails such as a database. In regards to your second question, if you are looking to run additional logic alongside your base plugin then I'd suggest looking into forwards.

Edit: I haven't dealt with forwards much at all, but I thought I'd give "overriding" a go and it seems to work well. I'm not sure if this is the best way to go about it, though.

Spoiler

PHP Code:

Handle hTeleportFwd;

public void OnPluginStart()
{
    hTeleportFwd = CreateGlobalForward("OnClientPreTeleport", ET_Event, Param_Cell);
    RegConsoleCmd("sm_teleport", Command_Teleport);
}

public Action Command_Teleport(int client, int args)
{
    if (!IsValidClient(client))
    {
        return Plugin_Handled;
    }
    
    if (GetCmdArgs() != 3)
    {
        PrintToChat(client, "[SM] Teleporting requires three coordinates!");
        return Plugin_Handled;
    }
    
    // Call our forward and push client through it
    Call_StartForward(hTeleportFwd);
    Call_PushCell(client);
    
    bool result;
    Call_Finish(result); // result is our return value from our forward
    
    // Our forward returned false, default logic (below) will be cancelled
    if (!result)
    {
        return Plugin_Handled;
    }
    
    float dest[3];
    char buffer[8];
    
    for (int i = 0; i < 3; i++)
    {
        GetCmdArg(i + 1, buffer, sizeof(buffer));
        dest[i] = StringToFloat(buffer);
    }
    
    TeleportEntity(client, dest, NULL_VECTOR, NULL_VECTOR);
    PrintToChat(client, "[SM] Teleported successfully!");
    return Plugin_Handled;
}

// returning false will cancel base plugin behaviour
public bool OnClientPreTeleport(int client)
{
    if (GetClientTeam(client) == 2)
    {
        PrintToChat(client, "[SM] You are not allowed to teleport.");
        return false;
    }
    
    return true;
} 


[Ilusion9]

PHP Code:


Database hDatabase;

public void OnPluginStart()
{
    Database.Connect(OnDatabaseConnection, "time");
}

public void OnDatabaseConnection(Database db, const char[] error, any data)
{
    if (db)
    {
        hDatabase = db; // or delete db if you dont need a global variable with this db
    }
    else
    {
        LogError("Could not connect to the database: %s", error);
        SetFailState("Could not connect to the database.");
    }
} 


once connected, you are always connected to that db, even if your sql server is down for certain time.

[GPhoenix97]

Originally Posted by Kolapsicle You can use SetFailState to stop your plugin

Wow. Thank you. That's embarrassing for me not to know such an elementary thing.

Originally Posted by Kolapsicle I'd suggest looking into forwards.

Yeah, I was thinking about using forwards but it didn't go well for me. I'll give it a second try, thanks.

Originally Posted by Ilusion9 once connected, you are always connected to that db, even if your sql server is down for certain time.

Oh my, didn't know about that. That can cause some problems. Gotta make a fail-safe for that. Thanks.