[groofshark]

Hello, I am trying to fix this code, but I am confused about everything continuing 2-3 days
So, I am trying to combine health regeneration with receiving more health after spawn...

1. g_iSpawnHealth - get spawn health, it can be also more than 100
2. type /regen and regenerate health until g_iSpawnHealth
3. type /buyhealth after spawn - add +50 health to g_iSpawnHealth and I want automatically g_iSpawnHealth to be transfered into g_iSpawnHealth + 50 (new max health) and +50 health to player only
4. regen to continue halth regeneration already until "g_iSpawnHealth + 50" (the new max health)

That's I want but can't make it... That's the code which I made. I would like to help me, thanks!

Code

PHP Code:

#include <amxmodx>
#include <fun>
#include <engine> 
#include <hamsandwich>

#define MAX_PLAYERS 32

new g_iSpawnHealth[MAX_PLAYERS + 1];

new bool:g_iRegeneratig_Status[MAX_PLAYERS + 1];
new bool:g_iBuyHealth_Status[MAX_PLAYERS + 1];

public plugin_init() 
{
    register_clcmd("say /regen", "ClCmd_regen");
    
    register_clcmd("say /buyhealth", "ClCmd_buyhealth");
    
    RegisterHam(Ham_Spawn, "player", "CBase_Player_Spawn_P", true);
}

public ClCmd_regen(id)
{
    g_iRegeneratig_Status[id] = true;
    if( g_iRegeneratig_Status[id] )
    {
        set_task(1.0, "Health_Regen_Task", id, .flags="b");
    
        client_print(id, print_chat, "* Your health regeneration has been activated.");
    }
}

public Health_Regen_Task(id)
{
    new Float:iHealth = entity_get_float(id, EV_FL_max_health);
    new iCurrentHealth = get_user_health(id);
    if( iCurrentHealth < iHealth )
    {
        set_user_health(id, iCurrentHealth + 1);
    }
}

public ClCmd_buyhealth(id)
{
    g_iBuyHealth_Status[id] = true;
    if( g_iBuyHealth_Status[id] )
    {
        new iHealthGiven = 50;
        new iNewMaxHealth = g_iSpawnHealth[id] + iHealthGiven;
        set_user_health(id, get_user_health(id) + iHealthGiven);
        
        if( iNewMaxHealth != 100 )
        {
            entity_set_float(id, EV_FL_max_health, float(iNewMaxHealth)); 
        }
    }
}

public CBase_Player_Spawn_P(id) 
{ 
     if( is_user_alive(id) ) 
        {
            if( get_user_health(id) != entity_get_float(id, EV_FL_health) )
            {
            entity_set_float(id, EV_FL_health, float(g_iSpawnHealth[id]));
        }
        if( get_user_health(id) != 100 )
        {
            entity_set_float(id, EV_FL_max_health, float(g_iSpawnHealth[id])); 
        }
            if( g_iRegeneratig_Status[id] )
            {
                g_iRegeneratig_Status[id] = !g_iRegeneratig_Status[id];
                client_print(id, print_chat, "* Your health regeneration expired.");             
            }
        }
} 


[Depresie]

i dont understand exactly what you want to do.. could you please explain better?
you want the regen hp limit to increase by 50hp for everytime the player is respawned?

[groofshark]

I just want HP regen, until spawn health(it can be 100, 120 etc...) and if I buy more health HP regen if I have spawn health 120 and HP Buy +50 = 170. So I want HP regen to be until 170. That's all.

[!Morte]

PHP Code:

/* Plugin generated by AMXX-Studio */

#include < amxmodx >
#include < amxmisc >
#include < fun >
#include < hamsandwich >

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"

const TASK_REGEN = 7777;

#define ID_REGEN        ( taskid - TASK_REGEN )

new g_SpawnHealth[ 33 ];
new g_MaxPlayers;

public plugin_init() 
{
    register_plugin( PLUGIN, VERSION, AUTHOR );
    
    register_logevent("logevent_round_end", 2, "1=Round_End")
    
    register_clcmd( "say /buyhealth", "clcmd_buyheatlh" );
    register_clcmd( "say /regen", "clcmd_regen" );
    
    RegisterHam( Ham_Killed, "player", "fw_PlayerKilled" );
    RegisterHam( Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1 );
    
    g_MaxPlayers = get_maxplayers( );
}

public client_putinserver( id )
{
    g_SpawnHealth[ id ] = 100;
}

public client_disconnect( id )
{
    remove_task( id+TASK_REGEN );
}

public logevent_round_end( )
{
    for( new id = 1; id <= g_MaxPlayers; id++ )
        remove_task( id+TASK_REGEN );
}

public clcmd_buyheatlh( id )
{
    g_SpawnHealth[ id ] += 50;
    set_user_health( id, get_user_health( id ) + 50 );
    client_print( id, print_chat, "You bought +50 HP and you healed +50 HP too." );
    return PLUGIN_HANDLED;
}

public clcmd_regen( id )
{
    if( task_exists( id+TASK_REGEN ) )
    {
        client_print( id, print_chat, "HP Regeneration is on." );
        return PLUGIN_HANDLED;
    }
    
    set_task( 1.0, "task_hp_regen", id+TASK_REGEN, _, _, "b" );
    
    return PLUGIN_HANDLED;
}

public task_hp_regen( taskid )
{
    if( !is_user_alive( ID_REGEN ) )
        remove_task( ID_REGEN );

    if( get_user_health( ID_REGEN ) < g_SpawnHealth[ ID_REGEN ] )
        set_user_health( ID_REGEN, get_user_health( ID_REGEN ) + 1 );
}

public fw_PlayerSpawn_Post( id )
{
    if( !is_user_alive( id ) )
        return;
    
    remove_task( id+TASK_REGEN );
    set_user_health( id, g_SpawnHealth[ id ] );
}

public fw_PlayerKilled( victim, attacker, shouldgib )
{
    if( task_exists( victim+TASK_REGEN ) )
        remove_task( victim+TASK_REGEN );
} 


[Bugsy]

My only suggestion would be to use a single thinking entity that regenerates all players via a loop. With your method, you are constantly re-creating tasks for each player and it is an expensive operation to create tasks. Also, when you call remove_task(), you do not need to check if the task exists first..it will remove it if it exists without checking first.

Edit: Made entity only think during round when player(s) have regen on. Added macros for bit operations.

PHP Code:

#include <amxmodx>
#include <engine>
#include <fun>
#include <hamsandwich>

#define CheckBit(%1)    (g_RegenStatus & (1<<(%1 & 31)))
#define SetBit(%1)    (g_RegenStatus = (1<<(%1 & 31)))
#define RemoveBit(%1)    (g_RegenStatus &= ~(1<<(%1 & 31)))

new g_SpawnHealth[ 33 ];
new g_MaxPlayers;
new g_RegenStatus;
new g_iRegenEntity;

public plugin_init() 
{
    register_logevent("logevent_round_end", 2, "1=Round_End")
    
    register_clcmd( "say /buyhealth", "clcmd_buyheatlh" );
    register_clcmd( "say /regen", "clcmd_regen" );
    
    RegisterHam( Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1 );
    
    g_iRegenEntity = create_entity( "info_target" );
    entity_set_string( g_iRegenEntity , EV_SZ_classname , "regenhealth_entity" );
    register_think( "regenhealth_entity" , "fw_EntThink" );
    
    g_MaxPlayers = get_maxplayers( );
}

public client_putinserver( id )
{
    g_SpawnHealth[ id ] = 100;
}

public client_disconnect( id )
{
    RemoveBit( id );
}

public clcmd_buyheatlh( id )
{
    g_SpawnHealth[ id ] += 50;
    
    set_user_health( id, get_user_health( id ) + 50 );
    client_print( id, print_chat, "* You bought +50 HP and you healed +50 HP too." );
    
    return PLUGIN_HANDLED;
}

public clcmd_regen( id )
{
    if ( !is_user_alive( id ) )
    {
        client_print( id, print_chat, "* You must be alive to use HP Regeneration." );
    }
    else if ( CheckBit( id ) )
    {
        client_print( id, print_chat, "* HP Regeneration is already on!" );
    }
    else
    {
        if ( !g_RegenStatus )
        {
            entity_set_float( g_iRegenEntity , EV_FL_nextthink , ( get_gametime() + 1.0 ) );
        }
        
        SetBit( id );
        client_print( id, print_chat, "* Your health regeneration has been activated.");
    }

    return PLUGIN_HANDLED;
}

public fw_PlayerSpawn_Post( id )
{
    if( is_user_alive( id ) )
    {
        set_user_health( id , g_SpawnHealth[ id ] );
    }
}

public logevent_round_end( )
{
    g_RegenStatus = 0;
}

public fw_EntThink( iEntity )
{
    if ( g_RegenStatus )
    {
        for ( new id = 1 ; id <= g_MaxPlayers ; id++ )
        {
            if ( CheckBit( id ) && ( get_user_health( id ) < g_SpawnHealth[ id ] ) )
            {
                set_user_health( id , get_user_health( id ) + 1 );    
            }
        }
    
        entity_set_float( g_iRegenEntity , EV_FL_nextthink , ( get_gametime() + 1.0 ) );
    }
} 


[groofshark]

Thank you @!Morte, thank you Bugsy - your code is everything which I want... I only made g_SpawnHealth to be checked at player's spawn with get_user_health. That was all. Thank you for helping me!

[aron9forever]

Originally Posted by Bugsy when you call remove_task(), you do not need to check if the task exists first..it will remove it if it exists without checking first.

I'm gonna partially hijack this thread and ask, because I have task_exists before every remove_task in every plugin I've ever made

Is there no error, warning, nothing when removing a task that doesn't exist? I went with the idea that it could spout warnings like executing on non valid clients does

[Bugsy]

Originally Posted by aron9forever I'm gonna partially hijack this thread and ask, because I have task_exists before every remove_task in every plugin I've ever made Is there no error, warning, nothing when removing a task that doesn't exist? I went with the idea that it could spout warnings like executing on non valid clients does

There are no issues/errors/warnings with calling remove_task() without checking task_exists() first.